680740_zh-TW

liliconcom

在資料集和產生的斜率之間擬合模型我想在加速資料集（特定溫度下不同時間點的資料）和這些點的斜率之間擬合一個模型
因為我想產生400個偽資料集並擬合每個資料集的斜率。 JMP 可以幫我做到這一點嗎？
我嘗試將斜率作為公式獲取，但不幸的是，分析器無法識別公式列，並且我無法將時間、結果值和斜率擬合到一行中以在添加噪聲後重複數據探索和視覺化預測建模和機器學習回覆：在資料集和產生的斜率之間擬合模型

你好，

您能否分享您嘗試在分析器中使用的資料和公式的範例（模擬資料可以）？ 僅憑您上面的簡短描述，我無法弄清楚如何解決您的問題。

謝謝。

最好的，

TS

回覆：在資料集和產生的斜率之間擬合模型

我想讓這個功能如下圖所示

回覆：在資料集和產生的斜率之間擬合模型

如果您的輸入資料類似於所附的 Excel 佈局圖片，則以下是執行此操作的方法範例。

 

names default to here(1);

// Create an example data table 
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

dtExample = dt << Subset( columns(:NPN1, :NPN2, :NPN3, :NPN4), output table( "Example" ) );

// Close the semiconductor capability data table
close( dt, nosave );

// add the initial comparison slope as row 1
dtExample << Add Rows( 1, At Start );
:NPN1[1] = 0;
:NPN2[1] = 1;
:NPN3[1] = 3;
:NPN4[1] = 6;

// Create the Slope Column and add the formula 
dtExample << New Column( "Slope",
 formula(
  // Create the y matrix from the 4 columns at row 1;
  // The y matrix needs to be the transpose of row 1,
  // since the matrix needs to be a 4 row matrix, not
  // a 4 column matrix
  As Constant( x = current data table()[1, 1::4]` );
  // For all rows in the data table, except the first
  // create the y matrix(transposed) and then run the
  // regression, stripping out only the slope from
  // the Estimates list created from the linear regression
  If( Row() > 1,
   y = current data table()[Row(), 1::4]`;
   {Estimates, Std_Error, Diagnostics} = Linear Regression( y, x );
   slope = Abs( Estimates[2] );
  ,
   slope = .
  );
 )
);

回覆：在資料集和產生的斜率之間擬合模型

進一步考慮您的請求，您希望考慮使用 JMP 中提供的回應篩選平台。它旨在查看大量分析，並嘗試使誤報可能影響分析的事實變得有意義。

為此，需要將資料從以行為中心的形狀簡單轉置為以列為中心的形狀（JMP 通常使用以列為中心的資料結構）。

下面的例子展示了轉置和分析

names default to here(1);

// Create an example data table 
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

dtExample = dt << Subset( columns(:NPN1, :NPN2, :NPN3, :NPN4), output table( "Example" ) );

// Close the semiconductor capability data table
close( dt, nosave );

// Transpose into columns
dtTrans = dtExample << Transpose(
 columns( Column Group( "Processes" ) ),
 Output Table( "Transpose of Example" )
);

close( dtExample, nosave );

// New column: Primary
dtTrans << New Column( "Primary",
 Numeric,
 "Continuous",
 Format( "Best", 12 ),
 values([0,1,3,6])
) << Move Selected Columns( {:Primary}, To First );

// Build a JMP list to handle all of the transposed columns as 
// a single reference
responseColList = dtTrans << get column names(string, continuous );
// Delete the first entry which is the new column called Primary
remove from( responseColList, 1,1);

// Run the Response Screening Platform which is designed to allow for the 
// exploration of a large number of analyses
// Launch platform: Predictor Screening
dtTrans <<
response Screening(
 Y( eval(responseColList)
 ),
 X( :Primary ),
 Show Slopes( 1 ),
 PValues Table on Launch( 0 ),
 Common Y Scale( 1 ),
 Common X Scale( 1 ),
);

有關響應篩選平台的詳細信息，請參閱幫助畫面或預測和專業建模文件（可在 JMP 文檔庫的「幫助」下拉式選單下找到）

回覆：在資料集和產生的斜率之間擬合模型

感謝您的努力，我的工作表的主要目的是進行蒙特卡羅模擬，以固定時間點將噪聲（400個偽數據集）添加到第一行，我與您共享的Excel工作表由實驗組成row和399 生成的數據集，我想說的是，如果以列為中心有助於生成這些數據，請告訴我如何做到這一點。

我已經嘗試過你的第一種方法並且它有效，但不幸的是我對 JMP 仍然是新手，所以現在我學習 JSL 以了解如何制定你的方法。

再次感謝

回覆：在資料集和產生的斜率之間擬合模型

JMP 文件庫中的刻畫器文件中有有關刻畫器和噪音因子使用的詳細文檔，可在「幫助」下拉式選單下找到。

也許這將為您提供您所需要的。