684024_zh-CN

liliconcom

用于重命名来自列联表选项的表的脚本：制作为数据表

大家好，

 

我编写了一个代码来获取带有列联表工具信息的数据表，不幸的是，发出的表名为“Untitled xxx”。 我想知道通过编写脚本是否可以选择最后创建的表并更改其名称，或者选择名称中包含 Untitled 的表，最后重命名它？

 

目标是在脚本每次启动时关闭表以避免拥有多个表。

 

我尝试使用当前数据表（）函数，但它无法正常工作（选择了另一个表）。

 

代码部分：

Contingency(
 Y( :"Pass/Fail"n ),
 X( :Task ),
 Contingency Table(
  Count( 1, Format( "Fixed Dec", 2, 0 ) ),
  Total %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Col %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Row %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Expected( 0, Format( "Best", 3 ) ),
  Deviation( 0, Format( "Best", 3 ) ),
  Cell Chi Square( 0, Format( "Fixed Dec", 2, 4 ) ),
  Col cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Col cumulative %( 0, Format( "Fixed Dec", 2, 2 ) ),
  Row cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Row cumulative %( 0, Format( "Fixed Dec", 2, 2 ) )
 ),
 Mosaic Plot( 0 ),
 Make Into Data Table,
);

谢谢 ！

 

此致

自动化和脚本编写回复：重命名来自列联表选项的表的脚本：制作成数据表

我不确定您是否可以在该命令中执行此操作，但我认为您可以将“Make Into Data Table”消息发送到 CrossTabBox

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
cont = dt << Contingency(
 Y(:Age),
 X(:sex),
 Contingency Table()
);

dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;

为此你可以获得参考

回复：重命名来自列联表选项的表的脚本：制作成数据表

嗨，jthi，

 

感谢您的及时答复。 但是，即使我添加：

 

dt_cont << Data Table(Name("Contingency Table"))

我得到了相同的结果，新的数据表被命名为“Untitled XXX”（没有代码错误）。

 

此致

回复：重命名来自列联表选项的表的脚本：制作成数据表

代码的工作原理如下：

 

dt_cont << Set Name("Contingency Table");

谢谢 ！

回复：重命名来自列联表选项的表的脚本：制作成数据表

你需要使用

dt_cont << set Name("Contingency Table")

回复：重命名来自列联表选项的表的脚本：制作成数据表

大家好，

 

我想升级我的代码，当我生成应急分析时，现在我有两个分析，一个名为“1”，第二个名为“2”，我想以相同的方式在最后获取两个数据表。

 

我尝试将代码更改如下：

dt << Contingency(
    Y( :"Pass/Fail"n ),
    X( :Task ),
    By( :X ),
);

dt_cont1 = Report("Contingency Analysis of Pass/Fail By Task X=1")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont1 << Set Name("Contingency Table 1");


dt_cont2 = Report("Contingency Analysis of Pass/Fail By TaskX=2")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont2 << Set Name("Contingency Table 2");

但它不起作用，我也没有找到解决方案。

 

先感谢您 ！

 

此致

回复：重命名来自列联表选项的表的脚本：制作成数据表

错误消息是：

 

“在访问或评估“报告（“任务 X = 1 的通过/失败的应急分析”）时，第 XXX 行的对象不可订阅[/*###*/Outline Box(“应急表”)]', Report( “任务 X=1 的通过/失败的应急分析”)[/*###*/Outline Box("应急表")]

回复：重命名来自列联表选项的表的脚本：制作成数据表

很少有不同的选择可以做到这一点。 这是一个使用循环来查看使用“按列”时从应急平台获得的不同参考

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
conts = dt << Contingency(
 Y(:height),
 X(:age),
 By(:sex)
);

Show(conts); // two references

dt_conts = {};

For Each({cont, idx}, conts,
 dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;
 groupname = Word(-1, Report(cont)[OutlineBox(1)] << get title, "=");
 dt_cont << Set Name("Contingency Table " || groupname);
 Insert Into(dt_conts, dt_cont);
);

回复：重命名来自列联表选项的表的脚本：制作成数据表

哇啊啊jthi，谢谢你！

虽然很复杂^^'但是也很有效:)

太感谢了 ！