667205_zh-CN

liliconcom

如何获得预测方程的半评估形式

我正在使用拟合模型来构建时间和一堆额外因素的回归方程。 最终目标是在期刊中创建一个表格，其中评估了所有额外因素的预测方程，并显示纯截距 + 斜率 * 基于时间的方程。 例子：

dt = Open("$SAMPLE_DATA\Powder Metallurgy.jmp");
fm = dt << Fit Model(
 Y( :Shrinkage ),
 Effects(
  :Formation Method, :Compaction Method, :Sintering Time
 ),
 Personality( "Standard Least Squares" ),
 Emphasis( "Effect Leverage" ),
 Run()
);
PredForm = Arg(Arg((FM << GetPredictionFormula), 3),1);

得出等式：

0.942161598883733 + Match( :Formation Method,
 "Die", 0.0407171588498178,
 "Extrusion", 0.0256123252434345,
 "Isostatic", -0.0663294840932524,
 .
) + Match( :Compaction Method,
 "Cold", 0.594574663098895,
 "Warm", -0.594574663098895,
 .
) + -0.0742413463542265 * :Sintering Time

然后我们可以创建一个包含额外因素的表：

dtEquations = dt << Summary(
 Group( :Formation Method, :Compaction Method ),
 Freq( "None" ),
 Weight( "None" )
);
dtEquations << DeleteColumns(:N Rows);

那么，我如何将方程写入一个新列，它会查看（在本例中）前两列并简化计算 Match 语句，但将方程留给时间？ 最终目标：

如果所有静态系数都减少到 1，那就更好了。

 

对于多个额外因素水平，整个过程需要是动态的，并且方程可以是共同斜率、共同截距，也可以是不同的斜率和/或不同的截距。

自动化和脚本编写回复：如何获得预测方程的半评估形式

这很可能需要大量修改，但一种选择是使用 Extract Expr

Names Default To Here(1);

dt = Open("$SAMPLE_DATA\Powder Metallurgy.jmp");
fm = dt << Fit Model(
 Y(:Shrinkage),
 Effects(:Formation Method, :Compaction Method, :Sintering Time),
 Personality("Standard Least Squares"),
 Emphasis("Effect Leverage"),
 Run()
);

dtEquations = dt << Summary(Group(:Formation Method, :Compaction Method), Freq("None"), Weight("None"));

dtEquations << New Column("Sintering Time", Character, Continuous, << Set Each Value(
 PredForm = Arg(Arg((FM << GetPredictionFormula), 3), 1);
 PredForm = Substitute(Name Expr(PredForm), Extract Expr(PredForm, Match(Wild List())), Eval(Extract Expr(PredForm, Match(Wild List()))));
 PredForm = Substitute(Name Expr(PredForm), Extract Expr(PredForm, Match(Wild List())), Eval(Extract Expr(PredForm, Match(Wild List()))));
 Char(Name Expr(PredForm));
));

回复：如何获得预测方程的半评估形式

@jthi太棒了，谢谢！

我在最后一个块中添加了一个简化表达式，以将所有系数减少为 1，但除此之外，解决方案是完美的。

dtEquations << New Column("Sintering Time", Character, Continuous, << Set Each Value(
 PredForm = Arg(Arg((FM << GetPredictionFormula), 3), 1);
 PredForm = Substitute( Name Expr( PredForm ),
  Extract Expr( PredForm, Match( Wild List() ) ), Eval( Extract Expr( PredForm, Match( Wild List() ) ) )
 );
 PredForm = Substitute( Name Expr( PredForm ),
  Extract Expr( PredForm, Match( Wild List() ) ), Eval( Extract Expr( PredForm, Match( Wild List() ) ) )
 );
 Char(Simplify Expr(Name Expr(PredForm)));
));

回复：如何获得预测方程的半评估形式

这是一个很好的问题@保罗丁和很好的解决方案@jthi ！