Funktion im Graph BuilderDiese Frage wurde mir schon mehrfach gestellt, aber gibt es eine Möglichkeit, die Fähigkeitsanalyse im Graph Builder anzuzeigen? Ich habe herausgefunden, wo eine 5-stellige Zusammenfassung angezeigt werden kann, aber ich weiß nicht, wie ich die Funktion anzeigen kann. Haben Sie überhaupt die Möglichkeit, Cpk oder Ppk anzuzeigen? Ich kann das scheinbar nicht finden, ist das möglich?
Ich verwende JMP Pro 16.0.
Qualitäts- und VerfahrenstechnikBetreff: Funktion im Graph BuilderIch habe mehrere Techniken ausprobiert und bin bei allen gescheitert.Ich bin dann auf eine Methode zurückgegriffen, die ich schon mehrmals verwendet habe.Grundsätzlich wird die Anzeige wie gewünscht organisiert und dann in ein Bildobjekt umgewandelt, und dieses Objekt wird einer Ausgabebox() in einem neuen Fenster hinzugefügt.Da es sich bei dem Bildobjekt um ein einzelnes Objekt handelt, wird es auf einer Folie angezeigt
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
Lineup Box( N Col( 1 ),
Spacer Box( size( 1, 15 ) ),
txb = Text Box( "Within Sigma Capability" ),
tb = Table Box()
)
);
txb << set font style( "Bold" );
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
)
)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );
Betreff: Funktion im Graph BuilderDanke, Jim. Leider funktioniert es nicht wie vorgesehen. Es spuckt immer noch zwei Fenster aus. Der Unterschied besteht jetzt darin, dass unten eine Zeile mit dem Titel des Graph Builder angezeigt wird. Haben Sie Empfehlungen? Danke.
Betreff: Funktion im Graph BuilderWenn Sie als .ppt speichern, erstellt JMP automatisch eine separate Folie für die beiden Gliederungsfelder „Graph Builder“ und „Within Sigma Capability“.
Ich denke, Sie können die beiden in einem neuen Gliederungsfeld zusammenfassen.Ich habe das nicht getestet, aber einen Versuch ist es wert.
Ändern Sie die Zeile Neues Fenster in
nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );
Betreff: Funktion im Graph BuilderHallo,
Ich versuche, den cpk und den GB im selben Fenster zu haben, und die von Ihnen angegebene Art und Weise bewirkt genau das. Das Problem ist, wenn ich versuche, es in ppt zu exportieren, werden CPK und GBin zwei verschiedenen Folien gedruckt. Wüssten Sie eine Möglichkeit, beides auf derselben Folie zu machen? Danke.
Betreff: Funktion im Graph BuilderNachfolgend einige Optionen
- Sie können das Auswahlwerkzeug verwenden und es dann kopieren und in Powerpoint einfügen
- Sie können mit der rechten Maustaste klicken und Diagramm kopieren verwenden
- Sie können das Menü „Datei“ verwenden und es als Powerpoint speichern
Betreff: Funktion im Graph BuilderHallo,
Gibt es eine Möglichkeit, dies in Power Point zu importieren? Ich hätte gerne einen Graph Builder und CPK und würde es dann in PPT importieren. Danke.
Betreff: Funktion im Graph BuilderDanke schön! Ich werde es versuchen.
Betreff: Funktion im Graph BuilderHier sind zwei verschiedene Möglichkeiten, diese Funktion zum Graph Builder hinzuzufügen
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
hlb << append(
Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
Number Col Box( 1 )] << get
)
)
);
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
);
textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);
Report( gb )[framebox( 1 )] <<
add graphics script(
Text( Center Justified, {120, 275}, textlist[1] );
Text(
Center Justified,
{122, 275},
Format( statlist[1], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 265}, textlist[2] );
Text(
Center Justified,
{122, 265},
Format( statlist[2], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 255}, textlist[3] );
Text(
Center Justified,
{122, 255},
Format( statlist[3], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 245}, textlist[4] );
Text(
Center Justified,
{122, 245},
Format( statlist[4], "Fixed Dec", 4, 2 )
);
);
Betreff: Funktion im Graph BuilderVielen Dank, Jim!Ich schätze Ihre Hilfe. Meine Benachrichtigung ist deaktiviert, daher habe ich gerade Ihre Antwort gesehen.
Ich werde es versuchen und euch berichten, wie es läuft.
