682688_zh-TW

liliconcom

過濾多列中出現頻率最高的值

大家好，

 

我的目標是僅選擇每列中具有最常見值（字元類型）的行。

 

例如，我的表格有四列：A、B、C 和 D。 A、B、C 和 D 欄出現最多的數值分別是 A1、B2、C3 和 D4。 如何編寫 JSL 程式碼來按這些值過濾行並使用過濾後的資料建立一個新表？ 謝謝。

 

謝謝

資料混合與清理視窗回覆：過濾多列中出現頻率最高的值

如果你有這樣的數據，其中（COL -> 大多數出現）是 A -> A1、B -> B2、C -> C1（實際上 C 有平局，這些應該如何處理？）

您是否希望只保留 row1，因為它有 A1、B2 和 C1？ 如果有更多行具有相同的值，您想保留它們嗎？ 或者您正在尋找完全不同的東西，例如您想要一個只包含出現次數最多的值的表嗎？

回覆：過濾多列中出現頻率最高的值

這是一個可以幫助您解決問題的腳本

Names Default To Here( 1 );

// build an example data table
dt = New Table( "Example",
 add rows( 20 ),
 New Column( "A",
  character,
  formula(
   rand = Random Uniform( 0, 100 );
   If(
    rand >= 0 & rand <= 40, x = 1,
    rand >= 40 & rand <= 60, x = 2,
    rand >= 60 & rand <= 80, x = 3,
    x = 4
   );
   "A" || Char( x );
  )
 ),
 New Column( "B",
  character,
  formula(
   rand = Random Uniform( 0, 100 );
   If(
    rand >= 0 & rand <= 20, x = 1,
    rand >= 20 & rand <= 60, x = 2,
    rand >= 60 & rand <= 80, x = 3,
    x = 4
   );
   "B" || Char( x );
  )
 ),
 New Column( "C",
  character,
  formula(
   rand = Random Uniform( 0, 100 );
   If(
    rand >= 0 & rand <= 20, x = 1,
    rand >= 20 & rand <= 40, x = 2,
    rand >= 40 & rand <= 80, x = 3,
    x = 4
   );
   "C" || Char( x );
  )
 ),
 New Column( "D",
  character,
  formula(
   rand = Random Uniform( 0, 100 );
   If(
    rand >= 0 & rand <= 20, x = 1,
    rand >= 20 & rand <= 40, x = 2,
    rand >= 40 & rand <= 60, x = 3,
    x = 4
   );
   "D" || Char( x );
  )
 )
);


// The JSL below is the code that does the actual work
Data Table( "Example" ) << Stack(
 columns( :A, :B, :C, :D</img> ),
 Source Label Column( "Column" ),
 Stacked Data Column( "Data" ),
 Output Table( "Stacked" )
);

dtS = Data Table( "Stacked" ) << Summary(
 Group( :Column, :Data ),
 Freq( "None" ),
 Weight( "None" ),
 output table name( "Summary" )
);

dtS << select where( :N Rows[Row()] == col max(:N Rows, :Data));
dtS << new column("Mode", formula(
 Col Max(:N Rows, :Column)
));
dtS << select where( :N Rows == :Mode);
dtS << invert row selection << delete rows;

eval(parse(
"dt << Select Where (dt:\!"" || dts:column[1]  || "\!"n == dtS:Data[1] );"));

For( i=2,i<=NRows(dtS), i++,
 eval(parse(
 "dt << Select Where (dt:\!"" || dts:column[i]  || "\!"n == dtS:Data[i] , current selection(\!"extend\!"));"));
);

dtFinal = dt << Subset( selected columns(0), selected rows(1), output table("Final"));