Capacité dans Graph BuilderOn m'a posé cette question à plusieurs reprises, mais existe-t-il un moyen d'afficher l'analyse des capacités dans Graph Builder ? J'ai trouvé où il peut afficher un résumé à 5 chiffres, mais je ne sais pas comment le faire afficher la capacité. Avez-vous même le Cpk ou le Ppk comme option à afficher ? Je n'arrive pas à trouver ça, est-ce possible ?
J'utilise JMP Pro 16.0.
Ingénierie Qualité et ProcédésRe : Capacité dans Graph BuilderJ'ai essayé plusieurs techniques et j'ai échoué avec chacune d'elles.Je suis ensuite revenu à une méthode que j'ai utilisée à plusieurs reprises.Fondamentalement, l'affichage est organisé comme souhaité, puis il est transformé en un objet image, et cet objet est ajouté à une boîte de sortie() dans une nouvelle fenêtre.L'objet image étant un objet unique, il est affiché sur une seule diapositive.
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
Lineup Box( N Col( 1 ),
Spacer Box( size( 1, 15 ) ),
txb = Text Box( "Within Sigma Capability" ),
tb = Table Box()
)
);
txb << set font style( "Bold" );
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
)
)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );
Re : Capacité dans Graph BuilderMerci Jim. Malheureusement, cela ne fonctionne pas comme prévu. Il crache encore deux fenêtres. La différence maintenant est qu'il y a une ligne en bas avec le titre du générateur de graphique. As-tu des recommandations? merci.
Re : Capacité dans Graph BuilderLorsque vous enregistrez au format .ppt, JMP crée automatiquement une diapositive distincte pour les deux zones de plan, "Graph Builder" et "Within Sigma Capability".
Je pense que vous pouvez regrouper les 2 sous une nouvelle boîte de contour.Je n'ai pas testé cela, mais cela vaut la peine d'essayer.
Remplacez la ligne Nouvelle fenêtre par
nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );
Re : Capacité dans Graph BuilderSalut,
J'essaie d'avoir le cpk et le GB sur la même fenêtre et la façon dont vous l'avez fournie fait exactement cela. Le problème est que lorsque j'essaie de l'exporter au format ppt, il imprime le cpk et le GB dans deux diapositives différentes. Connaissez-vous un moyen de les intégrer tous les deux dans la même diapositive ? Merci.
Re : Capacité dans Graph BuilderQuelques options ci-dessous
- Vous pouvez utiliser l'outil de sélection, puis le copier-coller dans Powerpoint
- vous pouvez cliquer avec le bouton droit et utiliser Copier le graphique
- Vous pouvez utiliser le menu Fichier et l'enregistrer sous Powerpoint.
Re : Capacité dans Graph BuilderSalut,
existe-t-il un moyen d'importer cela dans Power Point ? J'aimerais avoir un générateur de graphiques et cpk, puis l'importer dans ppt. Merci.
Re : Capacité dans Graph BuilderMerci! Je vais essayer ça.
Re : Capacité dans Graph BuilderVoici 2 façons différentes d'ajouter cette fonctionnalité au Graph Builder
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
hlb << append(
Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
Number Col Box( 1 )] << get
)
)
);
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
);
textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);
Report( gb )[framebox( 1 )] <<
add graphics script(
Text( Center Justified, {120, 275}, textlist[1] );
Text(
Center Justified,
{122, 275},
Format( statlist[1], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 265}, textlist[2] );
Text(
Center Justified,
{122, 265},
Format( statlist[2], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 255}, textlist[3] );
Text(
Center Justified,
{122, 255},
Format( statlist[3], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 245}, textlist[4] );
Text(
Center Justified,
{122, 245},
Format( statlist[4], "Fixed Dec", 4, 2 )
);
);
Re : Capacité dans Graph BuilderMerci beaucoup Jim!J'apprécie ton aide. Ma notification est désactivée, je viens donc de voir votre réponse.
Je vais l'essayer et je vous ferai savoir comment ça se passe.
