681814_es-ES

liliconcom

¿Es posible superponer texto en un gráfico?

Hola. ¿Alguien sabe si existe un método de secuencia de comandos para agregar texto encima de un gráfico? Por ejemplo, tengo un script para crear un diagrama de Pareto y me gustaría agregar texto sobre el diagrama, como se muestra en el archivo adjunto. Tenga en cuenta que no me refiero a agregar un título encima de la trama. Me refiero a preguntar si hay alguna manera de colocar el texto dentro del área de trazado. Siento que hay una manera, pero hasta ahora mi búsqueda no ha tenido éxito. ¡Gracias!

 

Utilizando JMP Pro 17.2.0.

 

Automatización y secuencias de comandosExploración y visualización de datosRe: ¿Es posible superponer texto en un gráfico?

Construye el gráfico como quieras.Luego, usando los íconos de la herramienta de anotación, seleccione el ícono de texto.

y agregue el texto que desee en el lugar del gráfico donde lo desee.Hacer clic derecho en la anotación le permitirá configurar la fuente y el color, etc.

Luego vaya al triángulo rojo y seleccione guardar el script en una ventana de script, y obtendrá un script que creará el gráfico y la anotación.

Graph Builder(
 Size( 522, 486 ),
 Show Control Panel( 0 ),
 Variables(
  X( :age, Order By( :age, Descending, Order Statistic( "N" ) ) ),
  Group X( :sex )
 ),
 Elements( Bar( X, Legend( 8 ) ) ),
 SendToReport(
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   Add Text Annotation(
    Text( "Overlay Text Here" ),
    Fixed Size( 0 ),
    Text Box( {46, 31, 224, 68} ),
    Text Color( "Medium Dark Red" ),
    Font( "Segoe UI", 14, "Bold" ),
    Filled( 0 )
   )
  )
 )
);

 

Re: ¿Es posible superponer texto en un gráfico?

Gracias Jim. Eso es exactamente lo que necesitaba. Funciona perfectamente.

Re: ¿Es posible superponer texto en un gráfico?

Otro enfoque es agregar un script gráfico. Muchas funciones gráficas admiten la visualización de texto:

A continuación se muestra un ejemplo de otra forma de agregar texto a un gráfico:

Names Default to Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

obj = dt << Graph Builder(
 Size( 534, 456 ),
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ) ),
 Elements( Points( X, Y, Legend( 3 ) ), Smoother( X, Y, Legend( 4 ) ) )
);

rpt = obj << Report;

rpt[FrameBox(1)] << Add Graphics Script(
 Text( { 55, 160 }, "Here I am!" )
);