695928_de-DE

liliconcom

Spezifikationsgrenzen erstellen

Hallo,

Ich versuche, Spezifikationsgrenzen mithilfe der JMP-Schnittstelle oder JSL zu erstellen. Ich versuche, das Spezifikationslimit für verschiedene Spalten ohne USL oder LSL zu erstellen. Bitte helfen Sie. Dank.

Grundlegende Datenanalyse und ModellierungQualitäts- und VerfahrenstechnikBetreff: Spezifikationsgrenzen erstellen

Haben Sie sich den Limits Manager angeschaut?

Analysieren=>Qualität und Prozess=>Limitsmanager

Betreff: Spezifikationsgrenzen erstellen

Hallo Jim,

Ich habe es mir angesehen, aber soweit ich weiß, besteht dieses Tool darin, Grenzwerte zu akzeptieren und auf die Spalte anzuwenden. Was ich versuche, ist, einfach eine USL oder LSL basierend auf einem Sigma und einem von mir bereitgestellten Mittelwert zu berechnen. Oder wenn es ein Tool gibt, mit dem ich spezifiziere, wie das Sigma für diese Spalte aussehen soll, und JMP dann die Spezifikationsgrenzen generiert. Sind Sie schon einmal auf so etwas gestoßen? Danke Jim.

Betreff: Spezifikationsgrenzen erstellen

Spezifikationsgrenzen sind normalerweise keine berechneten Grenzen.Sie werden auf der Grundlage der Designspezifikationen oder der Werkzeugbeschränkungen usw. festgelegt.

 

Hier ist jedoch ein einfaches Skript, das die Spezifikationsgrenzen für alle fortlaufenden Spalten in einer Datentabelle mithilfe von 3-Sigma-Grenzwerten festlegt

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

Betreff: Spezifikationsgrenzen erstellen

Sicherlich! Um Spezifikationsgrenzen in JMP mithilfe von JSL zu erstellen, öffnen Sie Ihre Datentabelle, wählen Sie die gewünschte Spalte aus und verwenden Sie die Verteilungsplattform mit der Option „Spezifikationsgrenzen“, um Ihre Grenzen festzulegen.

Betreff: Spezifikationsgrenzen erstellen

ist es möglich, für unterschiedliche Schritte unterschiedliche Spezifikationsgrenzen einzurichten, ohne alle Schritte auf die einzelnen Spalten aufzuteilen?

Betreff: Spezifikationsgrenzen erstellen

Derzeit ist nur ein Satz an Spezifikationsgrenzen pro Spalte zulässig.

Mithilfe von JSL können jedoch mehrere Spezifikationsgrenzen in ein Skript integriert werden, das eine Datentabelle durchläuft, jede Untergruppe einzeln herauszieht, die Spezifikationsgrenzen für die Untergruppe anwendet und dann die Analyse ausführt. Hier ist ein einfaches Beispiel.

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);