683642_de-DE

liliconcom

So schleifen Sie tabellarische Tabellen und Bilder in PPT-Folien ein

Hallo, ich stecke irgendwie fest und habe Probleme mit der JMP-Schleife. Wie kann ich eine tabellarische Tabelle, die aus meinen Teilmengentabellen stammt, in einer Schleife ausführen? Die Anzahl der Tabellen kann sich ändern, daher dachte ich, dass ich eine Schleife machen muss (aber ich habe Schwierigkeiten). Außerdem muss ich diese Bilder an Powerpoint-Folien anhängen. Ich habe keine Ahnung, wie ich den Variablennamen in einer Schleife erhalten und an die Folien anhängen kann.

 

Hier ist mein Beispielskript, das jedoch keine Schleife enthält. Ist es möglich?

 

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

:Sex << Set Name( "Sex_Subset" );
dt << New Column( "Sex", Formula(:Sex_Subset));

dt1 = dt << Subset( By( :Sex_Subset ), All rows, Selected columns only( 0 ) );

//this is where to loop tabulated tables since column values used in subsetting dt may change number of values
 
//how to loop this according to data table name? is that possible?
dt_Tab = Tabulate(
 Add Table(
  Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
  Row Table( Grouping Columns( :name, :age ) )
 )
);

tab = dt_Tab << get picture; //variable name needs to be looped? for ppt slides


//after getting the plot as image, how can I append those images that were loop to ppt slides?

//for male table
hbppt1 = H List Box(tab) << get picture;
ppt1 = Outline Box( "Male", hbppt1 );
ppt1 << savepresentation( pathppt, append, PNG );

//for female table
hbppt2 = H List Box(tab2) << get picture;
ppt2 = Outline Box( "Female", hbppt2 );
ppt2 << savepresentation( pathppt, append, PNG );

Tabellen aus Teilmenge

 

Automatisierung und SkripterstellungBetreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Wenn Sie Subset mit By verwenden, erhalten Sie eine Liste von Tabellen, die Sie dann durchlaufen können

dt1 = {DataTable("Sex_Subset=F"), DataTable("Sex_Subset=M")};

 

Bearbeiten:

Überprüfen Sie den Skriptindex für die von Ihnen verwendeten Funktionen und Nachrichten. Einige davon sind falsch

Names Default To Here(1);

pathppt = "$TEMP/bigclass.pptx";

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "Sex") << Set Name("Sex_Subset");
dt << New Column("Sex", Formula(:Sex_Subset));

dt_subsets = dt << Subset(By(:Sex_Subset), All rows, Selected columns only(0));

For Each({dt_subset}, dt_subsets,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );

 tab_pic = subset_tab << get picture; 
 subset_tab << Close Window;
 name_dt = dt_subset << get name;
 Close(, no save);
 hbppt = H List Box(tab_pic) << get picture;
 ppt = Outline Box(name_dt, hbppt);
 If(!File Exists(pathppt), 
  ppt << savepresentation(pathppt);
 , // append only if file already exists
  ppt << savepresentation(pathppt, append);
 );
);
 
Open(pathppt);

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Hier ist eine Überarbeitung Ihres Skripts, das die Folien erstellt

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// Specify the path to save the pptx's to
pathPPT = "$TEMP/UserID16644Slides.pptx";

:Sex << Set Name( "Sex_Subset" );
dt << New Column( "Sex", Formula( :Sex_Subset ) );

// Add value labels so the full value can be used for the slide title
dt:Sex_Subset << Value Labels( {"F" = "Female", "M" = "Male"} ) << Use Value Labels( 1 );

// Subset the tables.  The dataTableList will contain a reference to each table created
dataTableList = dt << Subset( By( :Sex_Subset ), All rows, Selected columns only( 0 ) );

// Loop across all of the tables and create the Tabulates
For Each( {table, i}, dataTableList, 

 dt_Tab = table << Tabulate(
  Add Table(
   Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
   Row Table( Grouping Columns( :name, :age ) )
  )
 );

 // Pull the subset name from the data table name
 theTitle = Word( 3, Char( dataTableList[i] ), "\!"=" );
 
 // Create the new slide
 hbppt1 = H List Box( dt_tab  << get picture);
 ppt1 = Outline Box( theTitle, hbppt1 );
 
 // The pptx must exist for the append to be used, so on the first
 // slide it is not appended
 if(i==1,
  ppt1 << savepresentation( pathppt,"PNG" ),
  ppt1 << savepresentation( pathppt, Append,"PNG" )
 );
);

// Open the powerpoint presentation to see the results
open(pathppt);

 

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Ich habe JMP 16 noch nicht. Ich habe versucht, die For-Each-Schleife in eine For-Schleife umzuwandeln, erhalte aber keine Ausgabe

For (i = 1, i <= dataTableList, i++,
 dt_Tab = table << Tabulate(
  Add Table(
   Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
   Row Table( Grouping Columns( :name, :age ) )
  )
 );
);

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Hallo, ich habe versucht, die For Each-Schleife in For zu konvertieren, erhalte aber keine Ausgabe

For (i = 1, i <= dt_subsets, i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

dt_subsets ist eine JMP-Liste.Was Sie benötigen, ist die Anzahl der Elemente in der Liste.

For (i = 1, i <= N Items( dt_subsets ), i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Ich verstehe. Außerdem frage ich mich nur, woher dt_subset kommt?

 

Denn als ich diese Codezeile ausprobiert habe, dt_subset ( dt_subset << Tabulate() )wurde nicht gefunden. Ich habe jedoch versucht, es durch dt_subsets zu ersetzen, es hat die Tabellen 2x tabellarisch aufgeführt (2 tabellarische Tabellen für Männer und 2 für Frauen).

For (i = 1, i <= N Items( dt_subsets ), i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Es muss sein

For (i = 1, i <= N Items( dataTableList ), i++,

Betreff: Wie man tabellarische Tabellen und Bilder in PPT-Folien umwandelt

Die Variable

dt_subset

ist ein Fehler, das muss so sein

dt_subsets