684401_zh-CN

liliconcom

名称未解析：当我将其指定为列表中的值时，列名称将无法解析

我正在尝试计算数据表中每一列的 AUC。 我将所有列名称收集到列表“colNamesList”中，并通过增加列表下标来检索 For 循环内的 Fit Model 中的每个列名称。 但是，对数组的调用并未在“拟合模型”调用内解析。如果我在单独的行上包含 show(colNamesList[i]) ，它可以很好地解析，只是不在 Fit Model 调用中。 我正在使用本论坛上一篇文章中的脚本，我怀疑我的旧版本 JMP（版本 9.0.0）只需要稍微不同的语法。 任何想法，将不胜感激。

 

Names Default To Here( 1 );

// Open and example data table
dt = Open( "sample.jmp" );

// Get the columns to be analyzed
colNamesList = dt << get column names( string );

// Create a data table to save the results to
dtOutput = New Table( "Results", New Column( "var_name", character ), New Column( "AUC", character ) );

// Loop across all of the columns to be analyzed and retrieve the AUC
For( i = 1, i <= N Items( colNamesList ), i++,
 // Add a new row to the output data table
 dtOutput << Add Rows( 1 );
 // Add the active variable name to the current row in the data table
 dtOutput:var_name[i] = colNamesList[i];
 // Run the Logistic Regression
 theLog = dt << Fit Model(invisible, Y( :case ),Effects( column (colNameList[i]) ),Personality( Nominal Logistic ),Run(Positive Level( "1" ),Likelihood Ratio Tests( 1 ),ROC Curve( 1 ),));
 // Add the AUC to the data table by grabbing it from the display report output
 dtOutput:AUC = (Report( theLog )["Receiver Operating Characteristic"][numberbox(1)] << get text);
 // Close the report window
 Report( theLog ) << close window;
);

日志中的错误如下：

Name Unresolved: colNameList{1}

 in access or evaluation of 'colNameList' , colNameList

Exception in platform launch{1}

 in access or evaluation of 'Fit Model' , Fit Model(
 invisible,
 Y( :case ),
 Effects( Column( colNameList[i] ) ),
 Personality( Nominal Logistic ),
 Run( Positive Level( "1" ), Likelihood Ratio Tests( 1 ), ROC Curve( 1 ) )
)

In the following script, error marked by /*###*/
Fit Model(
 invisible,
 Y( :case ),
 Effects( Column( colNameList/*###*/[i] ) ),
 Personality( Nominal Logistic ),
 Run( Positive Level( "1" ), Likelihood Ratio Tests( 1 ), ROC Curve( 1 ) )
)
Cannot subscript Display Box{1}

 in access or evaluation of 'Subscript' , Report( theLog )["Receiver Operating Characteristic"]

In the following script, error marked by /*###*/
Names Default To Here( 1 );
dt = Open( "sample.jmp" );
colNamesList = dt << get column names( string );
dtOutput = New Table( "Results",
 New Column( "var_name", character ),
 New Column( "AUC", character )
);
For( i = 1, i <= N Items( colNamesList ), i++,
 dtOutput << Add Rows( 1 );
 dtOutput:var_name[i] = colNamesList[i];
 theLog = dt << Fit Model(/*###*/invisible,
  Y( :case ),
  Effects( Column( colNameList[i] ) ),
  Personality( Nominal Logistic ),
  Run( Positive Level( "1" ), Likelihood Ratio Tests( 1 ), ROC Curve( 1 ) )
 );
 dtOutput:AUC = Report( theLog )[/*###*/"Receiver Operating Characteristic"][
 numberbox( 1 )] << get text;
 Report( theLog ) << close window;
);

自动化和脚本编写视窗回复：名称未解析：当我将其指定为列表中的值时，列名称将无法解析

1. 名称未解析的原因是您调用了列表 colNamesList，并将其引用为 colNameLise。
2. AUC值需要放置在定义的行，因此需要将下标添加到dtOutput:AUC

Names Default To Here( 1 );

// Open and example data table
dt = Open( "sample.jmp" );

// Get the columns to be analyzed
colNamesList = dt << get column names( string );

// Create a data table to save the results to
dtOutput = New Table( "Results", New Column( "var_name", character ), New Column( "AUC", character ) );

// Loop across all of the columns to be analyzed and retrieve the AUC
For( i = 1, i <= N Items( colNamesList ), i++, 
 // Add a new row to the output data table
 dtOutput << Add Rows( 1 );
 // Add the active variable name to the current row in the data table
 dtOutput:var_name[i] = colNamesList[i];
 // Run the Logistic Regression
 theLog = dt << Fit Model(
  invisible,
  Y( :case ),
  Effects( Column( colNamesList[i] ) ),
  Personality( Nominal Logistic ),
  Run( Positive Level( "1" ), Likelihood Ratio Tests( 1 ), ROC Curve( 1 ) )
 );
 
 // Add the AUC to the data table by grabbing it from the display report output
 dtOutput:AUC[i] = (Report( theLog )["Receiver Operating Characteristic"][numberbox( 1 )] << get text);
 // Close the report window
 Report( theLog ) << close window;
);

回复：名称未解析：当我将其指定为列表中的值时，列名称将无法解析

是的，这是一个错字，修复它是解决方案的一部分，所以感谢您看到这一点。 我仍然收到“无法找到列{1}”错误，并通过在指定列时引用数据表来解决该问题：Column(dt, colNamesList[i]) 而不是 Column(colNamesList[i])。 然后我收到错误“响应也不应该是一个因素，^1case”，因此我添加了一个 IF 语句来忽略响应列。无论我是否将下标添加到 AUC，都会运行。

 

这是我的第一个 jsl 脚本。 真是一次学习经历。 感谢 txnelson 的帮助！

 

Names Default To Here( 1 );

// Open and example data table
dt = Open( "sample.jmp" );

// Get the columns to be analyzed
colNamesList = dt << get column names( string );

// Create a data table to save the results to
dtOutput = New Table( "Results", New Column( "var_name", character ), New Column( "AUC", character ) );

// Loop across all of the columns to be analyzed and retrieve the AUC
For( i = 1, i <= N Items( colNamesList ), i++,
 // Add a new row to the output data table
 dtOutput << Add Rows( 1 );
 // Add the active variable name to the current row in the data table
 dtOutput:var_name[i] = colNamesList[i];
 //Get the next column name
 colName = colNamesList[i];
 // If the column is "case", leave AUC blank, otherwise run the Logistic Regression
 if(colName=="case", AUC=.,
  theLog = dt << Fit Model(
   invisible,
   Y(:case),
   Effects(column(dt,colName)),
   Personality( Nominal Logistic ),
   Run(
    Positive Level( "1" ),
    Likelihood Ratio Tests( 1 ),
    ROC Curve( 1 ),
    )
   );
  // Add the AUC to the data table by grabbing it from the display report output
  dtOutput:AUC[i] = (Report( theLog )["Receiver Operating Characteristic"][numberbox(1)] << get text);
 );
 // Close the report window
 Report( theLog ) << close window;
);

回复：名称未解析：当我将其指定为列表中的值时，列名称将无法解析

做得好！

 

您可以通过将该行更改为来避免错误响应

try(Report( theLog ) << close window);

您还可以通过删除单个语句的重复赋值来缩短 JSL 并使 JSL 运行更高效

colName = dtOutput:var_name[i] = colNamesList[i];