684024_de-DE

liliconcom

Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Hallo zusammen,

 

Ich habe einen Code erstellt, um eine Datentabelle mit Informationen zum Kontingenztabellen-Tool zu erhalten. Leider heißt die ausgegebene Tabelle „Untitled xxx“. Ich würde gerne wissen, ob es per Skript möglich sein wird, entweder die zuletzt erstellte Tabelle auszuwählen und ihren Namen zu ändern, oder die Tabelle auszuwählen, deren Name „Unbenannt“ enthält, um sie am Ende umzubenennen?

 

Das Ziel besteht darin, die Tabelle bei jedem Start des Skripts zu schließen, um zu vermeiden, dass mehrere Tabellen vorhanden sind.

 

Ich habe versucht, die Funktion „Aktuelle Datentabelle ()“ zu verwenden, aber sie funktioniert nicht richtig (eine andere Tabelle ist ausgewählt).

 

Der Codeabschnitt:

Contingency(
 Y( :"Pass/Fail"n ),
 X( :Task ),
 Contingency Table(
  Count( 1, Format( "Fixed Dec", 2, 0 ) ),
  Total %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Col %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Row %( 1, Format( "Fixed Dec", 2, 2 ) ),
  Expected( 0, Format( "Best", 3 ) ),
  Deviation( 0, Format( "Best", 3 ) ),
  Cell Chi Square( 0, Format( "Fixed Dec", 2, 4 ) ),
  Col cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Col cumulative %( 0, Format( "Fixed Dec", 2, 2 ) ),
  Row cumulative( 0, Format( "Fixed Dec", 2, 0 ) ),
  Row cumulative %( 0, Format( "Fixed Dec", 2, 2 ) )
 ),
 Mosaic Plot( 0 ),
 Make Into Data Table,
);

Danke !

 

Beste grüße

Automatisierung und SkripterstellungBetreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Ich bin mir nicht sicher, ob Sie dies mit nur diesem einen Befehl tun können, aber ich denke, Sie können die Nachricht „Make Into Data Table“ an die CrossTabBox senden

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
cont = dt << Contingency(
 Y(:Age),
 X(:sex),
 Contingency Table()
);

dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;

und dafür können Sie die Referenz erhalten

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Hallo jthi,

 

Danke für deine schnelle Antwort. Aber selbst wenn ich hinzufüge:

 

dt_cont << Data Table(Name("Contingency Table"))

Ich erhalte das gleiche Ergebnis, die neue Datentabelle heißt „Untitled XXX“ (ohne Codefehler).

 

Beste grüße

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Der Code funktioniert wie folgt:

 

dt_cont << Set Name("Contingency Table");

Danke !

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Sie müssen verwenden

dt_cont << set Name("Contingency Table")

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Hallo zusammen,

 

Ich möchte meinen Code aktualisieren, wenn ich die Kontingenzanalyse erstelle. Jetzt habe ich zwei Analysen, eine mit dem Namen „1“ und die zweite mit „2“. Ich möchte auf die gleiche Weise vorgehen, um am Ende zwei Datentabellen zu erhalten.

 

Ich habe versucht, den Code wie folgt zu ändern:

dt << Contingency(
    Y( :"Pass/Fail"n ),
    X( :Task ),
    By( :X ),
);

dt_cont1 = Report("Contingency Analysis of Pass/Fail By Task X=1")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont1 << Set Name("Contingency Table 1");


dt_cont2 = Report("Contingency Analysis of Pass/Fail By TaskX=2")[OutlineBox("Contingency Table")][CrossTabBox(1)] << Make Into Data Table;
dt_cont2 << Set Name("Contingency Table 2");

Aber es hat nicht funktioniert und ich finde die Lösung nicht.

 

Vielen Dank im Voraus !

 

Beste grüße

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Die Fehlermeldung lautet:

 

„Objekt kann in Zeile „Kontingenzanalyse von Pass/Fail durch Aufgabe X=1“)[/*###*/Outline Box(“Kontingenztabelle“)]

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Dafür gibt es nur wenige verschiedene Möglichkeiten. Hier ist eine Verwendungsschleife, um verschiedene Referenzen durchzugehen, die Sie von der Contingency-Plattform erhalten, wenn Sie die Spalte „By“ verwenden

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
conts = dt << Contingency(
 Y(:height),
 X(:age),
 By(:sex)
);

Show(conts); // two references

dt_conts = {};

For Each({cont, idx}, conts,
 dt_cont = Report(cont)[OutlineBox("Contingency Table"), CrossTabBox(1)] << Make Into Data Table;
 groupname = Word(-1, Report(cont)[OutlineBox(1)] << get title, "=");
 dt_cont << Set Name("Contingency Table " || groupname);
 Insert Into(dt_conts, dt_cont);
);

Betreff: Skript zum Umbenennen einer Tabelle aus der Option „Kontingenztabelle“: „In Datentabelle umwandeln“.

Waaaaah jthi, danke!

Es ist sehr kompliziert ^^', aber es funktioniert genauso

Vielen Dank !