680045_es-ES

liliconcom

Sesión 9: JSL avanzado

Incluye funciones, expr(), 'eval(evalexpr)', 'eval(parse)'.

Presentadores: @jthi , @maurogerber

 

Vídeo 1: Introducción

Este vídeo está siendo procesado actualmente. Inténtelo de nuevo en unos minutos.

(ver en Mis vídeos)

 

Vídeo 2: Ejemplo

Este vídeo está siendo procesado actualmente. Inténtelo de nuevo en unos minutos.

(ver en Mis vídeos)

Re: Sesión 9: JSL avanzado

Algunos de los enlaces que mencioné para publicar aquí.

• Una de las mejores publicaciones de la comunidad sobre la creación de fórmulas usando expresiones.
  • Inserte una expresión en otra usando Eval Insert, Eval Expr, Parse y Substitute
• Conocimiento más profundo de las expresiones.
  • Funciones de manejo de expresiones: Parte I - Desentrañando Expr(), NameExpr(), Eval(), ... Adivinanza (lamentablemente no hay una segunda parte). También adjuntaré el mismo PDF a esta publicación.
• ¿Puedes construir esto sin escribir la expresión como una cadena?
• Cómo crear secuencias de comandos de propiedades de columna usando variables
• Cómo utilizar un valor de variable en una fórmula

Re: Sesión 9: JSL avanzado

Y estos son algunos de los problemas más comunes con los que te puedes encontrar y cómo puedes resolverlos con expresiones y evaluándolas cuando sea necesario.

1. Usar constante en una fórmula

Problema:

Su fórmula funciona solo una vez y se ve así después de guardarla y volver a abrirla:

 

Solución:

Inserte una expresión en otra usando Eval Insert, Eval Expr, Parse y Substitute . La mayor parte del tiempo uso Eval(EvalExpr()).

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

value_to_add = 5;

Eval(EvalExpr(
 dt << New Column("HeightAddFive", Numeric, Continuous, Formula(
  Expr(value_to_add) + :height
 )); 
));

2. Usar constantes en escritura gráfica

Problema:

Terminas con un guión como este.

 

Graph Builder(
 Show Control Panel(0),
 Variables(X(:height), Y(:weight), Overlay(:sex)),
 Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
 SendToReport(
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    7,
    Description(""),
    Pen Color(color_to_use);
    Pen Size(size_to_use);
    H Line(value_to_add);
   )}
  )
 )
);

Solución:

 

Utilice Eval(EvalExpr()) (o Substitute() es otra buena opción)

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

value_to_add = 80;

gb = dt << Run Script("Graph Builder Smoother Line");
color_to_use = "Red";
size_to_use = 2;

Eval(EvalExpr(
 Report(gb)[FrameBox(1)] << Add Graphics Script(
  Pen Color(Expr(color_to_use));
  Pen Size(Expr(size_to_use));
  H Line(Expr(value_to_add));
 ); 
));

3. Establecer variables como límites de especificaciones

Problema:

Los límites de especificaciones no se están configurando correctamente

 

Solución:

Comience dejando que JMP cree código (agregue la propiedad de la columna y tome el código del Registro mejorado o haga clic derecho en la columna y "Copiar propiedades de la columna". Obtienes algo como esto

 

Data Table("Big Class"):height << Set Property(
 "Spec Limits",
 {LSL(11), USL(22), Target(12), Show Limits(1)}
);

Mejore este script para usar variables.

 

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
aa_specs = Associative Array();
aa_specs["height"] = ["LSL" => 50, "USL" => 80];
aa_specs["weight"] = ["LSL" => 60, "USL" => 160];

For Each({col_name}, dt << Get Column Names("String"),
 If(Contains(aa_specs, col_name),
  Eval(EvalExpr(
   Column(dt, col_name) << Set Property("Spec Limits" ,{
    LSL(Expr(aa_specs[col_name]["LSL"])), 
    USL(Expr(aa_specs[col_name]["USL"])),
    Target(Expr((aa_specs[col_name]["LSL"] + aa_specs[col_name]["USL"])/2)),
    Show Limits(1)
   })
  ));
 );
);

 

4. Agregar scripts de tabla a la tabla

Problema:

Terminas con un script de tabla que dice algo como esto

 

Solución:

Eval(EvalExpr()) con Nombre Expr(). Esto no creará el gráfico en absoluto. Si desea ejecutarlo, utilice << Ejecutar script ("Mi bonito gráfico") o evalúe la expresión.

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb_expr = Expr(dt << Graph Builder(
 Show Control Panel(0),
 Variables(X(:height), Y(:weight), Overlay(:sex)),
 Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
));

Eval(EvalExpr(
 dt << New Script("My nice graph", Expr(Name Expr(gb_expr)));
));

// dt << Run Script("My nice graph");
// Eval(gb_expr);

</CODE>pero en casos como este, la mayor parte del tiempo usaría << Guardar script en tabla de datos, pero esto ejecutará la plataforma, así que recuerde cerrarlo.</P> <P>&nbsp;</P> <PRE><CODE class=" language-jsl">Names Default To Here(1); dt = Open("$SAMPLE_DATA/Big Class.jmp"); gb_expr = Expr(dt << Graph Builder( Show Control Panel(0), Variables(X(:height), Y(:weight), Overlay(:sex)), Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))), )); gb = Eval(gb_expr); gb << Save Script to Data Table("My nice graph"); gb << Close Window; Wait(0);

 

 

