684974_zh-CN

liliconcom

优化列公式，将时间分辨数据标准化为 100% rel。在 t=0 时

我已收到我想讨论的公式大约3年前从@tx尼尔森，从那以后就再也没有放过它，并且之前多次思考过这个问题，慢慢地更加认真地对待脚本编写。 与此同时，公式救了我很多的时间。

在下面的示例中，相同的公式添加了 3 次，每次都有一点变化。 我想讨论的问题是复制和运行表的表脚本（包括新添加的公式列）时抛出的不同错误消息。

 

Names Default To Here( 1 );

// first, we need an example table
dt = New Table( "ExampleTable",
 Add Rows( 24 ),
 New Column( "BatchId",
  Character,
  "Nominal",
  Set Values(
   {"A", "A", "A", "A", "A", "A", "B", "B", "B", "C", "C", "C", "D", "D",
   "D", "E", "E", "E", "F", "F", "F", "G", "G", "G"}
  )
 ),
 New Column( "StorageCondition",
  Character,
  "Nominal",
  Set Values(
   {"25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "5°C", "5°C", "5°C",
   "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH",
   "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH",
   "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH", "25°C/60%RH",
   "25°C/60%RH", "25°C/60%RH", "25°C/60%RH"}
  )
 ),
 New Column( "Time",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [0, 1, 2, 0, 1, 2, 0, 1, 2, 0, 1, 2, 0, 1, 2, 0, 1, 2, 0, 1, 2, 0, 1, 2]
  )
 ),
 New Column( "QcParameter",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [0.2, 0.3, 0.4, 0.2, 0.21, 0.22, 0.3, 0.9, 1.2, ., 0.2, 0.4, 0.1, ., 0.1,
   0, 0, 0, 0.1, 0, 0, 0, 0.1, 0]
  )
 )
);


// adding formula column via approach nr. 1<BR />// this adds the formula alright, but when copying and executing the resulting table script will leave the formula column empty<BR />// no need to discuss this, because this obviously missing the 'eval(eval expr(expr()))' wrapping (see screenshot below)
dt << New Column( "QcParameter [% rel.]_1",
 numeric,
 formula(
  curBatch = :BatchId;
  curCondition = :StorageCondition;
  theRows = dt << get rows where(
   :BatchId == curBatch & :StorageCondition == curCondition & :Time == 0
  );
  d0Row = theRows[1];
  d0Time = :QcParameter[d0Row];
  (100 * :QcParameter / d0Time);
 )
);


// adding formula column via approach nr. 2<BR />// this will fill the formula column as desired when copying and running the table script with the added formula columns<BR />// but it will also throw an error message when new rows are added to the table then (see screenshot below)
Eval(
 Eval Expr(
  dt << New Column( "QcParameter [% rel.]_2",
   numeric,
   formula(
    curBatch = :BatchId;
    curCondition = :StorageCondition;
    theRows = Expr( dt ) << get rows where(
     :BatchId == curBatch & :StorageCondition == curCondition & :Time == 0
    );
    d0Row = theRows[1]; // removed from approach nr. 3
    d0Time = :QcParameter[d0Row];
    (100 * :QcParameter / d0Time);
   )
  )
 )
);


// adding formula column via approach nr. 3
// this will fill the formula column as desired when copying and running the table script with the added formula columns<BR />// and it will NOT throw an error message when new rows are added to the table then (see screenshot below)
Eval(
 Eval Expr(
  dt << New Column( "QcParameter [% rel.]_3",
   numeric,
   formula(
    curBatch = :BatchId;
    curCondition = :StorageCondition;
    theRows = Expr( dt ) << get rows where(
     :BatchId == curBatch & :StorageCondition == curCondition & :Time == 0
    );
    d0Time = :QcParameter[theRows];
    (100 * :QcParameter) / d0Time;
   )
  )
 )
);

 

使用其他公式列重新运行表脚本时公式列“QcParameter [%r rel.]_1]”的错误消息的屏幕截图：

 

重新运行具有附加公式列的表脚本时公式列“QcParameter [%r rel.]_2]”的错误消息的屏幕截图：

 

重新运行具有附加公式列的表脚本时公式列“QcParameter [%r rel.]_3]”的错误消息的屏幕截图：

 

