695928_zh-TW

liliconcom

建立規格限制

你好，

我正在嘗試使用 jmp 介面或 jsl 建立規格限制。 我正在嘗試為沒有 USL 或 LSL 的不同列建立規格限制。 請幫忙。感謝。

基礎資料分析與建模品質和工藝工程回覆：建立規格限制

您研究過限制管理器嗎？

分析=>品質和流程=>限制經理

回覆：建立規格限制

嗨吉姆，

我已經看過它，但據我所知，這個工具是接受限制並將其應用到列。 我想做的是根據 sigma 和我提供的平均值計算 USL 或 LSL。 或者，如果有一個工具，我可以在其中指定該列的西格瑪值，然後 JMP 產生規格限。 你遇過這樣的事情嗎？謝謝吉姆。

回覆：建立規格限制

規格限值通常不是計算限值。它們是根據設計規格或工具限制等設定的。

 

但是，這裡有一個簡單的腳本，它將使用 3 西格瑪限制為資料表中的所有連續列設定規格限制

Names Default To Here( 1 );
dt = Current Data Table();

colNames = dt << get column names( string, continuous );

For Each( {col}, colNames,
 theMean = Col Mean( As Column( dt, col ) );
 theSTD = Col Std Dev( As Column( dt, col ) );
 Eval(
  Substitute(
    Expr(
     Column( dt, col ) << set property(
      "Spec Limits",
      {LSL( _LSL_ ), Target( _Target_ ), USL( _USL_ ), Show Limits( 1 )}
     )
    ),
   Expr( _LSL_ ), theMean - 3 * theSTD,
   Expr( _Target_ ), theMean,
   Expr( _USL_ ), theMean + 3 * theSTD
  )
 );
);

回覆：建立規格限制

當然！ 若要使用 JSL 在 JMP 中建立規格限值，請開啟資料表，選擇所需的列，然後使用分佈平台和規格限值選項來設定限值。

回覆：建立規格限制

是否可以為不同步驟設定不同的規格限制，而無需將所有步驟拆分到每個欄位中？

回覆：建立規格限制

目前，每列僅允許一組規格限制。

然而，使用 JSL，可以將多個規格限制編織到一個腳本中，該腳本可以循環遍歷資料表，一次取出每個子組，應用該子集的規格限制，然後執行分析。這是一個簡單的例子。

Names Default To Here( 1 );
dt = 
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

dtLimits = New Table( "Limits",
	New Column( "Group", character, values( {"F", "M"} ) ),
	New Column( "USL", values( {66, 70} ) ),
	New Column( "Target", values( {61, 64} ) ),
	New Column( "LSL", values( {52, 51} ) )
);

groups = Associative Array( dt:sex ) << get keys;

nw = New Window( "Distributions", hlb = H List Box() );

For Each( {level}, groups,
	dt << select where( :sex == level );
	dtSub = dt << subset( selected columns( 0 ), selecte rows( 1 ), output table( level ), invisible );
	theRow = (dtLimits << get rows where( :group == level ))[1];
	Eval(
		Eval Expr(
			dtSub:height << set property(
				"spec limits",
				{LSL( Expr( dtLimits:LSL[theRow] ) ), USL( Expr( dtLimits:USL[theRow] ) ),
				Target( Expr( dtLimits:Target[theRow] ) ), Show Limits( 1 )}
			)
		)
	);
	hlb << append(
		dis = dtSub << Distribution( Continuous Distribution( Column( :height ), Process Capability( 0 ) ) );
		Report( dis )[Outline Box( 2 )] << set title( "Height=" || level )
		;
	);	
);