155675_it-IT

liliconcom

Come creare un grafico CDF in Graph Builder

Quale sarebbe il modo migliore per creare un grafico CDF in Graph Builder, paragonabile a Fit Y by X (CDF / CumProb), ma con le funzionalità di Graph Builder come Overlay, Group, Color ecc.?

Ri: Come creare un grafico CDF in Graph Builder

Per quanto riguarda Grafico CDF in Costruttore di grafici , per favore riferisci a come creare grafici di probabilità cumulativa in JMP?

Ri: Come creare un grafico CDF in Graph Builder

Questo è un grafico molto bello. Sarebbe utile se potessi fornire lo stesso esempio usando i conteggi e non la probabilità. Suppongo che il calcolo della probabilità sia frequenza/totale? il problema è fare i conti...

Grazie

Ri: Come creare un grafico CDF in Graph Builder

Adatterebbe loro una distribuzione parametrica o useresti qualcosa come Kaplan-Meier per adattare il CDF ai dati?

Inoltre, se non disponi di tonnellate di dati per ciascun gruppo, il semplice confronto dei valori CDF adattati per i tuoi dati rispetto ai valori dei dati effettivi probabilmente lascerà delle lacune nel CDF tracciato. Ecco perché ho creato una sequenza di valori da tracciare, quindi mi assicuro di riempire l'intero intervallo.

Questo lo rende un processo in 2 fasi. 1. adattare le distribuzioni a ciascun gruppo di dati e ottenere le stime dei parametri di distribuzione. 2. Creare una tabella di dati per tracciare le probabilità CDF (calcolate con formule di colonna) rispetto a una sequenza di valori che copre l'intervallo.

Questo è un processo laborioso, ma andrebbe bene se non hai un sacco di gruppi e devi farlo solo una volta. Se hai bisogno di qualcosa di robusto, probabilmente hai bisogno di una soluzione con script

Ri: Come creare un grafico CDF in Graph Builder

Grazie Cameron per aver fornito soluzioni per la distribuzione di Poisson e il suggerimento per collegare i punti in modo graduale. Ho usato i numeri di Poisson solo per generare i dati.

Quale sarebbe il modo per un dato set di dati senza sapere come sono distribuiti per creare un grafico CDF?

Ri: Come creare un grafico CDF in Graph Builder

Ecco un esempio con 4 distribuzioni di Poisson:

New Table( "Poisson CDF Example",
 Add Rows( 200 ),
 New Script(
  "Poisson CDF Comparison",
  Graph Builder(
   Size( 526, 452 ),
   Show Control Panel( 0 ),
   Variables( X( :X ), Y( :Probability ), Overlay( :Distribution ) ),
   Elements( Line( X, Y, Legend( 19 ), Connection( "Step" ) ) ),
   SendToReport(
    Dispatch(
     {},
     "X",
     ScaleBox,
     {Min( -1 ), Max( 12 ), Inc( 10 ), Minor Ticks( 1 )}
    )
   )
  )
 ),
 New Column( "Distribution",
  Character,
  "Nominal",
  Formula( "Pois(" || Char( :Lambda ) || ")" )
 ),
 New Column( "Lambda",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( If( Row() < 51, 0.5, Row() < 101, 2, Row() < 151, 4, 1.25 ) )
 ),
 New Column( "X",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( -1, 48, 1, 1 ) )
 ),
 New Column( "Probability",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Poisson Distribution( :Lambda, :X ) ),
  Set Selected
 )
)

La chiave con una funzione passo CDF è disattivare la linea più uniforme in Graph Builder e collegare i punti utilizzando Line.Quindi modificare Connection nel pannello di controllo in "Step".

Ri: Come creare un grafico CDF in Graph Builder

Scusa. Non ho notato la discrepanza prima. La guida di JMP dice:

 

Per N punteggi non mancanti, il punteggio di probabilità di un valore viene calcolato come il rango medio di quel valore diviso per N + 1. Questa colonna è simile alla funzione di distribuzione cumulativa empirica.

 

Quindi non sono la stessa cosa. Non riesco a trovare un sostituto.

