nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

666744_fr-FR

liliconcom

Création de plusieurs varcharts pour une liste donnée de colonnes avec des légendes différentes pour chaque var chart en utilisant à chaque fois une colonne de légende nouvellement créée.

// I want to create journal of varcharts for a list of columns in a dataset with different legends. a legend column is mentioned which would change in reality for each loop. everything works expect the new column formula does not work.  <BR />//In this example, i have used a static legend value of "ABC" but this would change for every loop in reality. the issue is the new formula column does not evaluate the column name <BR /><BR />dt = current data table();

mycolumnList = {"species","subject","season"};


For( i = 1, i <= N Items(mycolumnList), i++, 
 Try(dt << delete column("LegendCol"));

 legend = "ABC";

 Try( dt << New Column( "LegendCol", Formula( If(Column(mycolumnList[i])[Row()] == legend, "first", "rest" ) ) ) );


 myvarChart = vlb << append(
 dt << Variability Chart(
  Y( :miles ),
  X( eval(mycolumnList[i]) ),
  Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
  Connect Cell Means( 1 ),
  Variability Summary Report( 1 ),
  Std Dev Chart( 0 ),
  Points Jittered( 1 ),
  Show Box Plots( 1 ),
  Name( "Show Gauge R&R Specifications Dialog" )(0),
  Automatic Recalc( 1 ),
  SendToReport(
   Dispatch(
    {"Variability Chart for SORT@WAFER@T_GOOD"},
    "Variability Chart",
    FrameBox,
    {Row Legend(
     Name( "LegendCol" ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 1 ),
     Marker Theme( "Solid" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   )
  )
 )); 
);

Anmol@1996

Automatisation et script

Analyse et modélisation des données de base

Fusion et nettoyage des données

Exploration et visualisation des données

Re : Création de plusieurs varcharts pour une liste donnée de colonnes avec des légendes différentes pour chaque graphique var en utilisant à chaque fois une colonne de légende nouvellement créée.

J'ai un peu retravaillé ton script.Je ne suis pas sûr que cela vous apporte la solution totale.Cependant, cela semble fonctionner sur vos exemples de données.

Names Default To Here( 1 );
// I want to create journal of varcharts for a list of columns in a dataset 
// with different legends. a legend column is mentioned which would change in 
// reality for each loop. everything works expect the new column formula does not work.  
//In this example, i have used a static legend value of "ABC" but this would change 
// for every loop in reality. the issue is the new formula column does not evaluate 
// the column name dt = current data table();

nw = New Window( "test", vlb = V List Box() );

dt = Current Data Table();
mycolumnList = {"species", "subject", "season"};


For( i = 1, i <= N Items( mycolumnList ), i++,
 Try( dt << delete column( "LegendCol" ) );
 
 legend = "ABC";
 
 Eval(
  Substitute(
    Expr(
     Try(
      dt << New Column( "LegendCol", Formula( If( Char( As Column( _mycolumnList_ ) ) == _legend_, "first", "rest" ) ) )
     )
    ),
   Expr( _mycolumnList_ ), mycolumnlist[i],
   Expr( _legend_ ), legend
  )
 );

 myvarChart = vlb << append(
  dt << Variability Chart(
   Y( :miles ),
   X( Eval( mycolumnList[i] ) ),
   Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
   Connect Cell Means( 1 ),
   Variability Summary Report( 1 ),
   Std Dev Chart( 0 ),
   Points Jittered( 1 ),
   Show Box Plots( 1 ),
   Name( "Show Gauge R&R Specifications Dialog" )(0),
   Automatic Recalc( 1 ),
   SendToReport(
    Dispatch(
     {"Variability Gauge Analysis for miles", "Variability Chart for miles"},
     "Variability Chart",
     FrameBox,
     {Row Legend(
      LegendCol,
      Color( 1 ),
      Color Theme( "JMP Default"(1) ),
      Marker( 0 ),
      Marker Theme( "" ),
      Continuous Scale( 0 ),
      Reverse Scale( 0 ),
      Excluded Rows( 0 )
     )}
    )
   )
  )
 );
);

Merci Jim, mais il y a toujours un petit problème. D'une manière ou d'une autre, toutes les parcelles reçoivent la même légende.

Par exemple, quelque chose comme ça. la légende change à chaque fois dans la boucle. cependant, les légendes ne sont pas reprises dans les graphiques var. j'obtiens toujours les légendes finales des colonnes de légende dans tous les tracés

nw = New Window( "test", vlb = V List Box() );

dt = Current Data Table();
mycolumnList = {"species", "subject", "season"};
mylegendList = Associative Array({"species","subject","season"},{"FOX","2","summer"});

For( i = 1, i <= N Items( mycolumnList ), i++,
 Try( dt << delete column( "LegendCol" ) );
 
 //legend = "ABC";
 legend = mylegendList[mycolumnList[i]];
 
 Eval(
  Substitute(
    Expr(
     Try(
      dt << New Column( "LegendCol", Formula( If( Char( As Column( _mycolumnList_ ) ) == _legend_, "first", "rest" ) ) )
     )
    ),
   Expr( _mycolumnList_ ), mycolumnlist[i],
   Expr( _legend_ ), legend
  )
 );

 myvarChart = vlb << append(
  dt << Variability Chart(
   Y( :miles ),
   X( Eval( mycolumnList[i] ) ),
   Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
   Connect Cell Means( 1 ),
   Variability Summary Report( 1 ),
   Std Dev Chart( 0 ),
   Points Jittered( 1 ),
   Show Box Plots( 1 ),
   Name( "Show Gauge R&R Specifications Dialog" )(0),
   Automatic Recalc( 1 ),
   SendToReport(
    Dispatch(
     {"Variability Gauge Analysis for miles", "Variability Chart for miles"},
     "Variability Chart",
     FrameBox,
     {Row Legend(
      LegendCol,
      Color( 1 ),
      Color Theme( "JMP Default"(1) ),
      Marker( 0 ),
      Marker Theme( "" ),
      Continuous Scale( 0 ),
      Reverse Scale( 0 ),
      Excluded Rows( 0 )
     )}
    )
   ))));

Pour faire ce que vous faites, je pense que vous allez devoir créer une colonne Légendes distincte pour chaque graphique

Names Default To Here( 1 );
nw = New Window( "test", vlb = V List Box() );

dt = Current Data Table();
mycolumnList = {"species", "subject", "season"};
mylegendList = Associative Array( {"species", "subject", "season"}, {"FOX", "2", "summer"} );

For( i = 1, i <= N Items( mycolumnList ), i++,
 Try( dt << delete column( "LegendCol" || Char( i ) ) );
 
 //legend = "ABC";
 legend = mylegendList[mycolumnList[i]];
 
 Eval(
  Substitute(
    Expr(
     Try(
      dt << New Column( "LegendCol" || Char( i ),
       Formula( If( Char( As Column( _mycolumnList_ ) ) == _legend_, "first", "rest" ) )
      )
     )
    ),
   Expr( _mycolumnList_ ), mycolumnlist[i],
   Expr( _legend_ ), legend
  )
 );
 Eval(
  Substitute(
    Expr(
     myvarChart = vlb << append(
      dt << Variability Chart(
       Y( :miles ),
       X( Eval( mycolumnList[i] ) ),
       Analysis Type( "Choose best analysis (EMS REML Bayesian)" ),
       Connect Cell Means( 1 ),
       Variability Summary Report( 1 ),
       Std Dev Chart( 0 ),
       Points Jittered( 1 ),
       Show Box Plots( 1 ),
       Name( "Show Gauge R&R Specifications Dialog" )(0),
       Automatic Recalc( 1 ),
       SendToReport(
        Dispatch(
         {"Variability Gauge Analysis for miles", "Variability Chart for miles"},
         "Variability Chart",
         FrameBox,
         {Row Legend(
          _LegendCol_,
          Color( 1 ),
          Color Theme( "JMP Default"(1) ),
          Marker( 0 ),
          Marker Theme( "" ),
          Continuous Scale( 0 ),
          Reverse Scale( 0 ),
          Excluded Rows( 0 )
         )}
        )
       )
      )
     )
    ),
   Expr( _legendcol_ ), Parse( "LegendCol" || Char( i ) )
  )
 );
);

Comments

There are no comments yet