680045_ja-JP

liliconcom

セッション 9: 高度な JSL

関数、expr()、「eval(evalexpr)」、「eval(parse)」が含まれます。

プレゼンター: @jthi 、 @maurogerber

 

ビデオ 1: 概要

このビデオは現在処理中です。 数分後にもう一度試してください。

(マイビデオで表示)

 

ビデオ 2: 例

このビデオは現在処理中です。 数分後にもう一度試してください。

(マイビデオで表示)

Re: セッション 9: 高度な JSL

ここに投稿するために言及したリンクの一部

• 式を使用した式の構築に関するコミュニティでの最高の投稿の 1 つ
  • Eval Insert、Eval Expr、Parse、Substitute を使用して、ある式を別の式に挿入する
• 表現に関する知識が深まる
  • 式処理関数: パート I - Expr()、NameExpr()、Eval() などの解明 難問（残念ながらパート２はありません）。 この記事にも同じPDFを添付します
• 式を文字列として書かずにこれを構築できますか?
• 変数を使用して列プロパティをスクリプト化する方法
• 数式で変数値を使用する方法

Re: セッション 9: 高度な JSL

ここでは、遭遇する可能性のある非常に一般的な問題のいくつかと、式を使用して必要に応じて評価することで問題を解決する方法を示します。

1. 数式での定数の使用

問題：

数式は一度だけ機能し、保存して再度開くと次のようになります。

 

解決：

Eval Insert、Eval Expr、Parse、Substitute を使用して、ある式を別の式に挿入する。 ほとんどの場合、私は Eval(EvalExpr()) を使用します。

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

value_to_add = 5;

Eval(EvalExpr(
 dt << New Column("HeightAddFive", Numeric, Continuous, Formula(
  Expr(value_to_add) + :height
 )); 
));

2. グラフィックスクリプトでの定数の使用

問題：

このようなスクリプトが完成します

 

Graph Builder(
 Show Control Panel(0),
 Variables(X(:height), Y(:weight), Overlay(:sex)),
 Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
 SendToReport(
  Dispatch(
   {},
   "Graph Builder",
   FrameBox,
   {Add Graphics Script(
    7,
    Description(""),
    Pen Color(color_to_use);
    Pen Size(size_to_use);
    H Line(value_to_add);
   )}
  )
 )
);

解決：

 

Eval(EvalExpr()) を使用します (または Substitute() も良い選択肢です)

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

value_to_add = 80;

gb = dt << Run Script("Graph Builder Smoother Line");
color_to_use = "Red";
size_to_use = 2;

Eval(EvalExpr(
 Report(gb)[FrameBox(1)] << Add Graphics Script(
  Pen Color(Expr(color_to_use));
  Pen Size(Expr(size_to_use));
  H Line(Expr(value_to_add));
 ); 
));

3. 仕様限界として変数を設定する

問題：

スペック制限が正しく設定されていない

 

解決：

まず、JMP にコードを作成させます (列プロパティを追加して拡張ログからコードを取得するか、列を右クリックして「列プロパティをコピー」します)。 このようなものが得られます

 

Data Table("Big Class"):height << Set Property(
 "Spec Limits",
 {LSL(11), USL(22), Target(12), Show Limits(1)}
);

変数を使用できるようにこのスクリプトを改善します

 

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
aa_specs = Associative Array();
aa_specs["height"] = ["LSL" => 50, "USL" => 80];
aa_specs["weight"] = ["LSL" => 60, "USL" => 160];

For Each({col_name}, dt << Get Column Names("String"),
 If(Contains(aa_specs, col_name),
  Eval(EvalExpr(
   Column(dt, col_name) << Set Property("Spec Limits" ,{
    LSL(Expr(aa_specs[col_name]["LSL"])), 
    USL(Expr(aa_specs[col_name]["USL"])),
    Target(Expr((aa_specs[col_name]["LSL"] + aa_specs[col_name]["USL"])/2)),
    Show Limits(1)
   })
  ));
 );
);

 

4. テーブルスクリプトをテーブルに追加する

問題：

このようなテーブルスクリプトが完成します。

 

解決：

Eval(EvalExpr()) と名前 Expr()。 これではグラフはまったく作成されません。 実行したい場合は、<< Run Script("My nice chart") を使用するか、式を評価してください。

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb_expr = Expr(dt << Graph Builder(
 Show Control Panel(0),
 Variables(X(:height), Y(:weight), Overlay(:sex)),
 Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
));

Eval(EvalExpr(
 dt << New Script("My nice graph", Expr(Name Expr(gb_expr)));
));

// dt << Run Script("My nice graph");
// Eval(gb_expr);

