477249_it-IT

liliconcom

Funzionalità nel Costruttore di grafici

Mi è stata posta questa domanda più volte, ma esiste un modo per mostrare l'analisi delle capacità nel Costruttore di grafici? Ho trovato dove può mostrare un riepilogo di 5 numeri, ma non dove posso capire come farlo mostrare la capacità. Hai anche Cpk o Ppk come opzione da mostrare? Non riesco a trovarlo, è possibile?

 

Sto utilizzando JMP Pro 16.0.

Ingegneria della qualità e dei processiRi: Funzionalità nel Costruttore di grafici

Ho provato diverse tecniche e ho fallito con tutte.Sono quindi tornato ad un metodo che ho utilizzato più volte.Fondamentalmente la visualizzazione è organizzata come desiderato, quindi viene trasformata in un oggetto immagine e tale oggetto viene aggiunto a un output box() in una nuova finestra.Poiché l'oggetto immagine è un oggetto singolo, viene visualizzato su una diapositiva

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 gb = Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);

nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
 Lineup Box( N Col( 1 ),
  Spacer Box( size( 1, 15 ) ),
  txb = Text Box( "Within Sigma Capability" ),
  tb = Table Box()
 )
);
txb << set font style( "Bold" );
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
  )
 )
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );

Ri: Funzionalità nel Costruttore di grafici

Grazie Jim. Sfortunatamente non funziona come previsto. Sputa ancora da due finestre. La differenza ora è che c'è una linea in basso con il titolo del generatore di grafici. Avete consigli? Grazie.

Ri: Funzionalità nel Costruttore di grafici

Quando si salva in un file .ppt, JMP crea automaticamente una diapositiva separata per le due caselle di struttura, "Graph Builder" e "Within Sigma Capability".

Penso che tu possa raggruppare i 2 insieme in una nuova casella Contorno.Non l'ho testato, ma vale la pena provarlo.

Cambia la riga Nuova finestra in

nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );

Ri: Funzionalità nel Costruttore di grafici

CIAO,

Sto cercando di avere il cpk e il GB sulla stessa finestra e il modo che hai fornito fa esattamente questo. Il problema è che quando provo ad esportarlo in ppt, stampa il cpk e il GB in due diapositive diverse. Conosceresti un modo per realizzarli entrambi nella stessa diapositiva? Grazie.

Ri: Funzionalità nel Costruttore di grafici

Alcune opzioni di seguito

• È possibile utilizzare lo strumento di selezione e quindi copiarlo e incollarlo in Powerpoint
• puoi fare clic con il tasto destro e utilizzare Copia grafico
• È possibile utilizzare il menu File e salvarlo come PowerPoint

Ri: Funzionalità nel Costruttore di grafici

CIAO,

c'è un modo per importarlo in Power Point? Mi piacerebbe avere un generatore di grafici e un cpk e poi importarlo in ppt. Grazie.

Ri: Funzionalità nel Costruttore di grafici

Grazie! Lo proverò.

Ri: Funzionalità nel Costruttore di grafici

Ecco 2 modi diversi per aggiungere la funzionalità al Costruttore di grafici

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
hlb << append(
 Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   Number Col Box( 1 )] << get
  )
 )
);

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
gb = Graph Builder(
 Size( 528, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :NPN1 ) ),
 Elements( Histogram( X, Legend( 7 ) ) )
);


textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);

Report( gb )[framebox( 1 )] <<
add graphics script(
 Text( Center Justified, {120, 275}, textlist[1] );
 Text(
  Center Justified,
  {122, 275},
  Format( statlist[1], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 265}, textlist[2] );
 Text(
  Center Justified,
  {122, 265},
  Format( statlist[2], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 255}, textlist[3] );
 Text(
  Center Justified,
  {122, 255},
  Format( statlist[3], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 245}, textlist[4] );
 Text(
  Center Justified,
  {122, 245},
  Format( statlist[4], "Fixed Dec", 4, 2 )
 );
);