681834_ko-KR

liliconcom

JSL: 공통 초기 용어로 모든 열을 그룹화하는 방법은 무엇입니까?

초기에 설명된 용어를 기반으로 공통 번들로 그룹화하려는 dt(70,000열)가 있습니다.

 

예를 들어 모두 "ChamberID", "RecipeID" 또는 "SlotNo"로 시작하는 각각 10K 열입니다.

dt를 통해 모든 공통 열을 찾아 축소 가능한 번들로 그룹화하도록 스크립트를 작성하려면 어떻게 해야 합니까?

 

 

자동화 및 스크립팅Re: JSL: 공통 초기 용어로 모든 열을 그룹화하는 방법은 무엇입니까?

다음은 데이터 테이블에 열 그룹을 생성하는 예인 작은 스크립트입니다.

Names Default To Here( 1 );

dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

colNames = dt << get column names( string, continuous );

group1 = {};
group2 = {};
For Each( {name}, colNames,
 /*If(
  Left( name, 9 ) == "ChamberID",
   Insert Into( group1, name ),
  Left( name, 8 ) == "RecipeID",
   Insert Into( group2, name )
 )*/
 If(
  Left( name, 3 ) == "NPN",
   Insert Into( group1, name ),
  Left( name, 3 ) == "PNP",
   Insert Into( group2, name )
 )
);

dt << group columns( "NPN", group1);
dt << group columns( "PNP", group2);

Re: JSL: 공통 초기 용어로 모든 열을 그룹화하는 방법은 무엇입니까?

이를 수행하는 방법에는 여러 가지가 있습니다. 아래 스크립트에서 설명하는 것과 비슷한 것을 사용했습니다(연관 배열 사용).

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");

aa_groups = ["DELL" => {}, "DELW" => {}, "RCON" => {}];
col_names = dt << Get Column Names("String");

For Each({col_name}, col_names,
 For Each({{key, value}}, aa_groups,
  If(Starts With(col_name, key ||"_"), // "_" is used as additional separator
   Insert Into(aa_groups[key], col_name);
   Break();
  )
 );
);

For Each({{groupname, groupcols}}, aa_groups,
 dt << Group Columns(groupname, groupcols);
);

좀 더 역동적으로 가고 싶다면 그렇게 할 수도 있습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Probe.jmp");

aa_groups = Associative Array();
col_names = dt << Get Column Names("String");

For Each({col_name}, col_names,
 nameparts = Words(col_name, "_"); // depending ion your columns, this might need to change
 If(N Items(nameparts) > 1,
  If(!Contains(aa_groups, nameparts[1]),
   aa_groups[nameparts[1]] = {}; // add new key
  );
  Insert Into(aa_groups[nameparts[1]], col_name);
 );
);

For Each({{groupname, groupcols}}, aa_groups,
 dt << Group Columns(groupname, groupcols);
);

아이디어는 둘 다 동일합니다. 키가 열 그룹 이름이고 값이 해당 그룹에 속하는 열 목록인 연관 배열을 만듭니다.