</CODE>ただし、このような場合は、ほとんどの場合 << Save Script to Data Table を使用しますが、これによりプラットフォームが実行されるため、必ず閉じてください</P> <P>&nbsp;</P> <PRE><CODE class=" language-jsl">Names Default To Here(1); dt = Open("$SAMPLE_DATA/Big Class.jmp"); gb_expr = Expr(dt << Graph Builder( Show Control Panel(0), Variables(X(:height), Y(:weight), Overlay(:sex)), Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))), )); gb = Eval(gb_expr); gb << Save Script to Data Table("My nice graph"); gb << Close Window; Wait(0);

 

 

5.列リストボックスからのユーザー選択に基づいて数式を作成します

 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Selections",
 clb_x = Col List Box(dt, << Set items({"height"})),
 clb_y = Col List Box(dt, << Set items({"weight"}))
);

x_selection = clb_x << get items;
y_selection = clb_y << get items; // these are strings

wait(2);
nw << Close Window;

// Using Eval(EvalExpr())
Eval(EvalExpr(
 dt << New Column("Multiplication_EvalExpr", Numeric, Continuous, Formula(
  Expr(NameExpr(AsColumn(dt, x_selection))) * Expr(NameExpr(AsColumn(dt, y_selection)))
 ));
));

// Using Eval(Substitute())
Eval(Substitute(
 Expr(dt << New Column("Multiplication_EvalSubstitute", Numeric, Continuous, Formula(_xcol_ * _ycol_))),
 Expr(_xcol_), Name Expr(AsColumn(dt, x_selection)),
 Expr(_ycol_), Name Expr(AsColumn(dt, y_selection))
));

 

6. 式を使用してユーザー インターフェイスを構築します (最良の例ではありません)

問題：

コードが不格好になる

 

Names Default To Here(1);

nw = New Window("asdas",
 Button Box("Perform Action1",
  Caption("Perform Action1")
 ),
 Button Box("Perform Action2",
  Caption("Perform Action2")
 ),
 Button Box("Perform Action3",
  Caption("Perform Action3")
 ) 
);

問題2:

 

コードが機能しません (ウィンドウがすべての変数を常に認識しているわけではないため、この問題が発生する可能性があります)

 

Names Default To Here(1);

caption_expr = Expr(
 Caption("Perform Action");
);

nw = New Window("asdas",
 Button Box("Perform Action1",
  caption_expr
 ),
 Button Box("Perform Action2",
  caption_expr
 ),
 Button Box("Perform Action3",
  caption_expr
 ) 
);

 

解決策 1:

式を評価する

 

Names Default To Here(1);

caption_expr = Expr(
 Caption("Perform Action");
);

Eval(EvalExpr(
 nw = New Window("asdas",
  Button Box("Perform Action1",
   Expr(Name Expr(caption_expr))
  ),
  Button Box("Perform Action2",
   Expr(Name Expr(caption_expr))
  ),
  Button Box("Perform Action3",
   Expr(Name Expr(caption_expr))
  ) 
 );
))

解決策 2:

 

この場合、<< Set Function(Function([})) を使用することもできます。

 

Names Default To Here(1);

nw = New Window("asdas",
 Button Box("Perform Action1", << Set Function(function({this},
  Caption(this << get button name);
 ))),
 Button Box("Perform Action2", << Set Function(function({this},
  Caption(this << get button name);
 ))),
 Button Box("Perform Action3", << Set Function(function({this},
  Caption(this << get button name);
 )))
);

解決策 3:

 

組み合わせる

 

Names Default To Here(1);

button_caption_expr = Expr(
 Caption(this << get button name);
);

Eval(EvalExpr(
 nw = New Window("asdas",
  Button Box("Perform Action1", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  ))),
  Button Box("Perform Action2", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  ))),
  Button Box("Perform Action3", << Set Function(function({this},
   Expr(NameExpr(button_caption_expr));
  )))
 );
));

解決策 4:

 

関数を使用する (ソリューション 3 の方が堅牢である可能性があります)

Names Default To Here(1);

show_btn_caption = function({btn_ref}, {Default Local},
 Caption(btn_ref << get button name);
);

nw = New Window("asdas",
 Button Box("Perform Action1", << Set Function(function({this},
  show_btn_caption(this);
 ))),
 Button Box("Perform Action2", << Set Function(function({this},
  show_btn_caption(this);
 ))),
 Button Box("Perform Action3", << Set Function(function({this},
  show_btn_caption(this);
 )))
);

解決策5:

関数を使用してボタンを構築する

Names Default To Here(1);

create_btn = function({btn_title}, {Default Local},
 btn = Button Box(btn_title, << Set Function(function({this},
  Caption(btn_ref << get button name);
 )));
 
 return(btn);
);

nw = New Window("asdas",
 create_btn("Perform Action1"),
 create_btn("Perform Action2"),
 create_btn("Perform Action3")
);