477249_es-ES

liliconcom

Capacidad en Graph Builder

Me han hecho esta pregunta varias veces, pero ¿hay alguna manera de mostrar el análisis de capacidad en Graph Builder? Encontré dónde puede mostrar un resumen de 5 números, pero no puedo averiguar cómo hacer que muestre la capacidad. ¿Incluso tiene Cpk o Ppk como opción para mostrar? Parece que no puedo encontrar esto, ¿es posible?

 

Estoy usando JMP Pro 16.0.

Ingeniería de Calidad y ProcesosRe: Capacidad en Graph Builder

Probé varias técnicas y fallé en todas.Luego volví a un método que he usado varias veces.Básicamente, la pantalla se organiza como se desea y luego se convierte en un objeto de imagen y ese objeto se agrega a un cuadro de salida() en una nueva ventana.Debido a que el objeto de imagen es un solo objeto, se muestra en una diapositiva.

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 gb = Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);

nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
 Lineup Box( N Col( 1 ),
  Spacer Box( size( 1, 15 ) ),
  txb = Text Box( "Within Sigma Capability" ),
  tb = Table Box()
 )
);
txb << set font style( "Bold" );
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
  )
 )
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );

Re: Capacidad en Graph Builder

Gracias Jim. Lamentablemente no funciona según lo previsto. Todavía escupe dos ventanas. La diferencia ahora es que hay una línea en la parte inferior con el título del generador de gráficos. Tiene alguna recomendación? gracias.

Re: Capacidad en Graph Builder

Cuando guarda en un .ppt, JMP crea automáticamente una diapositiva separada para los 2 cuadros de esquema, "Creador de gráficos" y "Dentro de la capacidad de Sigma".

Creo que puedes agrupar los 2 en un nuevo cuadro de Esquema.No lo he probado, pero vale la pena intentarlo.

Cambie la línea Nueva ventana a

nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );

Re: Capacidad en Graph Builder

Hola,

Estoy intentando tener el cpk y el GB en la misma ventana y la forma que usted proporcionó hace exactamente eso. El problema es que cuando intento exportarlo a ppt, imprime el cpk y el GB en dos diapositivas diferentes. ¿Conocerías una manera de hacer que ambos estén en la misma diapositiva? Gracias.

Re: Capacidad en Graph Builder

Pocas opciones a continuación

• Puede utilizar la herramienta de selección y luego copiarla y pegarla en Powerpoint.
• puedes hacer clic derecho y usar Copiar gráfico
• Puedes usar el menú Archivo y guardarlo como Powerpoint.

Re: Capacidad en Graph Builder

Hola,

¿Hay alguna manera de importar esto a PowerPoint? Me gustaría tener un generador de gráficos y un cpk y luego importarlo a ppt. Gracias.

Re: Capacidad en Graph Builder

¡Gracias! Intentaré esto.

Re: Capacidad en Graph Builder

Aquí hay 2 formas diferentes de agregar la capacidad al Graph Builder

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
hlb << append(
 Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   Number Col Box( 1 )] << get
  )
 )
);

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
gb = Graph Builder(
 Size( 528, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :NPN1 ) ),
 Elements( Histogram( X, Legend( 7 ) ) )
);


textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);

Report( gb )[framebox( 1 )] <<
add graphics script(
 Text( Center Justified, {120, 275}, textlist[1] );
 Text(
  Center Justified,
  {122, 275},
  Format( statlist[1], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 265}, textlist[2] );
 Text(
  Center Justified,
  {122, 265},
  Format( statlist[2], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 255}, textlist[3] );
 Text(
  Center Justified,
  {122, 255},
  Format( statlist[3], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 245}, textlist[4] );
 Text(
  Center Justified,
  {122, 245},
  Format( statlist[4], "Fixed Dec", 4, 2 )
 );
);