我问这个冗长问题的原因是我假设在方法 nr 中使用变量“d0Row”肯定有某种原因。 2、不是吗？对于方法nr。 3 我只是删除了这个变量（见下面的屏幕截图），结果公式的表现“更好”，即，当通过点点击临时添加新行到数据表时，没有错误消息。

 

因此，我的问题是，我删除“d0Row”变量是否做错了什么。 在现实生活中，我正在使用更大的数据表，并且无法单独检查每一行的准确性。

自动化和脚本编写回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

我不完全确定我正在关注您的问题，但我看到的是，当您复制公式 1 时，您对 dt 的引用丢失了。在示例 2 和 3 中，最终数据表引用指向数据表“ExampleTable”，并且数据表名称（如图所示）为“Example Table 2”。再说一次，如果我理解你的问题，我认为你可以通过使用“Current Daa Table()”来解决问题。

curBatch = :BatchId;
curCondition = :StorageCondition;
theRows = Current Data Table() << get rows where(
 :BatchId == curBatch & :StorageCondition == curCondition & :Time == 0
);
d0Row = theRows[1];
d0Time = :QcParameter[d0Row];
If( Row() == 11,
 Show( therows, d0Time )
);
(100 * :QcParameter) / d0Time;

 

回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

谢谢！ 我再尝试总结一下：

1. 将三个公式列添加到之前没有公式列的示例表中，然后复制并执行现在包含三个公式列的表的结果表脚本时，只有示例 2 和 3 会使用预期的相对值填充相应的公式列。 第一个公式列保持为空。
2. 此外，当向在 1 下创建的最终表添加新行时。 （即来自现在包含所有 3 个公式列的表脚本），只有第三个示例在添加新的空行时不会抛出错误消息。

由于这一观察结果，我删除了示例 3 中的“d0Row”变量。 此后，向表中添加新行时不会出现错误消息，并且会按预期重现相关数据。 因此问题是“d0Row”是否是必需的。 我专门创建了示例 3 来检验这个假设。 （删除“d0Row”会使公式更短，但我担心这个变量是必不可少的，或者我忽略了一些东西。 我是吗？

 

我不确定这是否与公式中使用或不使用“当前数据表（）”有关。 我已经使用“当前数据表（）”作为解决方法很长时间了。 在向表中添加新行时，这仍然会导致错误消息，但我仍然希望能够向表中添加新行，而不必在添加新行时不断确认表中每个相关列的错误消息。 其中有数十个相关列，重复此操作需要时间。 当然可以抑制评估，但这也需要时间。 如果这个例子不清楚，我很抱歉，但我愿意进一步解释。）

回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

您应该能够使用 Try() 函数消除错误消息

Try(
 curBatch = :BatchId;
 curCondition = :StorageCondition;
 theRows = Current Data Table() << get rows where(
  :BatchId == curBatch & :StorageCondition == curCondition & :Time == 0
 );
 d0Row = theRows[1];
 d0Time = :QcParameter[d0Row];
 If( Row() == 11,
  Show( therows, d0Time )
 );
 (100 * :QcParameter) / d0Time;
);

回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

与这个问题不完全相关，但您可以使用一些 Col 函数魔法来“简化”公式。 这些建议应该有效，但您应该在替换旧的工作公式之前验证它们

dt << New Column("FormulaA", Numeric, Continuous, Formula(
 100 * :QcParameter / Col Sum(If(:Time == 0, :QcParameter, .),:BatchID, :StorageCondition) 
));

如果数据的排序方式使得时间 0 始终位于该组的第一位，则可以使其更容易理解（也许）

dt << New Column("FormulaB", Numeric, Continuous, Formula(
 100 * :QcParameter / QcParameter[Col Min(Row(), :BatchID, :StorageCondition)]
));

 

回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

这实际上与讨论完全相关。 讨论是关于消除错误消息的。 你的建议就是这样做的。 谢谢。 第二个目标是解释原始公式中“d0Row”变量的必要性。 这个问题还没有解决，但看起来确实没有必要。 当然，简单是可取的。

回复：优化列公式以将时间解析数据标准化为 100% rel。在 t=0 时

也许 d0Row 就在那里万一是否有多个地方每个组的时间都是 0？ 使用 d0Row 你只会采用其中的第一个（我的示例公式没有考虑到这一点（排序的事情有点考虑））。