Ri: Come creare un grafico CDF in Graph Builder

Grazie per la risposta veloce e campioni interessanti Cameron. Cosa bisogna fare per creare un grafico CDF in Graph Builder i dati allegati simili al risultato del grafico CDF dalla piattaforma Y bx X?

 

Ri: Come creare un grafico CDF in Graph Builder

Grazie per il vostro sostegno. Ho provato il metodo Prob Score. Tuttavia ho ottenuto un risultato diverso per la pozione zero del file allegato. La distribuzione e il grafico CDF dalla piattaforma Y by X stanno fornendo una quota zero del 60,4%.

Il costruttore di grafici e il punteggio prob stanno offrendo un 30% per la parte zero.

Ri: Come creare un grafico CDF in Graph Builder

Usa il Distribuzione piattaforma per ottenere le probabilità. Fare clic sul triangolo rosso per la variabile in Distribuzione e selezionare Salva > Punteggi Prob . Ora usa questa nuova colonna di dati nel ruolo Y in Costruttore di grafici e la colonna di dati originale nel ruolo X.

Ri: Come creare un grafico CDF in Graph Builder

Ecco un esempio che utilizza sequenze ripetute di probabilità e quantili di tali probabilità per diverse distribuzioni:

Ecco lo script per la tabella che ho creato per illustrare:

New Table( "Untitled",
 Add Rows( 8040 ),
 New Script(
  "Normal CDFs",
  Graph Builder(
   Size( 526, 452 ),
   Show Control Panel( 0 ),
   Variables( X( :Quantile ), Y( :Probability ), Overlay( :Distribution ) ),
   Elements( Line( X, Y, Legend( 18 ) ) )
  )
 ),
 New Column( "Probability",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( 1 / (1 + Exp( -Sequence( -10, 10, 0.1, 1 ) )) )
 ),
 New Column( "Quantile",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Normal Quantile( :Probability, :mu, :sigma ) )
 ),
 New Column( "mu",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 1, 10, 1, 402 ) )
 ),
 New Column( "sigma",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Formula( Sequence( 2, 2.5, 0.5, 402 ) )
 ),
 New Column( "Distribution",
  Character,
  "Nominal",
  Formula( "Normal(" || Char( :mu ) || ", " || Char( :sigma ) || ")" ),
  Set Selected
 )
)

Re: Come creare un grafico CDF nel Costruttore di grafici

Ed ecco un augurio dal 2022 a direttamente Aggiungi CDF al Costruttore di grafici di @BHarris .

Re: Come creare un grafico CDF in Graph Builder

Dalla discussione lì:

dt = Open( "$DOWNLOADS/CDF_Data.jmp" );
new column("one_Nr", formula(1));


dt << Graph Builder(
	Variables(
		X( :Data ),
		Y( :"Cumulative Probability[Data]"n ),
		Y( :one_Nr, Position( 1 ) ),
		//Y( :Prob DataX, Position( 1 ) ) // enable after saving the data to the table
	),
	Elements(
		Points( X, Y( 1 ), Y( 3 ), Legend( 11 ) ),
		Points( X, Y( 2 ), Legend( 2 ), Summary Statistic( "Cumulative Percent" ) ),
		Line(
			X,
			Legend( 3 ),
			Connection( "Step" ),
			Summary Statistic( "Cumulative Percent" ),
			Interval Style( "Band" )
		)
	),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				11,
				Properties(
					1,
					{Marker( "FilledCircle" ), Marker Size( 6 )},
					Item ID( "Prob Data", 1 )
				)
			), Legend Model(
				2,
				Properties( 0, {Marker Size( 10 )}, Item ID( "Sum %(one_Nr)", 1 ) )
			), Legend Model(
				3,
				Properties( 0, {Line Color( 8 )}, Item ID( "Count", 1 ) )
			)}
		)
	)
);

Se la linea orizzontale mancante e il primo passaggio dal bordo sinistro a 0 al valore x del primo punto e verso l'alto ( link ) vanno bene per te,
l'approccio tramite "Linea" + "Percentuale cumulativa" (linea viola) è una buona scorciatoia.