Gráfico de GraphBuilder: ¿Etiquetas?Hola, sé cómo habilitar etiquetas para mapas de calor: las etiquetas están muy bien alineadas con las celdas del mapa de calor y los valores corresponden a los valores de las columnas que se utilizan como color.
También sé cómo habilitar etiquetas para gráficos de puntos, donde las etiquetas se pueden elegir independientemente de la columna "color":
¿Es posible combinar ambos enfoques?
Etiquetas de mapa de calor, donde se usa una columna como etiquetas que NO ES LA MISMA que la columna utilizada para el color.
Caso de aplicación:
use un valor normalizado significativo como color [por ejemplo, tasa de mortalidad], pero muestre los recuentos reales [por ejemplo, víctimas de Covid 19] como etiquetas.
Pregunta adicional: ¿es posible utilizar Etiquetas de personajes ?
por ejemplo, una combinación de
y
... algo como:
Entonces, ¿es similar a agregar etiquetas de puntos a un gráfico de mapa de calor, pero con el texto bien limitado a las celdas del mapa de calor?
Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Formula Column(
Operation( Category( "Distributional" ), "Rank" ),
Columns( :height ),
Group By( :age, :sex )
);
dtsplit = dt << Split(
Split By( :"Rank[height][age,sex]"n ),
Split( :name ),
Group( :age, :sex ),
Remaining Columns( Drop All )
);
dtCombine = dtsplit << Combine Columns(
columns( :"1"n, :"2"n, :"3"n, :"4"n, :"5"n, :"6"n, :"7"n ),
Column Name( "Students" ),
Delimiter( "," )
);
New Column( "N_students",
Formula( N Items( Words( :Students, "," ) ) )
);
Graph Builder(
Variables( Y( :age ), Group X( :sex ), Color( :N_students ) ),
Elements( Heatmap( Y ) )
);
dtCombine << Split(
Split By( :sex ),
Split( :Students ),
Group( :age ),
Remaining Columns( Drop All )
)
Exploración y visualización de datosRe: Gráfico de GraphBuilder: ¿Etiquetas?¿Establecer columna como etiqueta y etiqueta por fila?
Re: Gráfico de GraphBuilder: ¿Etiquetas?Con algunas trampas (agregando manualmente algunos saltos de línea en la tabla), lo mejor que puedo ofrecer en este momento:
una combinación de mapa de calor y puntos.
... desafortunadamente con las etiquetas colocadas de alguna manera arbitrariamente
Hay una entrada en la lista de deseos para resolver estos problemas, pero lamentablemente se archivó 
Alineación de etiquetas en Graph Builder
dtSplit << Graph Builder(
Variables( Y( :age ), Group X( :sex ), Color( :N_students ) ),
Elements(
Heatmap( Y, Legend( 1 ) ),
Points( Y, Color( 0 ), Legend( 2 ) )
),
SendToReport(
Dispatch(
{},
"400",
ScaleBox,
{Legend Model(
2,
Properties( 0, {Marker Size( 0 )}, Item ID( "age", 1 ) )
)}
)
)
)
Re: Gráfico de GraphBuilder: ¿Etiquetas?Qué día tan maravilloso, ya está ahí 
¡Característica bastante oculta!
Las etiquetas no cambian cuando se agregan filas o columnas como etiquetas,
Las etiquetas simplemente se actualizan cuando el usuario cambia la configuración de la etiqueta.
Re: Gráfico de GraphBuilder: ¿Etiquetas?Entonces, en realidad
Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
:name << Label( 1 );
Graph Builder(
Variables( X( :sex ), Y( :age ) ),
Elements( Heatmap( X, Y, Label( "Label by Row" ) ) )
)
... hará el trabajo.
¿Existe alguna configuración para separar las entradas con nuevas líneas en lugar de punto y coma?
Re: Gráfico de GraphBuilder: ¿Etiquetas?Utilice el script anterior que utilizó y utilice \!N como separador
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Formula Column(Operation(Category("Distributional"), "Rank"), Columns(:height), Group By(:age, :sex));
dtsplit = dt << Split(Split By(:"Rank[height][age,sex]"n), Split(:name), Group(:age, :sex), Remaining Columns(Drop All));
dtsplit << Combine Columns(columns(:"1"n, :"2"n, :"3"n, :"4"n, :"5"n, :"6"n, :"7"n), Column Name("Students"), Delimiter("\!N"));
//dtCombine << get name;
dtsplit << New Column("N_students", Formula(N Items(Words(:Students, "\!N"))));
Column(dtsplit, "Students") << Label(1);
gb = dtsplit << Graph Builder(
Variables(Y(:age), Group X(:sex), Color(:N_students)),
Elements(Heatmap(Y, Legend(1), Label("Label by Row")))
);Re: Gráfico de GraphBuilder: ¿Etiquetas?1:0 para JSL frente a GUI
Delimiter("\!N")Re: Gráfico de GraphBuilder: ¿Etiquetas?En JMP, es posible combinar etiquetas de mapas de calor con una columna separada para etiquetas diferentes de la columna de color. Esto puede resultar útil para mostrar valores normalizados como color y al mismo tiempo mostrar los recuentos reales como etiquetas.
Re: Gráfico de GraphBuilder: ¿Etiquetas?Estaba a punto de solicitar esto: lo usaríamos *todo el tiempo*.
[actualización: Jarmo demostró que JMP ya hace esto: ¡felicitaciones!]
