665596_fr-FR

liliconcom

Problèmes avec les légendes des lignes du tableau de variabilité JMP17

J'essaie d'ajouter des légendes de lignes dans les tracés VC. Cependant, le sendToReport n'ajoute pas de légendes à tous les tracés. Cela ne fonctionne que pour le premier tracé mais pas pour les autres graphiques VC. Cela fonctionnait très bien dans JMP 16.

 

Tout travail autour?

 

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp" );
obj = dt << Variability Chart( Y( :Measurement,:Standard ), X( :Operator, :part# ),

SendToReport(
  Dispatch(
   {"",
   ""},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 ) );

Automatisation et scriptRe : Problèmes avec les légendes des lignes du tableau de variabilité JMP17

Je n'ai jamais pu ajouter de légendes directement à l'intrigue.Les légendes apparaissent toujours dans une fenêtre séparée, ce qui est frustrant.J'ai hâte de savoir si quelqu'un peut résoudre ce problème ou s'il doit simplement être ajouté à la liste de souhaits.

Re : Problèmes avec les légendes des lignes du tableau de variabilité JMP17

Vous devez envoyer le code de légende aux nœuds de plan qui vous intéressent.

dt = Open( "$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp" );
obj = Variability Chart(
 Y( :Measurement, :Standard ),
 X( :Operator, :part# ),
 SendToReport(
  Dispatch(
   {"Variability Gauge Analysis for Measurement",
   "Variability Chart for Measurement"},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    :Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  ),
  Dispatch(
   {"Variability Gauge Analysis for Standard",
   "Variability Chart for Standard"},
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 )
);

Re : Problèmes avec les légendes des lignes du tableau de variabilité JMP17

@tonya_mauldin J'ai plus de 200 colonnes et forcer brutalement pour chaque colonne ne serait pas la meilleure approche.

 

Col_names = dt << get column names(); /// contains 200+ columns
obj = dt << Variability Chart( Y( Eval(Col_names) ), X(:LotNumber, :WaferId),

SendToReport(
  Dispatch(
   {"", 
   ""},/// is there a way to reference the column name for 200+ colunm names here?
   "Variability Chart",
   FrameBox,
   {Row Legend(
    Operator,
    Color( 1 ),
    Color Theme( "JMP Default"(1) ),
    Marker( 0 ),
    Marker Theme( "" ),
    Continuous Scale( 0 ),
    Reverse Scale( 0 ),
    Excluded Rows( 0 )
   )}
  )
 ) );

 

Re : Problèmes avec les légendes des lignes du tableau de variabilité JMP17

Ça marche. Merci Jarmo

Re : Problèmes avec les légendes des lignes du tableau de variabilité JMP17

Une option consiste à utiliser XPath pour obtenir des références aux FrameBoxes.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Variability Data/2 Factors Crossed.jmp");

obj = dt << Variability Chart(
 Y(:Measurement, :Standard),
 X(:Operator, :part#)
);

(Report(obj) << XPath("//FrameBox")) << Row Legend(
 Operator,
 Color(1),
 Color Theme("JMP Default"(1)),
 Marker(0),
 Marker Theme(""),
 Continuous Scale(0),
 Reverse Scale(0),
 Excluded Rows(0)
);

Cet exemple utilise TOUS les cadres, mais vous souhaiterez probablement limiter la sélection dans la requête XPath ou utiliser des index spécifiques.

C'est aussi un peu lié à cette discussion Afficher la légende sur chaque graphique du générateur lors de l'utilisation de la page

 

Edit : Exemple d'utilisation de l'attribut xml et de sa valeur dans XPath et l'indexation :

Voir plus...