684024_fr-FR

liliconcom

Script pour renommer une table issue de l'option Table de Contingence : Make Into Data Table

Salut tout le monde,

 

J'ai créé un code pour obtenir un tableau de données avec des informations sur l'outil de tableau de contingence, malheureusement, le tableau émis s'appelle "Sans titre xxx". J'aimerais savoir si par script il sera possible soit de sélectionner la dernière table créée et de changer son nom, soit de sélectionner la table contenant Sans titre dans son nom, de la renommer à la fin ?

 

L'objectif est de fermer la table à chaque lancement du script pour éviter d'avoir plusieurs tables.

 

J'ai essayé d'utiliser la fonction Current Data Table() mais elle ne fonctionne pas correctement (une autre table est sélectionnée).

 

La partie code :

Contingency(
 Y( :"Pass/Fail"n ),
 X( :Task ),
 Contingency Table(
  Count( 1, Format( "Fixed Dec", 2, 0 ) ),
  Total %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Col %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Row %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Expected( 0, Format( "Best", 3 ) ),
  Deviation( 0, Format( "Best", 3 ) ),
  Cell Chi Square( 0, Format( "Fixed Dec", 2, 4 ) ),
  Col cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Col cumulative %( 0, Format( "Fixed Dec", 2, 2 ) ),
  Row cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Row cumulative %( 0, Format( "Fixed Dec", 2, 2 ) )
 ),
 Mosaic Plot( 0 ),
 Make Into Data Table,
);

Merci !

 

Cordialement

Automatisation et scriptsRe: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Je ne sais pas si vous pouvez le faire avec cette seule commande, mais je pense que vous pouvez envoyer le message Make Into Data Table à CrossTabBox.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
cont = dt << Contingency(
 Y(:Age),
 X(:sex),
 Contingency Table()
);

dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;

et pour cela tu peux avoir la référence

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Salut Jthi,

 

Merci pour votre réponse rapide. Cependant, même si j'ajoute :

 

dt_cont << Data Table(Name("Contingency Table"))

J'obtiens le même résultat, la nouvelle table de données est nommée "Untitled XXX" (sans erreur de code).

 

Cordialement

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Le code fonctionne comme suit :

 

dt_cont << Set Name("Contingency Table");

Merci !

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Vous devez utiliser

dt_cont << set Name("Contingency Table")

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Salut tout le monde,

 

Je voudrais mettre à jour mon code, lorsque je génère l'analyse de contingence, maintenant j'ai deux analyses une nommée "1" et la seconde "2", je voudrais faire de la même manière pour obtenir deux tableaux de données à la fin.

 

J'ai essayé de changer le code comme suit :

dt << Contingency(
    Y( :"Pass/Fail"n ),
    X( :Task ),
    By( :X ),
);

dt_cont1 = Report("Contingency Analysis of Pass/Fail By Task X=1")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont1 << Set Name("Contingency Table 1");


dt_cont2 = Report("Contingency Analysis of Pass/Fail By TaskX=2")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont2 << Set Name("Contingency Table 2");

Mais cela n'a pas fonctionné et je ne trouve pas la solution.

 

Merci d'avance !

 

Cordialement

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Le message d'erreur est :

 

"objet non inscriptible à la ligne XXX lors de l'accès ou de l'évaluation du 'Rapport("Analyse de contingence de réussite/échec par tâche X=1")[/*###*/Outline Box("Tableau de contingence")]', Rapport( "Analyse de contingence de réussite/échec par tâche X=1")[/*###*/Outline Box("Tableau de contingence")]

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Peu d'options différentes pour faire cela. En voici une utilisant une boucle pour passer en revue les différentes références que vous obtenez de la plateforme de contingence lorsque vous utilisez la colonne Par

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
conts = dt << Contingency(
 Y(:height),
 X(:age),
 By(:sex)
);

Show(conts); // two references

dt_conts = {};

For Each({cont, idx}, conts,
 dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;
 groupname = Word(-1, Report(cont)[OutlineBox(1)] << get title, "=");
 dt_cont << Set Name("Contingency Table " || groupname);
 Insert Into(dt_conts, dt_cont);
);

Re: Script pour renommer une table venant de l'option Table de contingence : Make Into Data Table

Waaaaah jthi, merci !

C'est très compliqué ^^' mais ça marche aussi

Merci beaucoup !