658341_es-ES

liliconcom

Constructor de gráficos. ¿Cómo combinar suavizado y línea?

Tengo grupos de medidas que quiero graficar "juntos".

Las curvas de medición individuales de un grupo deben tener el mismo color y ser semitransparentes.
Para cada grupo debe haber una curva adicional más suave con el mismo color.

¿Es esto posible en Jmp? ¿Sin “soluciones alternativas”?

versión 1:

• Las medidas de un grupo tienen el mismo color
• una curva por medición
• la transparencia funciona
• 1 línea más suave en lugar de 3
• La curva más suave no tiene el color "correcto" [error consecuente]

versión 2:

• Las medidas de un grupo tienen el mismo color
• Saltos desagradables hacia atrás para las curvas individuales
• la transparencia funciona
• Cada grupo tiene su propia curva más suave.
• Las curvas más suaves tienen el color incorrecto

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

Exploración y visualización de datosRe: Graph Builder. ¿Cómo combinar suavizador y línea?

Bueno: La sugerencia de respaldo de Graph Builder: Línea: posibilidad de agregar saltos [opción (2)] ya está disponible:

Con este nuevo hallazgo, me complace presentarles:

versión 3:

• mismo grupo = mismo color
• Sin desagradables curvas en zigzag
• La transparencia funciona
• Cada grupo tiene su propia curva más suave.
• Curvas más suaves con color a juego.
  
• Se agregaron nuevas filas a la tabla de datos *)

*) OK como solución alternativa: funciona porque se agregaron filas auxiliares a la tabla de datos

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

#1000

Re: Graph Builder. ¿Cómo combinar suavizador y línea?

Espero que alguien encuentre una manera de crear este gráfico en Jmp (17), sin agregar nuevas filas y columnas al gráfico.

La superposición de varias columnas resolverá el problema. Si la superposición acepta más de una columna, el usuario puede seleccionar diferentes superposiciones para los dos tipos de gráfico:

1. Superposición para el elemento más suave:
   :grupo-> una curva de ajuste por grupo
   
   
2. Superposición para el elemento de línea:
   :Estación -> trazas separadas por estación = sin líneas en zigzag

Además de mejorar la funcionalidad de superposición, aquí hay otro deseo del generador de gráficos: Línea: posibilidad de agregar saltos que utiliza un truco simple para agregar los saltos:
La idea: un trazo de medición que va de izquierda a derecha.
Cada paso de derecha a izquierda marca el inicio de un nuevo trazo -> agrega un salto.

Re: Graph Builder. ¿Cómo combinar suavizador y línea?

Ah, el color = "grupo" es demasiado. Se puede eliminar por completo.

Respecto a Zig-Zag:
Quiero tener curvas separadas por estación, por eso habilité el orden de filas .

Deshabilitar la opción da como resultado una curva combinada para todas las estaciones de un grupo.

versión 2 (b):

• Las medidas de un grupo tienen el mismo color.
• Saltos desagradables hacia atrás para las curvas individuales (se solucionó eliminando el orden de las filas)
  Lamentablemente ya no:una curva por estación
• La transparencia funciona
• Cada grupo tiene su propia curva más suave.
• Curvas más suaves con color a juego.

Re: Generador de gráficos. Combine Smoother y Line: ¿cómo?

Intente eliminar el grupo del color para que sea más suave y, para eliminar el zigzag, desactive el orden de las filas.

 

Re: Generador de gráficos. Combine Smoother y Line: ¿cómo?

@XanGregg , Overlay Encoding facilitará la creación de dichos gráficos (diferentes colores y curvas de ajuste individuales para diferentes variantes, pero más de una curva de medición por variante).

Re: Graph Builder. ¿Cómo combinar suavizador y línea?

¿Y configurar niveles ?
no: de nuevo las líneas en zigzag.

Ver más...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

Re: Constructor de gráficos. ¿Cómo combinar suavizador y línea?

Si genera gráficos de este tipo periódicamente, eche un vistazo a la Barra de herramientas de selección rápida .
Hay un icono de acceso directo para crear filas ficticias automáticamente y ordenar la tabla para colocar las filas ficticias en la posición correcta.

La función se eliminó de la barra de herramientas de selección rápida.
Una función similar ahora está disponible a través de la barra de herramientas GraphBuilder

Re: Graph Builder. ¿Cómo combinar suavizador y línea?

Estamos probando la versión beta de un complemento de "control remoto" para Graph Builder que facilitará el formato manual de los gráficos.
Agregué un botón para eliminar las líneas en zigzag

En comparación con "agregar filas ficticias", tiene el beneficio de que no entra en conflicto con Ordenar tabla de datos + agregar filas + concatenar: lo hace posible

Re: Graph Builder. ¿Cómo combinar suavizador y línea?

un formalismo como "columna de ID de curva" en Ajustar curva para dividir los datos en curvas individuales, pero aún así agrupar curvas similares en función de otra columna.

Fit Curve tiene esta característica: Graph Builder también podría beneficiarse de esta característica.

Re: Constructor de gráficos. ¿Cómo combinar suavizador y línea?

Una mejora interesante en JMP19 es la función Propiedades de tipo() , que nos permite aplicar transparencia mucho más fácilmente:

• mismo grupo = mismo color
• Transparencia a través de Propiedades de tipo: no es necesario configurarla manualmente para cada curva.
• Cada grupo tiene su propia curva más suave (codificación de superposición = automática o color)
• Curvas más suaves con colores a juego
• Sólo las líneas en zigzag necesitan un poco de esfuerzo extra *)
  

*) y este tema puede abordarse en una versión futura de JMP:
https://community.jmp.com/t5/JMP-Wish-List/Posibilidad de agregar saltos de línea en el generador de gráficos/idc-p/921029/highlight/true#M8150
¡Frío!

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

Re: Constructor de gráficos. ¿Cómo combinar suavizador y línea?

Genial, JMP20 traerá una solución muy fácil para el problema con las líneas en zigzag : Sí, ¡estad atentos!

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

Re: Constructor de gráficos. ¿Cómo combinar suavizador y línea?

Parece un cambio radical para tipos específicos de gráficos, como las curvas IV agrupadas.
@isabelleswaenep