693781_it-IT

liliconcom

Come eseguire elegantemente un aggiornamento, ma per una singola riga?

Ciao, sto cercando di prendere una riga da una tabella e di inserirla in un'altra tabella in una riga specificata dall'utente in una casella di immissione. Tuttavia, la funzione di aggiornamento non sembra avere la possibilità di specificare le righe, quindi mi resta da impiegare un'ora e digitare ciascuna delle mie 105 colonne per entrambe le tabelle di dati in quanto tali:

dt:{"ColA"}[rownumber] = dt1:{"ColA"}[1];<BR />dt:{"ColB"}[rownumber] = dt1:{"ColB"}[1];<BR />.<BR />.<BR />.<BR />dt:{"ColDA"}[rownumber] = dt1:{"ColDA"}[1];

Il che va bene, ma posso immaginare i miei amici programmatori che si dimenano sui loro posti. Esiste un modo più elegante per farlo? Ho visto qualcuno fare riferimento ad array associativi, ma ho problemi a usarli.

 

Presumo che il codice sopra sia sufficiente, ma se è importante, ecco il codice originale, con la relativa linea disegnata in rosso:

w = New Window( "Choose Row Number for XRD Run input", // opens a window with a title and this content...
    Border Box( top( 20 ), bottom( 20 ), Left( 20 ), Right( 20 ), // window dressing 
        V List Box( // V and H lists nest to organize the display boxes
            H Center Box( Text Box( "Choose Row Number for XRD Run input" ) ), // a second title, centered
            Spacer Box( size( 1, 30 ) ), // a little vertical space
            H Center Box( rowtemp=Number Edit Box( ) ), // data entry
            Spacer Box( size( 1, 10 ) ), // a little vertical space
            H Center Box( // center the button
                Button Box( "Import Data", // this script runs when the button is pressed...
     rownumber = rowtemp << Get;
                    // Run XML Import
                    Include( "jmpprj://contents/Import XRD XML.jsl");
                    // Reference Data Tables
                    dt = Data Table( "Experimental Info" );
                    dt1 = Data Table( "XMLTempTable" );
                    // Move to Experimental info table
                    <FONT color="#FF0000">dt:{"xsi:Schema Location 1"}[rownumber] = dt1:{"xsi:Schema Location 1"}[1];</FONT>
                    // Close XMLTempTable
                    close(dt1);
                    // optionally, close the dialog. Or, you might want to run it again...
                    w << closeWindow; // just the dialog, not the report
                )
            )
        )
    )
);

Automazione e scriptingfinestreRe: Come eseguire un aggiornamento in modo elegante, ma per una singola riga?

Ecco un modo per eseguire un aggiornamento di una singola riga.Prende una riga specificata da una tabella di dati e la aggiorna in una riga specificata in un'altra tabella di dati.

names default to here(1);
dt=
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

// Create a random data table with 5 rows
// Subset data table
// → Data Table( "Subset of Big Class" )
dt2 = dt << Subset( Sample Size( 5 ), Selected columns only( 0 ), output table("Selection") );

// Give new names to the subsetted table
dt2:name[1] = "PAT"; 
dt2:name[2] = "BRIT";
dt2:name[3] = "TERRY";
dt2:name[4] = "KRIS";
dt2:name[5] = "JEN";
wait(10);

// Below is the code that does the 1 row update

// Row in data table Big Class to be updated
outRow = 12;

// Row in data table Selection to get data from
inRow = 4;

// The Update process
// Create a row column in data table Big Class
dt << new column( "Row", formula(row()));

// Subset the inRow to a new table
dt2 << select where(row()== inRow);

dtTemp = dt2 << subset(selected rows(1), selected columns(0), invisible);

// Clear selected row in data table Selection
dt2 << clear select;

// Create a new column in the temp data table
dtTemp << new column("Row", set each value(outRow));

// Update data table Big Class
dt << Update(
 With( dtTemp ),
 Match Columns( :Row = :Row )
);

//  Delete the temp data table
close( dtTemp, nosave );

// Delete the Row Column
dt << delete columns( :Row );

Re: Come eseguire un aggiornamento in modo elegante, ma per una singola riga?

Se disponi di identificatori univoci in entrambe le tabelle, come nome ed età, potresti utilizzarli come condizioni di corrispondenza.

 

Inoltre, puoi utilizzare una colonna di trasformazione virtuale selezione della riga per fornire una condizione di corrispondenza aggiuntiva per selezionare le righe da aggiornare:

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Namespace(
 "selection"
);

selection:ChangeRows = [5, 2, 7];

updateTable = dt << Subset( All rows, Selected columns only( 0 ) );
:weight << set each value( 1000 );

dt << Update(
 With( updateTable ),
 Match Columns(
  :name = :name,
  :age = :age,
  transform column( "row selection", Formula( If( N Items( Loc( selection:ChangeRows, Row() ) ), 1, . ) ) ) =
  transform column( "row selection", Formula( 1 ) )
 ),
 Add Columns from Update Table( None ),
 Replace Columns in Main Table( :weight )
);