693781_zh-CN

liliconcom

如何优雅地执行更新，但对于单行？

您好 - 我正在尝试从一个表中取出一行，并将其放入另一个表中用户在输入框中指定的行中。 但是，更新函数似乎无法指定行，因此我需要花一个小时为两个数据表键入 105 列中的每一列，如下所示：

dt:{"ColA"}[rownumber] = dt1:{"ColA"}[1];<BR />dt:{"ColB"}[rownumber] = dt1:{"ColB"}[1];<BR />.<BR />.<BR />.<BR />dt:{"ColDA"}[rownumber] = dt1:{"ColDA"}[1];

这很好，但我可以想象我的编码朋友们在座位上蠕动。 有没有更优雅的方法来做到这一点？ 我见过有人引用关联数组，但我在使用它们时遇到了问题。

 

我认为上面的代码就足够了，但如果重要的话，这里是原始代码，相关行用红色绘制：

w = New Window( "Choose Row Number for XRD Run input", // opens a window with a title and this content...
    Border Box( top( 20 ), bottom( 20 ), Left( 20 ), Right( 20 ), // window dressing 
        V List Box( // V and H lists nest to organize the display boxes
            H Center Box( Text Box( "Choose Row Number for XRD Run input" ) ), // a second title, centered
            Spacer Box( size( 1, 30 ) ), // a little vertical space
            H Center Box( rowtemp=Number Edit Box( ) ), // data entry
            Spacer Box( size( 1, 10 ) ), // a little vertical space
            H Center Box( // center the button
                Button Box( "Import Data", // this script runs when the button is pressed...
     rownumber = rowtemp << Get;
                    // Run XML Import
                    Include( "jmpprj://contents/Import XRD XML.jsl");
                    // Reference Data Tables
                    dt = Data Table( "Experimental Info" );
                    dt1 = Data Table( "XMLTempTable" );
                    // Move to Experimental info table
                    <FONT color="#FF0000">dt:{"xsi:Schema Location 1"}[rownumber] = dt1:{"xsi:Schema Location 1"}[1];</FONT>
                    // Close XMLTempTable
                    close(dt1);
                    // optionally, close the dialog. Or, you might want to run it again...
                    w << closeWindow; // just the dialog, not the report
                )
            )
        )
    )
);

自动化和脚本编写视窗回复：如何优雅地执行更新，但对于单行？

这是进行单行更新的一种方法。它从一个数据表中获取指定行，并将其更新到另一数据表中的指定行。

names default to here(1);
dt=
// Open Data Table: Big Class.jmp
// → Data Table( "Big Class" )
Open( "$SAMPLE_DATA/Big Class.jmp" );

// Create a random data table with 5 rows
// Subset data table
// → Data Table( "Subset of Big Class" )
dt2 = dt << Subset( Sample Size( 5 ), Selected columns only( 0 ), output table("Selection") );

// Give new names to the subsetted table
dt2:name[1] = "PAT"; 
dt2:name[2] = "BRIT";
dt2:name[3] = "TERRY";
dt2:name[4] = "KRIS";
dt2:name[5] = "JEN";
wait(10);

// Below is the code that does the 1 row update

// Row in data table Big Class to be updated
outRow = 12;

// Row in data table Selection to get data from
inRow = 4;

// The Update process
// Create a row column in data table Big Class
dt << new column( "Row", formula(row()));

// Subset the inRow to a new table
dt2 << select where(row()== inRow);

dtTemp = dt2 << subset(selected rows(1), selected columns(0), invisible);

// Clear selected row in data table Selection
dt2 << clear select;

// Create a new column in the temp data table
dtTemp << new column("Row", set each value(outRow));

// Update data table Big Class
dt << Update(
 With( dtTemp ),
 Match Columns( :Row = :Row )
);

//  Delete the temp data table
close( dtTemp, nosave );

// Delete the Row Column
dt << delete columns( :Row );

回复：如何优雅地执行更新，但对于单行？

如果两个表中都有唯一标识符，例如姓名和年龄，则可以将它们用作匹配条件。

 

此外，您还可以使用虚拟变换列行选择提供额外的匹配条件来选择要更新的行：

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Namespace(
 "selection"
);

selection:ChangeRows = [5, 2, 7];

updateTable = dt << Subset( All rows, Selected columns only( 0 ) );
:weight << set each value( 1000 );

dt << Update(
 With( updateTable ),
 Match Columns(
  :name = :name,
  :age = :age,
  transform column( "row selection", Formula( If( N Items( Loc( selection:ChangeRows, Row() ) ), 1, . ) ) ) =
  transform column( "row selection", Formula( 1 ) )
 ),
 Add Columns from Update Table( None ),
 Replace Columns in Main Table( :weight )
);