이 질문을 여러 번 받았는데 그래프 빌더에서 공정 능력 분석을 표시할 수 있는 방법이 있습니까? 5자리 요약을 표시할 수 있는 위치를 찾았지만 해당 기능을 표시하는 방법을 어디서 찾을 수 있습니까? 표시할 옵션으로 Cpk 또는 Ppk가 있습니까? 이걸 찾을 수 없는 것 같은데, 가능할까요?
JMP Pro 16.0을 사용하고 있습니다.
여러 가지 기술을 시도했지만 모두 실패했습니다.그런 다음 여러 번 사용했던 방법으로 되돌아갔습니다.기본적으로 원하는 대로 디스플레이를 구성한 후 그림 개체로 만들고 해당 개체를 새 창의 출력 상자()에 추가합니다.그림 개체는 단일 개체이므로 하나의 슬라이드에 표시됩니다.
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
Lineup Box( N Col( 1 ),
Spacer Box( size( 1, 15 ) ),
txb = Text Box( "Within Sigma Capability" ),
tb = Table Box()
)
);
txb << set font style( "Bold" );
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
)
)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );
고마워요 짐. 불행하게도 의도한 대로 작동하지 않습니다. 여전히 두 개의 창을 뱉어냅니다. 이제 차이점은 하단에 그래프 빌더 제목이 있는 줄이 있다는 것입니다. 추천 사항이 있나요? 감사해요.
.ppt로 저장하면 JMP는 2개의 개요 상자인 "그래프 빌더"와 "시그마 기능 내"에 대한 별도의 슬라이드를 자동으로 생성합니다.
새 개요 상자 아래에 2개를 그룹화할 수 있다고 생각합니다.나는 이것을 테스트하지 않았지만 시도해 볼 가치가 있습니다.
새 창 줄을 다음으로 변경합니다.
nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );
안녕,
나는 cpk와 GB를 동일한 창에 두려고 노력하고 있으며 귀하가 제공한 방식이 정확히 그렇게 합니다. 문제는 ppt로 내보내려고 할 때 두 개의 다른 슬라이드에 cpk와 GB가 인쇄된다는 것입니다. 같은 슬라이드에서 두 가지를 모두 만드는 방법을 알고 계십니까? 감사해요.
안녕,
이것을 파워포인트로 가져올 수 있는 방법이 있나요? 그래프 빌더와 cpk를 갖고 이를 ppt로 가져오고 싶습니다. 감사해요.
그래프 빌더에 기능을 추가하는 두 가지 방법은 다음과 같습니다.
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
)
);
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
hlb << append(
Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
String Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
String Col Box( 1 )] << get
)
)
);
tb << append(
Number Col Box( "",
Eval(
Report( dis )["Within Sigma Capability"][
Number Col Box( 1 )] << get
)
)
);
Names Default To Here( 1 );
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
invisible,
Continuous Distribution(
Column( :NPN1 ),
Process Capability( Use Column Property Specs )
)
);
gb = Graph Builder(
Size( 528, 454 ),
Show Control Panel( 0 ),
Variables( X( :NPN1 ) ),
Elements( Histogram( X, Legend( 7 ) ) )
);
textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);
Report( gb )[framebox( 1 )] <<
add graphics script(
Text( Center Justified, {120, 275}, textlist[1] );
Text(
Center Justified,
{122, 275},
Format( statlist[1], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 265}, textlist[2] );
Text(
Center Justified,
{122, 265},
Format( statlist[2], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 255}, textlist[3] );
Text(
Center Justified,
{122, 255},
Format( statlist[3], "Fixed Dec", 4, 2 )
);
Text( Center Justified, {120, 245}, textlist[4] );
Text(
Center Justified,
{122, 245},
Format( statlist[4], "Fixed Dec", 4, 2 )
);
);
