658341_zh-CN

liliconcom

图形生成器：如何将平滑器和直线结合起来？

我有几组测量数据，我想把它们“一起”绘制出来。

同一组个体的测量曲线应具有相同的颜色，并且是半透明的。
每个组都应该有一条颜色相同的更平滑的曲线。

在Jmp中可以实现吗？——无需使用“变通方法”？

版本 1：

• 一组测量结果颜色相同
• 每次测量一条曲线
• 透明度工作
• 用一条更平滑的线代替三条。
• 平滑曲线的颜色“不正确”[后果性错误]

版本 2：

• 一组测量结果颜色相同
• 各个曲线的糟糕回弹
• 透明度工作
• 每个组都有其自身更平滑的曲线。
• 曲线越平滑，颜色就越错误。

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

数据探索与可视化回复：图形生成器。如何结合平滑器和线条？

很好： 图形生成器的后备建议：线 - 可以添加中断[选项 (2)] 已经可用：

有了这一新发现，我很高兴向你们介绍：

版本 3：

• 同一组=同一颜色
• 没有令人讨厌的曲折曲线
• 透明度是有效的
• 每组都有自己更平滑的曲线
• 曲线更平滑，颜色更匹配
  
• 数据表中添加了新行*)

*) 作为一种解决方法，它可以工作，因为辅助行已添加到数据表中

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

第 1000 章

回复：图形生成器。如何结合平滑器和线条？

我希望有人能找到一种方法来在 Jmp (17) 中创建此图表 - 而无需在图表中添加新的行和列。

通过多列叠加可以解决这个问题。如果叠加层接受多列，用户可以为两种绘图类型选择不同的叠加层：

1. 更平滑元素的叠加：
   :group->每组一条拟合曲线
   
   
2. 线元素的叠加：
   :站点 -> 每个站点有单独的线路 = 没有曲折线

除了增强覆盖功能之外， 图形生成器还有另一个愿望：线 - 可以添加断点，使用一个简单的技巧来添加断点：
想法：测量轨迹从左到右。
从右到左的每个步骤都标志着一个新轨迹的开始 -> 添加一个断点。

回复：图形生成器。如何结合平滑器和线条？

啊，Color = “Group” 太多了。可以将其完全删除。

关于之字形：
我希望每个站点都有单独的曲线，这就是我启用行顺序的原因。

禁用该选项会导致一个组的所有站点产生一条组合曲线。

版本 2（b）：

• 同一组的测量值具有相同的颜色
• 各个曲线出现令人讨厌的跳转（通过删除行顺序来修复）
  不幸的是现在不再是这样了：每站一条曲线
• 透明度是有效的
• 每组都有自己更平滑的曲线
• 曲线更平滑，颜色更匹配

回复：图形生成器。 结合平滑器和线条 - 如何？

尝试从颜色中删除组以使其更平滑，并删除锯齿形禁用行顺序

 

回复：图形生成器。将平滑器和线条结合起来 - 如何？

@XanGregg ，叠加编码将有助于创建此类图（不同变体的不同颜色和单独的拟合曲线 - 但每个变体有多个测量曲线）。

回复：图形生成器。如何结合平滑器和线条？

并配置级别？
不，又是锯齿状的线条。

查看更多...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

回复：图形生成器。如何将平滑器和直线结合起来？

如果您经常生成此类图表，请查看快速选择工具栏。
有一个快捷图标可以自动创建虚拟行，并对表格进行排序，将虚拟行放置在正确的位置。

该功能已从快速选择工具栏中移除。
现在可以通过 GraphBuilder 工具栏获得类似的功能。

回复：图形生成器。如何结合平滑器和线条？

我们正在对 Graph Builder 的“远程控制”插件进行 beta 测试，这将有助于手动格式化图表。
我添加了一个按钮来删除曲折线：）

与“添加虚拟行”相比，它的优点是它不会与排序数据表 + 添加行 + 连接相冲突 - 使其成为可能

回复：图形生成器。如何结合平滑器和线条？

类似于“拟合曲线”中的“曲线 ID 列”的形式将数据拆分为单独的曲线 - 但仍然根据另一列捆绑类似的曲线。

拟合曲线具有此功能 -图形生成器也可以从该功能中受益。

回复：图形生成器。如何将平滑器和直线结合起来？

JMP19 的一个不错的改进是类型属性()功能，它使我们能够更轻松地应用透明度：

• 同一组 = 相同颜色
• 通过类型属性设置透明度 - 无需为每条曲线手动设置。
• 每个组都有自己的平滑曲线（叠加编码 = 自动或颜色）
• 更流畅的曲线，颜色也更协调
• 只是之字形线条需要多花些功夫*)
  

*）并且该主题可能会在JMP的未来版本中得到解决：
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
凉爽的！

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

回复：图形生成器。如何将平滑器和直线结合起来？

太好了，JMP20 将为锯齿线问题带来一个非常简单的解决方案： 敬请期待！

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

回复：图形生成器。如何将平滑器和直线结合起来？

它感觉像是对某些特定类型的图表（例如分组 IV 曲线）的颠覆性改变。
@isabelleswaenep