672169_zh-CN

liliconcom

如果颜色范围类型设置为中间 90%，则显示消息

在图形生成器中，如果颜色范围类型设置为“中间 90%”，请提供在图例框中包含一条消息的选项，以通知图表查看者此范围有效。目前，在使用线性标度时，没有迹象表明异常值以这种方式被“隐藏”。 非专家 JMP 用户或屏幕截图/平面图像的接收者无法知道已选择此选项。

 

在下图中，我展示了 5-95% 比例的示例，以及可以立即包含在比例下的信息文本类型的建议。

 

如果能够通过 JSL 以及交互方式访问此选项，那就太好了。

 

非常感谢，

马修。

数据探索和可视化回复：如果颜色范围类型设置为中间 90%，则显示消息

进一步思考我的问题后，这可以在 JSL 中非常简单地实现，如下所示：

 

names default to here(1);
dt = open("$SAMPLE_DATA/Semiconductor Capability.jmp");

win01 = new window( "Demo",
 bb = button box( "Toggle color scale: full vs middle 90%", toggleScale ),
 gb1 = dt << Graph Builder(
  Size( 534, 362 ),
  Show Control Panel( 0 ),
  Variables( X( :PNP1 ), Y( :NPN1 ), Color( :PNP2 ) ),
  Elements( Points( X, Y, Legend( 5 ) ) ),
  SendToReport(
   Dispatch(
    {}, "400", ScaleBox,
    {Legend Model(
     5,
     Properties(
      0,
      {gradient(
       {Range Type( "Middle 90%" ), N Labels( 6 ), Width( 12 )}
      )},
      Item ID( "PNP2", 1 )
     )
    )}
   )
  )
 )
);

Report(gb1)["Graph Builder",LegendBox(1)] << sibappend(
 tb = text box("Color Scale:\!NMiddle 90% (5-95%)")
);
tb << text color( "Dark Gray" );

toggleScale = expr(
 server = gb1 << Get Legend Server;
 item = server << Get Legend Items( 1, 1 );
 rangeType = (item << Get Gradient Settings)[1][1]["Range Type"];
 if( rangeType == "Middle 90%",
  rangeType = "Exact Data Range"; tb << set text( "Color Scale:\!NExact Data Range" ),
  rangeType = "Middle 90%"; tb << set text( "Color Scale:\!NMiddle 90% (5-95%)" )
 );
 item << set properties(
  {gradient(Range Type( eval(substitute(expr( a ), expr( a ), rangeType ) ) ), N Labels(6))}
 );
);

 

回复：如果颜色范围类型设置为中间 90%，则显示消息

添加这样的警告是个好主意。
现在可通过Graph Builder 工具栏使用: )