693151_fr-FR

liliconcom

Cellules de couleur

Salut,

 

Comment puis-je griser les cellules vides ou avec des points ?

J'ai la version 16.1.

Merci

Accès aux donnéesRe : Cellules de couleur

Si par grisage vous entendez changer la couleur de la cellule, les options les plus simples sont probablement basées sur un script. Une option consiste à utiliser << Get Rows Where pour obtenir les lignes que vous souhaitez colorer, puis à utiliser << Color Cells pour définir la couleur de ces lignes.

Names Default To Here(1);

dt = Current Data Table();

For Each({colname}, dt << Get Column Names("String"),
 rows_to_color = dt << Get Rows Where(Is Missing(Column(dt, colname)[]));
 Column(dt, colname) << Color Cells("Gray", rows_to_color);
 dt << Clear Select;
);

 

Re : Cellules de couleur

Si vous souhaitez que cela soit appliqué à chaque colonne, vous pouvez utiliser ce script.

For Each( {col}, dt << Get Column Names( "String" ),
 Eval(
  Eval Expr(
   dt << Select Where( Is Missing( As Column( Expr( col ) ) ) );
   Expr( Column( col ) ) << Color Cells( "gray" );
   dt << Clear Select;
  )
 )
);

*modifier

Le Expr() et tout ça sont complètement inutiles.@jthi l'a souligné avec son exemple.

For Each( {col}, dt << Get Column Names( "String" ),
 dt << Select Where( Is Missing( As Column( col ) ) );
 Column( col ) << Color Cells( "gray" );
 dt << Clear Select;
);

 

Re : Cellules de couleur

@mmarchandTSI vous souhaiterez peut-être également vérifier que certaines lignes sont sélectionnées (<< Color Cells colorera sinon toutes les cellules).

Names Default To Here(1);

dt = New Table("Untitled",
 Add Rows(3),
 Compress File When Saved(1),
 New Column("Column 1", Numeric, "Continuous", Format("Best", 12), Set Values([., ., 1])),
 New Column("Column 2", Numeric, "Continuous", Format("Best", 12), Set Values([., ., .])),
 New Column("Column 3", Numeric, "Continuous", Format("Best", 12), Set Values([2, 3, 4]))
);

For Each({col}, dt << Get Column Names("String"),
 dt << Select Where(Is Missing(As Column(col)));
 Column(col) << Color Cells("gray");
 dt << Clear Select;
);
/*
For Each({col}, dt << Get Column Names("String"),
 dt << Select Where(Is Missing(As Column(col)));
 If(N Items(dt << Get Selected Rows) > 0,
  Column(col) << Color Cells("gray");
 );
 dt << Clear Select;
);
*/

Re : Cellules de couleur

Cela devrait aller, car <

dt << Select Where( Is Missing( As Column( col ) ), current selection( "clear" ) )

Re : Cellules de couleur

Salut Jarmo,

 

Où puis-je ajouter cette option ? désolé, je suis nouveau dans l'utilisation du logiciel JMP.

Re : Cellules de couleur

Ce que je voulais dire, c'est que si aucune ligne n'est sélectionnée, toutes les cellules de cette colonne seront colorées.

 

Dans ce cas, toutes les cellules de Age seront colorées car aucune ligne n'est sélectionnée.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
wait(1);

:Age << Color Cells("Red");
wait(1);

dt << Select Rows([2,4,6,20]);
:Name << Color Cells("Blue");
dt << Clear Select;

 

Re : Cellules de couleur

Oui, bon point.

Re : Cellules de couleur

Selon la façon dont cela sera utilisé, il existe peu d’options. L'option la plus simple et qui vous permettra d'y aller est d'ouvrir un nouveau fichier de script à partir du menu Fichier.

Copiez ensuite le script dans cette fenêtre qui s'ouvrira

Vérifiez que vous avez la bonne table dans la "barre d'outils" supérieure (cela devrait être le cas si elle était active pour la dernière fois lorsque vous avez ouvert le nouveau fichier de script).

Appuyez ensuite sur Exécuter le script dans la barre d'outils

 

Si cela doit être fait à plusieurs reprises, vous pouvez transformer ce script en élément de barre d'outils, complément, script de table, fichier de script... en fonction de l'utilisation.

 

Re : Cellules de couleur

Parfait! Merci pour votre aide. J'apprécie vraiment cela.