665596_es-ES

liliconcom

Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

Estoy tratando de agregar leyendas de fila en los gráficos de VC. Sin embargo, sendToReport no agrega leyendas a todos los gráficos. Solo funciona para la primera gráfica, pero no para las otras gráficas de VC. Solía funcionar bien en JMP 16.

 

Cualquier trabajo alrededor?

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp" );
obj = dt << Variability Chart( Y( :Measurement,:Standard ), X( :Operator, :part# ),

SendToReport(
  Dispatch(
   {"",
   ""},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 ) );

Automatización y secuencias de comandosRe: Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

Nunca he podido agregar leyendas directamente a la trama.Las leyendas siempre aparecen en una ventana separada, lo cual es frustrante.Ansioso por saber si alguien puede resolver esto o simplemente debe agregarse a la lista de deseos.

Re: Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

Debe enviar el código de la leyenda a los nodos del esquema que le interesen.

dt = Open( "$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp" );
obj = Variability Chart(
 Y( :Measurement, :Standard ),
 X( :Operator, :part# ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Analysis for Measurement",
   "Variability Chart for Measurement"},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    :Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  ),
  Dispatch(
   {"Variability Gauge Analysis for Standard",
   "Variability Chart for Standard"},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 )
);

Re: Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

@tonya_mauldin Tengo más de 200 columnas y la fuerza bruta para cada columna no sería el mejor enfoque.

 

Col_names = dt << get column names(); /// contains 200+ columns
obj = dt << Variability Chart( Y( Eval(Col_names) ), X(:LotNumber, :WaferId),

SendToReport(
  Dispatch(
   {"", 
   ""},/// is there a way to reference the column name for 200+ colunm names here?
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 ) );

 

Re: Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

Funciona. gracias jarmo

Re: Problemas con las leyendas de las filas del gráfico de variabilidad JMP17

Una opción es usar XPath para obtener referencias a FrameBoxes.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp");

obj = dt << Variability Chart(
 Y(:Measurement, :Standard),
 X(:Operator, :part#)
);

(Report(obj) << XPath("//FrameBox")) << Row Legend(
 Operator,
 Color(1),
 Color Theme("JMP Default"(1)),
 Marker(0),
 Marker Theme(""),
 Continuous Scale(0),
 Reverse Scale(0),
 Excluded Rows(0)
);

Este ejemplo usa TODOS los marcos, pero lo más probable es que desee limitar la selección en la consulta XPath o usar índices específicos.

También esto está un poco relacionado con esta discusión. Mostrar leyenda en cada gráfico en el generador cuando se usa la página

 

Editar: ejemplo de cómo usar el atributo xml y su valor en XPath e indexación:

Ver más...