477249_zh-CN

liliconcom

图形生成器的功能

我多次被问到这个问题，但是有没有办法在图形生成器中显示能力分析？ 我发现它可以在哪里显示 5 个数字的摘要，但我不知道在哪里可以让它显示该功能。 甚至可以选择显示 Cpk 或 Ppk？ 我似乎找不到这个，可能吗？

 

我使用的是 JMP Pro 16.0。

质量和工艺工程回复：图形生成器的功能

我尝试了几种技术，但都失败了。然后我又恢复了我已经用过几次的方法。基本上，显示是根据需要进行组织的，然后将其制作成图片对象，并将该对象添加到新窗口中的输出框（）中。由于图片对象是单个对象，因此它显示在一张幻灯片上

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 gb = Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);

nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
 Lineup Box( N Col( 1 ),
  Spacer Box( size( 1, 15 ) ),
  txb = Text Box( "Within Sigma Capability" ),
  tb = Table Box()
 )
);
txb << set font style( "Bold" );
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
  )
 )
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );

回复：图形生成器的功能

谢谢吉姆。 不幸的是它没有按预期工作。 它仍然吐出两个窗口。 现在的区别在于底部有一行带有图形生成器标题。 你有什么建议？谢谢。

回复：图形生成器的功能

当您保存到 .ppt 时，JMP 会自动为 2 个大纲框“图形生成器”和“Sigma 功能内”创建单独的幻灯片。

我认为您可以将两者分组到一个新的大纲框下。我没有测试过这个，但值得一试。

将新窗口行更改为

nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );

回复：图形生成器的功能

你好，

我试图将 cpk 和 GB 放在同一个窗口上，而您提供的方式正是这样做的。 问题是当我尝试将其导出到 ppt 时，它会在两张不同的幻灯片中打印 cpk 和 GB。 您知道如何将它们放在同一张幻灯片中吗？ 谢谢。

回复：图形生成器的功能

下面几个选项

• 您可以使用选择工具，然后将其复制粘贴到 Powerpoint
• 您可以右键单击并使用复制图表
• 您可以使用“文件”菜单并将其另存为 Powerpoint

回复：图形生成器的功能

你好，

有没有办法将其导入到power point？ 我想要一个图形生成器和 cpk，然后将其导入到 ppt 中。 谢谢。

回复：图形生成器的功能

谢谢你！ 我会尝试这个。

回复：图形生成器的功能

以下是向图形生成器添加功能的两种不同方法

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
 Graph Builder(
  Size( 528, 454 ),
  Show Control Panel( 0 ),
  Variables( X( :NPN1 ) ),
  Elements( Histogram( X, Legend( 7 ) ) )
 )
);
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
hlb << append(
 Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
 String Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   String Col Box( 1 )] << get
  )
 )
);
tb << append(
 Number Col Box( "",
  Eval(
   Report( dis )["Within Sigma Capability"][
   Number Col Box( 1 )] << get
  )
 )
);

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
 invisible,
 Continuous Distribution(
  Column( :NPN1 ),
  Process Capability( Use Column Property Specs )
 )
);
gb = Graph Builder(
 Size( 528, 454 ),
 Show Control Panel( 0 ),
 Variables( X( :NPN1 ) ),
 Elements( Histogram( X, Legend( 7 ) ) )
);


textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);

Report( gb )[framebox( 1 )] <<
add graphics script(
 Text( Center Justified, {120, 275}, textlist[1] );
 Text(
  Center Justified,
  {122, 275},
  Format( statlist[1], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 265}, textlist[2] );
 Text(
  Center Justified,
  {122, 265},
  Format( statlist[2], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 255}, textlist[3] );
 Text(
  Center Justified,
  {122, 255},
  Format( statlist[3], "Fixed Dec", 4, 2 )
 );
 Text( Center Justified, {120, 245}, textlist[4] );
 Text(
  Center Justified,
  {122, 245},
  Format( statlist[4], "Fixed Dec", 4, 2 )
 );
);