683642_ko-KR

liliconcom

표와 이미지를 PPT 슬라이드로 반복하는 방법

안녕하세요. JMP 루핑에 어려움을 겪고 있습니다. 하위 집합 테이블에서 가져온 표로 구성된 테이블을 어떻게 반복할 수 있나요? 테이블 수가 변경될 수 있으므로 루핑을 해야 한다고 생각했습니다(하지만 어려움을 겪고 있습니다). 또한 이 이미지를 파워포인트 슬라이드에 추가해야 합니다. 반복되는 변수 이름을 가져와서 슬라이드에 추가하는 방법을 모르겠습니다.

 

다음은 내 샘플 스크립트이지만 루핑이 없습니다. 가능합니까?

 

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

:Sex << Set Name( "Sex_Subset" );
dt << New Column( "Sex", Formula(:Sex_Subset));

dt1 = dt << Subset( By( :Sex_Subset ), All rows, Selected columns only( 0 ) );

//this is where to loop tabulated tables since column values used in subsetting dt may change number of values
 
//how to loop this according to data table name? is that possible?
dt_Tab = Tabulate(
 Add Table(
  Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
  Row Table( Grouping Columns( :name, :age ) )
 )
);

tab = dt_Tab << get picture; //variable name needs to be looped? for ppt slides


//after getting the plot as image, how can I append those images that were loop to ppt slides?

//for male table
hbppt1 = H List Box(tab) << get picture;
ppt1 = Outline Box( "Male", hbppt1 );
ppt1 << savepresentation( pathppt, append, PNG );

//for female table
hbppt2 = H List Box(tab2) << get picture;
ppt2 = Outline Box( "Female", hbppt2 );
ppt2 << savepresentation( pathppt, append, PNG );

하위 집합의 테이블

 

자동화 및 스크립팅Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

By와 함께 Subset을 사용하면 반복할 수 있는 테이블 목록이 표시됩니다.

dt1 = {DataTable("Sex_Subset=F"), DataTable("Sex_Subset=M")};

 

편집하다:

사용 중인 기능과 메시지에 대한 스크립팅 인덱스를 확인하세요. 일부가 올바르지 않습니다.

Names Default To Here(1);

pathppt = "$TEMP/bigclass.pptx";

dt = Open("$SAMPLE_DATA/Big Class.jmp");
Column(dt, "Sex") << Set Name("Sex_Subset");
dt << New Column("Sex", Formula(:Sex_Subset));

dt_subsets = dt << Subset(By(:Sex_Subset), All rows, Selected columns only(0));

For Each({dt_subset}, dt_subsets,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );

 tab_pic = subset_tab << get picture; 
 subset_tab << Close Window;
 name_dt = dt_subset << get name;
 Close(, no save);
 hbppt = H List Box(tab_pic) << get picture;
 ppt = Outline Box(name_dt, hbppt);
 If(!File Exists(pathppt), 
  ppt << savepresentation(pathppt);
 , // append only if file already exists
  ppt << savepresentation(pathppt, append);
 );
);
 
Open(pathppt);

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

다음은 슬라이드를 생성하는 스크립트의 재작업입니다.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// Specify the path to save the pptx's to
pathPPT = "$TEMP/UserID16644Slides.pptx";

:Sex << Set Name( "Sex_Subset" );
dt << New Column( "Sex", Formula( :Sex_Subset ) );

// Add value labels so the full value can be used for the slide title
dt:Sex_Subset << Value Labels( {"F" = "Female", "M" = "Male"} ) << Use Value Labels( 1 );

// Subset the tables.  The dataTableList will contain a reference to each table created
dataTableList = dt << Subset( By( :Sex_Subset ), All rows, Selected columns only( 0 ) );

// Loop across all of the tables and create the Tabulates
For Each( {table, i}, dataTableList, 

 dt_Tab = table << Tabulate(
  Add Table(
   Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
   Row Table( Grouping Columns( :name, :age ) )
  )
 );

 // Pull the subset name from the data table name
 theTitle = Word( 3, Char( dataTableList[i] ), "\!"=" );
 
 // Create the new slide
 hbppt1 = H List Box( dt_tab  << get picture);
 ppt1 = Outline Box( theTitle, hbppt1 );
 
 // The pptx must exist for the append to be used, so on the first
 // slide it is not appended
 if(i==1,
  ppt1 << savepresentation( pathppt,"PNG" ),
  ppt1 << savepresentation( pathppt, Append,"PNG" )
 );
);

// Open the powerpoint presentation to see the results
open(pathppt);

 

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

아직 JMP 16이 없습니다. For Each 루프를 For 루프로 변환하려고 시도했지만 출력이 나오지 않습니다.

For (i = 1, i <= dataTableList, i++,
 dt_Tab = table << Tabulate(
  Add Table(
   Column Table( Grouping Columns( :Sex ), Analysis Columns( :height ) ),
   Row Table( Grouping Columns( :name, :age ) )
  )
 );
);

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

안녕하세요, For Each 루프를 For로 변환하려고 했지만 출력이 나오지 않습니다.

For (i = 1, i <= dt_subsets, i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

dt_subsets는 JMP 목록입니다.필요한 것은 목록의 요소 수입니다.

For (i = 1, i <= N Items( dt_subsets ), i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

알겠어요. 또한 dt_subset이 어디에서 왔는지 궁금하십니까?

 

왜냐하면 이 코드 줄을 시도했을 때 dt_subset( dt_subset << 표로 작성() )을 찾을 수 없습니다. 그러나 dt_subsets로 바꾸려고 시도했는데 테이블이 2x로 표로 작성되었습니다(남성용 표 2개, 여성용 표 2개).

For (i = 1, i <= N Items( dt_subsets ), i++,
 subset_tab = dt_subset << Tabulate(
  Add Table(
   Column Table(Grouping Columns(:Sex), Analysis Columns(:height)),
   Row Table(Grouping Columns(:name, :age))
  )
 );
);

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

그럴 필요가있다

For (i = 1, i <= N Items( dataTableList ), i++,

Re: 표와 이미지를 ppt 슬라이드로 반복하는 방법

변수

dt_subset

오류입니다.

dt_subsets