658341_ko-KR

liliconcom

그래프 작성기. 부드럽게 하기와 선 그리기 기능을 결합하는 방법은 무엇일까요?

저는 여러 측정값을 그룹으로 묶어 그래프로 나타내고 싶습니다.

그룹 내 개별 측정 곡선은 모두 동일한 색상이어야 하며 반투명해야 합니다.
각 그룹마다 동일한 색상의 더 부드러운 곡선이 추가되어야 합니다.

Jmp에서 "편법" 없이 이것이 가능한가요?

버전 1:

• 한 그룹의 측정값은 모두 같은 색입니다.
• 측정값당 하나의 곡선
• 투명성 작업
• 3개가 아닌 1개의 더 부드러운 선
• 더 부드러운 곡선이 "올바른" 색상을 가지고 있지 않습니다 [결과적 오류]

버전 2:

• 한 그룹의 측정값은 모두 같은 색입니다.
• 개별 곡선에 대한 불쾌한 역방향 점프
• 투명성 작업
• 각 그룹은 고유의 더 매끄러운 곡선을 가지고 있습니다.
• 더 매끄러운 곡선에는 잘못된 색상이 사용되었습니다.

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

데이터 탐색 및 시각화Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

좋음: Graph Builder의 대체 제안: 선 - 끊기 추가 가능성 [옵션(2)]이 이미 사용 가능합니다:

이 새로운 발견을 바탕으로 저는 여러분께 다음과 같은 내용을 소개하게 되어 기쁩니다.

버전 3:

• 같은 그룹 = 같은 색상
• 불쾌한 지그재그 곡선은 없다
• 투명성 작업
• 각 그룹은 각자의 더 부드러운 곡선을 가지고 있습니다
• 색상이 일치하는 더 부드러운 곡선
  
• 데이터 테이블에 새로운 행이 추가됨 *)

*) 해결 방법으로 확인: 보조 행이 데이터 테이블에 추가되었기 때문에 작동합니다.

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

#1000

Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

누군가가 그래프에 새로운 행과 열을 추가하지 않고도 Jmp(17)에서 이 그래프를 생성할 수 있는 방법을 찾기를 바랍니다.

여러 열로 오버레이하면 문제가 해결됩니다. 오버레이가 두 개 이상의 열을 허용하는 경우 사용자는 두 플롯 유형에 대해 다른 오버레이를 선택할 수 있습니다.

1. 더 부드러운 요소에 대한 오버레이:
   :group-> 그룹당 하나의 적합 곡선
   
   
2. 라인 요소에 대한 오버레이:
   :역 -> 역당 별도의 트레이스 = 지그재그 라인 없음

오버레이 기능을 향상시키는 것 외에도 그래프 빌더에 대한 또 다른 희망사항은 다음과 같습니다. 선 - 간단한 트릭을 사용하여 끊김을 추가할 수 있는 기능 입니다.
아이디어: 측정 흔적이 왼쪽에서 오른쪽으로 이어진다.
오른쪽에서 왼쪽으로의 각 단계는 새로운 추적의 시작을 표시합니다 -> 중단을 추가합니다.

Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

아, 색상 = "그룹"은 너무 과합니다. 완전히 제거할 수 있습니다.

지그재그에 관하여:
저는 스테이션별로 별도의 곡선을 원하기 때문에 행 순서를 활성화했습니다.

해당 옵션을 비활성화하면 그룹의 모든 스테이션에 대해 하나의 결합된 곡선이 생성됩니다.

버전 2(b):

• 한 그룹의 측정값은 같은 색상을 갖습니다.
• 개별 곡선에 대한 불쾌한 점프 백(행 순서를 제거하여 수정됨)
  불행히도 더 이상 그렇지 않습니다:스테이션 당 하나의 곡선
• 투명성 작업
• 각 그룹은 각자의 더 부드러운 곡선을 가지고 있습니다
• 색상이 일치하는 더 부드러운 곡선

답변: 그래프 빌더. Smoother와 Line을 결합하는 방법 - 어떻게?

더 매끄럽게 하기 위해 색상에서 그룹을 제거하고 지그재그 비활성화 행 순서를 제거해 보십시오.

 

답변: 그래프 빌더. Smoother와 Line을 결합하는 방법 - 어떻게?

@XanGregg 는 오버레이 인코딩을 통해 이러한 플롯(다양한 변형에 대해 다양한 색상 및 개별 맞춤 곡선 - 변형당 둘 이상의 측정 곡선) 생성을 용이하게 합니다.

Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

그리고 수준을 구성하나요 ?
아니요: 또 지그재그 선이에요.

더 보기...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

제목: 그래프 작성기 관련 질문입니다. 부드럽게 하기 기능과 선 그리기 기능을 결합하는 방법은 무엇인가요?

이러한 그래프를 정기적으로 생성하는 경우 QuickSelect 툴바를 살펴보시기 바랍니다.
더미 행을 자동으로 생성하고 테이블을 정렬하여 더미 행을 올바른 위치에 배치하는 바로가기 아이콘이 있습니다.

해당 기능은 퀵셀렉트 툴바에서 제거되었습니다.
이제 GraphBuilder 툴바를 통해 유사한 기능을 사용할 수 있습니다.

Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

우리는 그래프 빌더용 "원격 제어" 추가 기능의 베타 테스트를 진행 중이며, 이를 통해 플롯의 수동 서식 지정이 가능해질 것입니다.
지그재그 선을 제거하는 버튼을 추가했습니다 : )

"더미 행 추가"와 비교하면 정렬 데이터 테이블 + 행 추가 + 연결과 충돌하지 않는다는 이점이 있습니다.

Re: 그래프 빌더. Smoother와 Line을 결합하는 방법?

Fit curve에서 "곡선 ID 열"과 같은 형식을 사용하여 데이터를 개별 곡선으로 분할하지만 다른 열을 기준으로 유사한 곡선을 묶습니다.

Fit Curve 에는 이 기능이 있습니다. Graph Builder 도 이 기능으로부터 이점을 얻을 수 있습니다.

제목: 그래프 작성기 관련 질문입니다. 부드럽게 하기 기능과 선 그리기 기능을 결합하는 방법은 무엇인가요?

JMP19의 훌륭한 개선점 중 하나는 유형 속성() 기능으로, 이를 통해 투명도를 훨씬 쉽게 적용할 수 있게 되었습니다.

• 같은 그룹 = 같은 색상
• 유형 속성을 통해 투명도를 설정할 수 있으므로 곡선마다 수동으로 설정할 필요가 없습니다.
• 각 그룹은 고유한 부드러운 곡선을 가지고 있습니다(오버레이 인코딩 = 자동 또는 색상).
• 더욱 매끄러운 곡선과 어울리는 색상
• 지그재그 선만 좀 더 신경 써서 그려야 해요 *)
  

*) 이 주제는 JMP의 향후 버전에서 다뤄질 수 있습니다.
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
시원한!

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

제목: 그래프 작성기 관련 질문입니다. 부드럽게 하기 기능과 선 그리기 기능을 결합하는 방법은 무엇인가요?

멋지네요! JMP20은 지그재그 선 문제를 아주 쉽게 해결해 줄 거예요. 기대해 주세요!

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

제목: 그래프 작성기 관련 질문입니다. 부드럽게 하기 기능과 선 그리기 기능을 결합하는 방법은 무엇인가요?

이는 그룹화된 IV 곡선과 같은 특정 유형의 그래프에 있어서 판도를 바꿀 만한 혁신적인 기능처럼 느껴집니다.
@isabelleswaenep