658341_ja-JP

liliconcom

グラフビルダー。スムージングとラインを組み合わせるにはどうすればいいですか?

「一緒に」プロットしたい測定値のグループがあります。

グループ内の個々の測定曲線は同じ色で半透明である必要があります。
各グループには、同じ色のより滑らかな曲線が追加されている必要があります。

これは Jmp で可能ですか? - 「回避策」なしで?

バージョン1:

• 1つのグループの測定値は同じ色になります
• 測定ごとに1つの曲線
• 透明性は機能する
• 3本ではなく1本の滑らかな線
• 滑らかな曲線は「正しい」色ではありません [結果的なエラー]

バージョン2:

• 1つのグループの測定値は同じ色になります
• 個々のカーブで厄介なジャンプバック
• 透明性は機能する
• 各グループには独自の滑らかな曲線があります
• より滑らかな曲線は色が間違っている

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

データの探索と可視化Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

いいですね: グラフビルダーのフォールバック提案: ライン - ブレークを追加する可能性[オプション (2)] はすでに利用可能です:

この新たな発見を皆さんにご紹介できることを嬉しく思います。

バージョン3:

• 同じグループ = 同じ色
• 厄介なジグザグ曲線はありません
• 透明性は機能する
• 各グループには独自の滑らかな曲線がある
• より滑らかな曲線と一致する色
  
• データテーブルに新しい行が追加されました*)

*) 回避策としては、補助行がデータテーブルに追加されたため機能します。

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

＃1000

Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

誰かが、グラフに新しい行や列を追加せずに、Jmp (17) でこのグラフを作成する方法を見つけてくれることを願っています。

複数列によるオーバーレイにより、問題は解決します。オーバーレイが複数の列を受け入れる場合、ユーザーは 2 つのプロット タイプに対して異なるオーバーレイを選択できます。

1. よりスムーズな要素のオーバーレイ:
   :group-> グループごとに1つのフィット曲線
   
   
2. 線要素のオーバーレイ:
   :ステーション -> ステーションごとに別々のトレース = ジグザグ線なし

オーバーレイ機能の強化に加えて、 グラフ ビルダーのもう 1 つの要望として、ライン - ブレークを追加するための簡単なトリックを使用するブレークの追加があります。
アイデア: 測定トレースは左から右に実行されます。
右から左への各ステップは、新しいトレースの開始を示します -> ブレークを追加します。

Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

ああ、Color = "Group" はやりすぎです。完全に削除できます。

ジグザグについて:
ステーションごとに別々の曲線を作成したいので、行順序を有効にしました。

このオプションを無効にすると、グループのすべてのステーションに対して 1 つの結合曲線が作成されます。

バージョン2 (b):

• 1つのグループの測定値は同じ色になります
• 個々の曲線が逆方向にジャンプする (行の順序を削除することで修正)
  残念ながらもうそうではありません:駅ごとに1つのカーブ
• 透明性は機能する
• 各グループには独自の滑らかな曲線がある
• より滑らかな曲線と一致する色

Re: グラフビルダー。 スムーサーとラインを組み合わせる - どのように?

スムーズにするために色からグループを削除し、ジグザグを削除するには行順序を無効にしてみてください

 

Re: グラフビルダー。スムーサーとラインを組み合わせる - どのように?

@XanGregg 、オーバーレイエンコーディングにより、そのようなプロット（異なるバリアントごとに異なる色と個別のフィットカーブ - ただし、バリアントごとに複数の測定曲線）の作成が容易になります。

Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

レベルを設定しますか?
いいえ、またジグザグの線です。

もっと見る...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

Re: グラフビルダー。スムージングとラインを組み合わせるにはどうすればいいですか?

このようなプロットを定期的に生成する場合は、 クイック選択ツールバーをご覧ください。
ダミー行を自動的に作成し、テーブルを並べ替えてダミー行を適切な位置に配置するためのショートカット アイコンがあります。

この機能は QuickSelect ツールバーから削除されました。
同様の機能がGraphBuilderツールバーから利用できるようになりました

Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

私たちは、グラフの手動フォーマットを容易にするグラフ ビルダーの「リモート コントロール」アドインのベータ テストを行っています。
ジグザグ線を削除するボタンを追加しました:)

「ダミー行の追加」と比較すると、データテーブルの並べ替え+行の追加+連結と衝突しないという利点があり、

Re: グラフ ビルダー。スムーザーとラインを組み合わせるにはどうすればいいですか?

フィット曲線の「曲線 ID 列」のような形式を使用して、データを個別の曲線に分割しますが、それでも別の列に基づいて類似の曲線をバンドルします。

Fit Curve にはこの機能があり、 Graph Builder もこの機能の恩恵を受けることができます。

Re: グラフビルダー。スムージングとラインを組み合わせるにはどうすればいいですか?

JMP19 のすばらしい改善点は型プロパティ()機能で、これにより透明性をはるかに簡単に適用できるようになりました。

• 同じグループ = 同じ色
• タイププロパティによる透明度 - 曲線ごとに手動で設定する必要はありません。
• 各グループには独自の滑らかな曲線があります（オーバーレイエンコーディング = 自動またはカラー）
• 色がマッチした滑らかな曲線
• ジグザグの線を描くのに少し手間がかかります*)
  

*) このトピックは、JMP の将来のバージョンで対処される可能性があります。
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
いいね！

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

Re: グラフビルダー。スムージングとラインを組み合わせるにはどうすればいいですか?

すごいですね。JMP20 はジグザグ線の問題に非常に簡単な解決策をもたらします。 はい、お楽しみに!

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

Re: グラフビルダー。スムージングとラインを組み合わせるにはどうすればいいですか?

グループ化された IV 曲線などの特定の種類のプロットにとっては画期的な機能のように思えます。
@isabelleswaenep