Hallo,
Ich habe Kontrolldiagramme aus mehreren Variablen erstellt, möchte jedoch den Achsentitel ändern, damit sie übereinstimmen. Gibt es eine schnelle Möglichkeit, dies zu tun, ohne sie manuell zu ändern? Ich habe versucht, dabei die Strg-Taste gedrückt zu halten, aber aus irgendeinem Grund scheint sich dadurch der Titel der X-Achse zu ändern. Irgendwelche Ideen, danke?
Hallo @Mo_Hoque_95 ,
Brady hat vielleicht eine Methode, um das einfach zu machen, aber die einzige Möglichkeit, die ich kenne, ist die Verwendung eines Skripts, insbesondere wenn Sie viele Kontrolldiagramme haben. Sie haben nicht erwähnt, ob Sie zum Erstellen Ihrer Kontrolldiagramme die ältere Kontrolldiagramm-Benutzeroberfläche oder die Kontrolldiagramm-Builder-Benutzeroberfläche oder etwas anderes verwenden. Unten öffnet dieses Skript eine JMP-Beispieldatentabelle, erstellt ältere Kontrolldiagramme und passt dann alle Beschriftungen der x-Achse an. //======== segmentiert die JSL.Das zweite Beispiel verwendet die Benutzeroberfläche des Kontrolldiagramm-Generators.
Viel Glück! Ich hoffe, es gibt eine einfache alternative Methode.
Names Default to Here(1);
dt =Open("$Sample_Data/Quality Control/Steam Turbine Historical.jmp");
//==========JMP 14 Legacy Control Charts ==================================
// Saved the script of my control chart window to a script window
// Assigned the Control Chart report to cc using cc=
cc = Control Chart(
Group Size( 1 ),
KSigma( 3 ),
Chart Col( :Fuel, Individual Measurement ),
Chart Col( :Steam Flow, Individual Measurement ),
Chart Col( :Steam Temp, Individual Measurement ),
Chart Col( :MW, Individual Measurement ),
Chart Col( :Cool Temp, Individual Measurement ),
Chart Col( :Pressure, Individual Measurement )
);
//xpath creates a list of references to each box. Note the X or sequence
// AxisBox might have a different ID depending upon your use: Legacy Control Chart or Control Chart Builder
axx = cc << xpath("//AxisBox[@charID='1']/TextEditBox");
//now send a few customizing messages to all these axes
axx << {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
Set Text( " Samples May 24 - Jun20" )};
//================== JMP 14 Using Control Chart Builder===============================================================
//JMP 15 and later versions have a better structure for X axis labels, I find the graph structure strange in v14
ccb14 = Control Chart Builder(
Show Capability( 0 ),
Variables( Y( :Fuel, :Steam Flow, :Steam Temp, :MW, :Cool Temp, :Pressure ) ),
Chart( Position( 1 ), Limits( Sigma( "Moving Range" ) ) ),
Chart( Position( 2 ), Limits( Sigma( "Moving Range" ) ) )
);
axxb14= ccb14 << xpath("//GraphBuilderTitleBox/TextEditBox");
//Every 3rd GraphTitleBox is the Xaxis or Subgroup axis
For(i=3, i<=nitems(axxb14), i=i+5,
axxb14[i]<< {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
Set Text( " Samples May 24 - Jun20" )};
);
//========================JMP 15========================================================
/*
//It's my opinion, JMP 15 has better structure references , AxisBox for Subgroup
//this code is commented out since you are working with JMP14
ccb15 = Control Chart Builder(
Variables Y( :Fuel, :Steam Flow, :Steam Temp, :MW, :Cool Temp, :Pressure ) );
axxb15= ccb15 << xpath("//AxisBox['Subgroup']/TextEditBox");
axxb15 << {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
Set Text( " Samples May 24 - Jun20" )};
Können Sie eine Beispieltabelle zusammen mit einem gespeicherten Skript eines Beispielkontrolldiagrammberichts anhängen? Das würde uns helfen, Ihre Situation genau in den Griff zu bekommen. Bitte zeigen Sie uns auch, was Sie unter „Titel“ verstehen, da es möglicherweise mehr als eine Stelle gibt, die wir als Titel interpretieren könnten.
Beifall,
Brady
