我多次被問到這個問題，但是有沒有辦法在圖形產生器中顯示能力分析？ 我發現它可以在哪裡顯示 5 個數字的摘要，但我不知道在哪裡可以讓它顯示該功能。 甚至可以選擇顯示 Cpk 或 Ppk？ 我似乎找不到這個，可能嗎？
我使用的是 JMP Pro 16.0。
我嘗試了幾種技術，但都失敗了。然後我又恢復了我已經用過幾次的方法。基本上，顯示是根據需要進行組織的，然後將其製作成圖片對象，並將該對象添加到新視窗中的輸出框（）中。由於圖片對像是單一對象，因此它顯示在一張投影片上
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
Lineup Box( N Col( 1 ),
Spacer Box( size( 1, 15 ) ),
txb = Text Box( "Within Sigma Capability" ),
tb = Table Box()
)
);
txb << set font style( "Bold" );
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
)
)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );
謝謝吉姆。 不幸的是它沒有按預期工作。 它仍然吐出兩個視窗。 現在的差異在於底部有一行帶有圖形產生器標題。 你有什麼建議？謝謝。
當您儲存至 .ppt 時，JMP 會自動為 2 個大綱方塊「圖形產生器」和「Sigma 功能內」建立單獨的投影片。
我認為您可以將兩者分組到一個新的大綱框下。我沒有測試過這個，但值得一試。
將新視窗行更改為
nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );
你好，
我試圖將 cpk 和 GB 放在同一個視窗上，而您提供的方式正是這樣做的。 問題是當我嘗試將其匯出到 ppt 時，它會在兩張不同的幻燈片中列印 cpk 和 GB。 您知道如何將它們放在同一張投影片中嗎？ 謝謝。
你好，
有沒有辦法將其導入到power point？ 我想要一個圖形產生器和 cpk，然後將其匯入到 ppt 中。 謝謝。
以下是為圖形產生器添加功能的兩種不同方法
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
hlb << append(
Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
Number Col Box( 1 )] << get
)
)
);
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
);
textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);
Report( gb )[framebox( 1 )] <<
add graphics script(
Text( Center Justified, {120, 275}, textlist[1] );
Text(
Center Justified,
{122, 275},
Format( statlist[1], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 265}, textlist[2] );
Text(
Center Justified,
{122, 265},
Format( statlist[2], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 255}, textlist[3] );
Text(
Center Justified,
{122, 255},
Format( statlist[3], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 245}, textlist[4] );
Text(
Center Justified,
{122, 245},
Format( statlist[4], "Fixed Dec", 4, 2 )
);
);
非常感謝吉姆！我感謝您的幫助。 我的通知已關閉，所以我才看到您的回覆。
我會嘗試一下，然後讓你知道進展如何。