5. Cree fórmulas basadas en las selecciones del usuario en los cuadros de lista de columnas

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Selections",
 clb_x = Col List Box(dt, << Set items({"height"})),
 clb_y = Col List Box(dt, << Set items({"weight"}))
);

x_selection = clb_x << get items;
y_selection = clb_y << get items; // these are strings

wait(2);
nw << Close Window;

// Using Eval(EvalExpr())
Eval(EvalExpr(
 dt << New Column("Multiplication_EvalExpr", Numeric, Continuous, Formula(
  Expr(NameExpr(AsColumn(dt, x_selection))) * Expr(NameExpr(AsColumn(dt, y_selection)))
 ));
));

// Using Eval(Substitute())
Eval(Substitute(
 Expr(dt << New Column("Multiplication_EvalSubstitute", Numeric, Continuous, Formula(_xcol_ * _ycol_))),
 Expr(_xcol_), Name Expr(AsColumn(dt, x_selection)),
 Expr(_ycol_), Name Expr(AsColumn(dt, y_selection))
));

 

6. Utilice expresiones para crear interfaces de usuario (no es el mejor ejemplo)

Problema:

El código se vuelve torpe

 

Names Default To Here(1);

nw = New Window("asdas",
 Button Box("Perform Action1",
  Caption("Perform Action1")
 ),
 Button Box("Perform Action2",
  Caption("Perform Action2")
 ),
 Button Box("Perform Action3",
  Caption("Perform Action3")
 ) 
);

Problema 2:

 

Mi código no funciona (puede ocurrir porque la ventana no siempre conoce todas las variables)

 

Names Default To Here(1);

caption_expr = Expr(
 Caption("Perform Action");
);

nw = New Window("asdas",
 Button Box("Perform Action1",
  caption_expr
 ),
 Button Box("Perform Action2",
  caption_expr
 ),
 Button Box("Perform Action3",
  caption_expr
 ) 
);

 

Solución1:

Evaluar la expresión

 

Names Default To Here(1);

caption_expr = Expr(
 Caption("Perform Action");
);

Eval(EvalExpr(
 nw = New Window("asdas",
  Button Box("Perform Action1",
   Expr(Name Expr(caption_expr))
  ),
  Button Box("Perform Action2",
   Expr(Name Expr(caption_expr))
  ),
  Button Box("Perform Action3",
   Expr(Name Expr(caption_expr))
  ) 
 );
))

Solución2:

 

En este caso también puedes usar << Set Function(Function([}))

 

Names Default To Here(1);

nw = New Window("asdas",
 Button Box("Perform Action1", << Set Function(function({this},
  Caption(this << get button name);
 ))),
 Button Box("Perform Action2", << Set Function(function({this},
  Caption(this << get button name);
 ))),
 Button Box("Perform Action3", << Set Function(function({this},
  Caption(this << get button name);
 )))
);

Solución3:

 

Combinar

 

Names Default To Here(1);

button_caption_expr = Expr(
 Caption(this << get button name);
);

Eval(EvalExpr(
 nw = New Window("asdas",
  Button Box("Perform Action1", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  ))),
  Button Box("Perform Action2", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  ))),
  Button Box("Perform Action3", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  )))
 );
));

Solución 4:

 

Utilice la función (la solución 3 podría ser más sólida)

Names Default To Here(1);

show_btn_caption = function({btn_ref}, {Default Local},
 Caption(btn_ref << get button name);
);

nw = New Window("asdas",
 Button Box("Perform Action1", << Set Function(function({this},
  show_btn_caption(this);
 ))),
 Button Box("Perform Action2", << Set Function(function({this},
  show_btn_caption(this);
 ))),
 Button Box("Perform Action3", << Set Function(function({this},
  show_btn_caption(this);
 )))
);

Solución5:

Utilice la función para construir los botones.

Names Default To Here(1);

create_btn = function({btn_title}, {Default Local},
 btn = Button Box(btn_title, << Set Function(function({this},
  Caption(btn_ref << get button name);
 )));
 
 return(btn);
);

nw = New Window("asdas",
 create_btn("Perform Action1"),
 create_btn("Perform Action2"),
 create_btn("Perform Action3")
);