Ich würde gerne Hilfe beim Senden von Befehlen an Elemente innerhalb eines Plattformberichts erhalten. Ich habe dies mithilfe des Vorschlags von Xan Gregg bereits zuvor getan. Ich habe es in einem anderen Fall selbst gemacht, als ich zufällig den richtigen Code bekam, aber ich kann nichts finden, was jedes Mal wirklich erklärt, wie es geht. Ich habe einen Bericht von der Time Series-Plattform und möchte dem Bericht einen Befehl zum Speichern von Spalten in der Gliederungsbox senden, in der das erste Modell angezeigt wird. Dieses Gliederungsfeld verfügt über ein Dropdown-Fenster. Ich habe Update Element() sowie Save Columns(1) und Save columns ausprobiert. Ich vermute, dass ich das Gliederungsfeld nicht richtig identifiziere und keine Informationen darüber finden kann, wie das geht, daher würde ich mich über eine Diskussion darüber, wie ich jedes Mal das richtige Element identifizieren kann, sehr freuen. Im Anhang finden Sie einen Screenshot des Berichtsfensters und unten meine JSL-Versuche. Jede Hilfe wird sehr geschätzt.
dt = Current Data Table();
ts = dt << Time Series(
Y( :"Forming Line-Forming Line Speed"n ),
Input List( :Mat Length ),
Variogram( 1 ),
Transfer Function(
Order( 0, 1, 6 ),
Seasonal( 0, 0, 0, 1 ),
:Mat Length( Order( 0, 1, 0 ), Seasonal( 0, 0, 0, 1 ), Lag( 0 ) ),
Prediction Interval( 0.85 ),
Number of Forecast Periods( 6 )
),
Model Comparison Report( Select Reports( [1] ), Select Graphs( Empty() ) ),
Input Series( :Mat Length, Variogram( 0 ) ),
SendToReport(
Dispatch(
{"Time Series Forming Line-Forming Line Speed", "Model Comparison"},
"",
ScrollBox,
{Background Color( {246, 250, 254} )}
),
Dispatch(
{"Time Series Forming Line-Forming Line Speed", "Transfer Function Model (1)",
"Interactive Forecasting"},
"Time Series",
FrameBox,
{DispatchSeg( CustomStreamSeg( 2 ), {Line Color( "Red" )} ),
DispatchSeg( CustomStreamSeg( 3 ), {Line Color( "Blue" )} ),
DispatchSeg( CustomStreamSeg( 4 ), {Line Color( "Blue" )} ),
DispatchSeg( CustomStreamSeg( 5 ), {Line Color( "Blue" )} )}
)
)
);
tsr = Report( ts );
tsb = tsr( Outline Box( "Transfer Function Model (1)" ) );
tsb << Save Columns;
// tsr << Update Element(1, 1, 1, 1, 8, 1, {Save Columns}));
// tsr << Update Element(1, 1, 3, {Save Columns}));
;Im Folgenden finden Sie einige Optionen, die für Sie in Frage kommen könnten (oder Ihnen zumindest eine Idee geben könnten, was zu tun ist).
Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Time Series/SeriesJ.jmp");
obj = dt << Time Series(Y(:Output CO2), Input List(:Input Gas Rate));
obj << Transfer Function(
Order(2, 0, 0),
Seasonal(0, 0, 0, 0),
:Input Gas Rate(Order(2, 0, 2), Seasonal(0, 0, 0, 0), Lag(3))
);
obj2 = obj << Transfer Function(
Order(2, 0, 0),
Seasonal(0, 0, 0, 0),
:Input Gas Rate(Order(2, 0, 2), Seasonal(0, 0, 0, 0), Lag(3)),
No Intercept(1),
Alternative Parameterization(1),
Confidence Intervals(0.99),
Number of Forecast Periods(10)
);
dt1 = obj2 << Save Columns; // using second reference
// using timeseries reference
dt2 = (Report(obj)[OutlineBox("Transfer Function Model (1)")] << get scriptable object) << Save Columns;
show(dt1, dt2);
Ich danke Ihnen für Ihre Hilfe! Das funktioniert! Ich schätze es wirklich!
Dan
