695928_fr-FR

liliconcom

Création de limites de spécifications

Salut,

J'essaie de créer des limites de spécifications à l'aide de l'interface jmp ou jsl. J'essaie de créer la limite de spécifications pour différentes colonnes sans USL ni LSL. S'il vous plaît, aidez-moi. remercier.

Analyse et modélisation des données de baseIngénierie Qualité et ProcédésRe : Création de limites de spécifications

Avez-vous consulté le gestionnaire de limites ?

Analyse=>Qualité et Process=>Gestionnaire des Limites

Re : Création de limites de spécifications

Salut Jim,

Je l'ai regardé, mais d'après ce que je vois, cet outil consiste à accepter la limite et à l'appliquer à la colonne. Ce que j'essaie de faire, c'est simplement de calculer un USL ou un LSL basé sur un sigma et une moyenne que je fournis. Ou s'il existe un outil dans lequel je précise ce que je veux que le sigma soit pour cette colonne, puis JMP génère les limites de spécifications. Avez-vous vécu quelque chose comme ça ? merci Jim.

Re : Création de limites de spécifications

Les limites de spécifications ne sont normalement pas des limites calculées.Ils sont définis en fonction des spécifications de conception ou des limitations de l'outil, etc.

 

Cependant, voici un script simple qui définira les limites de spécifications pour toutes les colonnes continues d'une table de données en utilisant 3 limites sigma.

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

Re : Création de limites de spécifications

Certainement! Pour créer des limites de spécifications dans JMP à l'aide de JSL, ouvrez votre table de données, choisissez la colonne souhaitée et utilisez la plateforme de distribution avec l'option Limites de spécifications pour définir vos limites.

Re: Création de limites de spécifications

est-il possible de configurer différentes limites de spécifications pour différentes étapes sans diviser toutes les étapes dans chaque colonne ?

Re: Création de limites de spécifications

Actuellement, un seul ensemble de limites de spécifications est autorisé par colonne.

Cependant, en utilisant JSL, plusieurs limites de spécification peuvent être intégrées dans un script qui peut parcourir une table de données en extrayant chaque sous-groupe un par un, en appliquant les limites de spécification pour le sous-ensemble, puis en exécutant l'analyse. Voici un exemple simple.

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);