この質問を何度も受けましたが、グラフ ビルダーで工程能力分析を表示する方法はありますか? 5 つの数字の概要を表示できる場所は見つかりましたが、機能を表示する方法はどこにも見つかりません。 Cpk または Ppk を表示するオプションもありますか? 見つからないようですが、可能でしょうか？
JMP Pro 16.0を使用しています。
いくつかのテクニックを試しましたが、すべて失敗しました。その後、私が何度か使用した方法に戻りました。基本的に、表示は必要に応じて編成され、画像オブジェクトに作成され、そのオブジェクトが新しいウィンドウの出力 box() に追加されます。画像オブジェクトは単一のオブジェクトであるため、1 つのスライドに表示されます
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
Lineup Box( N Col( 1 ),
Spacer Box( size( 1, 15 ) ),
txb = Text Box( "Within Sigma Capability" ),
tb = Table Box()
)
);
txb << set font style( "Bold" );
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
)
)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );
ありがとう、ジム。 残念ながら、意図したとおりに機能しません。 それでも 2 つのウィンドウが吐き出されます。 違いは、下部にグラフ ビルダーのタイトルを含む行があることです。 何かお勧めはありますか？ありがとう。
.ppt に保存すると、JMP は 2 つのアウトライン ボックス、「グラフ ビルダー」と「シグマ機能内」用に別のスライドを自動的に作成します。
新しいアウトラインボックスの下に 2 つをグループ化できると思います。私はこれをテストしていませんが、試してみる価値はあります。
新しいウィンドウの行を次のように変更します。
nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );
こんにちは、
cpkとGBを同じウィンドウに表示しようとしていますが、あなたが提供した方法はまさにそれを行います。 問題は、それを ppt にエクスポートしようとすると、cpk と GBin の 2 つの異なるスライドが印刷されてしまうことです。 両方を同じスライド内に作成する方法をご存知ですか? ありがとう。
こんにちは、
これをパワーポイントにインポートする方法はありますか？ グラフビルダーとcpkを用意して、それをpptにインポートしたいと考えています。 ありがとう。
グラフ ビルダーに機能を追加する 2 つの異なる方法を次に示します。
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
hlb << append(
Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
Number Col Box( 1 )] << get
)
)
);
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
);
textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);
Report( gb )[framebox( 1 )] <<
add graphics script(
Text( Center Justified, {120, 275}, textlist[1] );
Text(
Center Justified,
{122, 275},
Format( statlist[1], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 265}, textlist[2] );
Text(
Center Justified,
{122, 265},
Format( statlist[2], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 255}, textlist[3] );
Text(
Center Justified,
{122, 255},
Format( statlist[3], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 245}, textlist[4] );
Text(
Center Justified,
{122, 245},
Format( statlist[4], "Fixed Dec", 4, 2 )
);
);
ジムさん、本当にありがとうございました！私はあなたの助けに感謝します。 通知がオフになっているので、今返信を見ました。
試してみて、どうなるかをお知らせします。
