693151_de-DE

liliconcom

Farbzellen

Hallo,

 

Wie kann ich leere oder mit Punkten versehene Zellen ausgrauen?

Ich habe Version 16.1.

Danke

DatenzugriffBetreff: Zellen färben

Wenn Sie mit Ausgrauen das Ändern der Zellenfarbe meinen, sind die einfachsten Optionen höchstwahrscheinlich skriptbasiert. Eine Möglichkeit besteht darin, << Get Rows Where zu verwenden, um die Zeilen abzurufen, die Sie einfärben möchten, und dann << Color Cells zu verwenden, um die Farbe für diese Zeilen festzulegen

Names Default To Here(1);

dt = Current Data Table();

For Each({colname}, dt << Get Column Names("String"),
 rows_to_color = dt << Get Rows Where(Is Missing(Column(dt, colname)[]));
 Column(dt, colname) << Color Cells("Gray", rows_to_color);
 dt << Clear Select;
);

 

Betreff: Zellen färben

Wenn Sie möchten, dass dies für jede Spalte erledigt wird, können Sie dieses Skript verwenden.

For Each( {col}, dt << Get Column Names( "String" ),
 Eval(
  Eval Expr(
   dt << Select Where( Is Missing( As Column( Expr( col ) ) ) );
   Expr( Column( col ) ) << Color Cells( "gray" );
   dt << Clear Select;
  )
 )
);

*bearbeiten

Das Expr() und all das ist völlig unnötig.@jthi Darauf hat er mit seinem Beispiel hingewiesen.

For Each( {col}, dt << Get Column Names( "String" ),
 dt << Select Where( Is Missing( As Column( col ) ) );
 Column( col ) << Color Cells( "gray" );
 dt << Clear Select;
);

 

Betreff: Zellen färben

@mmarchandTSI Möglicherweise möchten Sie auch eine Überprüfung hinzufügen, ob einige Zeilen ausgewählt sind (<< Zellen einfärben färbt andernfalls alle Zellen ein).

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(3),
 Compress File When Saved(1),
 New Column("Column 1", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 1])),
 New Column("Column 2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("Column 3", Numeric, "Continuous", Format("Best", 12), Set Values([2, 3, 4]))
);

For Each({col}, dt << Get Column Names("String"),
 dt << Select Where(Is Missing(As Column(col)));
 Column(col) << Color Cells("gray");
 dt << Clear Select;
);
/*
For Each({col}, dt << Get Column Names("String"),
 dt << Select Where(Is Missing(As Column(col)));
 If(N Items(dt << Get Selected Rows) > 0,
  Column(col) << Color Cells("gray");
 );
 dt << Clear Select;
);
*/

Betreff: Zellen färben

Sollte in Ordnung sein, da <

dt << Select Where( Is Missing( As Column( col ) ), current selection( "clear" ) )

Betreff: Zellen färben

Hallo Jarmo,

 

Wo kann ich diese Option hinzufügen? Tut mir leid, ich bin neu im Umgang mit der JMP-Software.

Betreff: Zellen färben

Was ich meinte ist, dass alle Zellen in dieser Spalte gefärbt werden, wenn überhaupt keine Zeilen ausgewählt sind.

 

In diesem Fall werden alle Zellen in „Alter“ gefärbt, da keine Zeilen ausgewählt sind

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
wait(1);

:Age << Color Cells("Red");
wait(1);

dt << Select Rows([2,4,6,20]);
:Name << Color Cells("Blue");
dt << Clear Select;

 

Betreff: Zellen färben

Ja, guter Punkt.

Betreff: Zellen färben

Je nachdem, wie dies verwendet wird, gibt es nur wenige Optionen. Die einfachste Option, mit der Sie loslegen können, ist das Öffnen einer neuen Skriptdatei über das Menü „Datei“.

Kopieren Sie dann das Skript und fügen Sie es in das Fenster ein, das sich öffnet

Überprüfen Sie in der oberen „Symbolleiste“, ob die Tabelle korrekt ist (dies sollte der Fall sein, wenn sie zuletzt aktiv war, als Sie die neue Skriptdatei geöffnet haben).

Klicken Sie dann in der Symbolleiste auf „Skript ausführen“.

 

Wenn dies wiederholt erfolgen muss, können Sie das Skript je nach Verwendungszweck in ein Symbolleistenelement, ein Add-In, ein Tabellenskript, eine Skriptdatei usw. umwandeln

 

Betreff: Zellen färben

Perfekt! Ich danke Ihnen für Ihre Hilfe. Ich schätze es wirklich.