684353_de-DE

liliconcom

Gruppe anpassen und Y an X anpassen

Hallo! Ich versuche, ein Skript für eine Analyse zu erstellen, bei der der Benutzer eine Datentabelle eingibt und das Skript eine Anpassung von Y durch nominale Variablen) als X-Auswahlen. Gibt es eine Möglichkeit, „Anpassung Y nach

 

Dies ist ein von mir geschriebenes Skript, das sie alle in einem Feld ausgibt, aber ich möchte, dass der Benutzer die signifikanten Anpassungen anhand der ANOVA leicht finden kann. Idealerweise würde ich gerne signifikante Anpassungen in einem tabellarischen Berichtsfenster ausgeben, aber das übersteigt derzeit meinen Wissensstand. Jede Hilfe wäre dankbar!

Names Default To Here( 1 );
dt = Current Data Table();
dlg = Column Dialog(
 iv = ColList( "Depedent Variable",
  Min Col( 1 ),
  Max Col( 1 ),
  Data Type( "Numeric" )
 )
);
If( dlg["Button"] != 1,
 Beep();
 Throw();
);
iv = dlg["iv"];
n_cols = N Cols( dt );
New Window( "Report",
 H List Box(
  For( c = 1, c <= n_cols, c++,
   Fit Y by X(
    Y( Column( iv[1] ) ),
    X( Column( c ) ),
    Fit Line( 1 ),
    Anova( 1 )
   )
  )
 )
);

 

Automatisierung und SkripterstellungWindowsBetreff: Gruppe anpassen und Y an X anpassen

Das folgende Skript führt die Anpassung von Y nach X aus und gibt dann die Tabelle „Zusammenfassung der Anpassung“ für alle Analysen aus.Ich hoffe, das ist, was Sie wollen.

Names Default To Here( 1 );
dt = Current Data Table();
dlg = Column Dialog(
 iv = ColList( "Depedent Variable",
  Min Col( 1 ),
  Max Col( 1 ),
  Data Type( "Numeric" )//,
  //modeling type(ordinal,nominal)
 )
);
If( dlg["Button"] != 1,
 Beep();
 Throw();
);
iv = Char( dlg["iv"][1] );

// Get the names of all of the columns in the data table
colNameList = dt << get column names( string );
// Remove the Dependent Column from the list
Remove From( colNameList, Contains( colNameList, iv ), 1 );


ft = Fit Y by X(
 Y( Column( iv ) ),
 X( Eval( colNameList ) ),
 Fit Line( 1 ),
 Anova( 1 )
);
(ft << report)[1]["Summary of Fit", Table Box( 1 )] << make combined data table;

Hier ein paar Anmerkungen:

1. Wenn Sie JSL veröffentlichen, verwenden Sie bitte das JSL-Symbol, um das JSL-Fenster zu öffnen und den Code in dieses Fenster zu kopieren.Dies ermöglicht eine übersichtlichere Anzeige des Eintrags.
2. Sie müssen sich die Zeit nehmen, das Skripthandbuch zu lesen, das in der JMP-Dokumentationsbibliothek im Pulldown-Menü „Hilfe“ verfügbar ist.
3. Die Column Dialog()-Struktur wurde veraltet.Sie müssen dazu übergehen, ein neues Fenster mit einer Col List Box() zu verwenden.

Betreff: Gruppe anpassen und Y an X anpassen

Vielen Dank!