658341_it-IT

liliconcom

Graph Builder. Come combinare Smoother e Line?

Ho gruppi di misurazioni che voglio tracciare "insieme".

Le singole curve di misurazione di un gruppo devono avere lo stesso colore ed essere semitrasparenti.
Per ogni gruppo dovrebbe esserci un'ulteriore curva più uniforme con lo stesso colore.

È possibile farlo in Jmp? - senza "soluzioni alternative"?

versione 1:

• le misurazioni di un gruppo hanno lo stesso colore
• una curva per misurazione
• la trasparenza funziona
• 1 linea più fluida invece di 3
• la curva più liscia non ha il colore "giusto" [errore conseguente]

versione 2:

• le misurazioni di un gruppo hanno lo stesso colore
• salti brutti all'indietro per le singole curve
• la trasparenza funziona
• ogni gruppo ha la sua curva più fluida
• le curve più morbide hanno il colore sbagliato

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

Esplorazione e visualizzazione dei datiRe: Graph Builder. Come combinare Smoother e Line?

Bene: il suggerimento di fallback di Graph Builder: Line - possibilità di aggiungere interruzioni [opzione (2)] è già disponibile:

Con questa nuova scoperta, sono felice di presentarvi:

versione 3:

• stesso gruppo = stesso colore
• niente brutte curve a zig-zag
• la trasparenza funziona
• ogni gruppo ha la sua curva più fluida
• curve più morbide con colori abbinati
  
• nuove righe aggiunte alla tabella dati *)

*) OK come soluzione alternativa: funziona perché sono state aggiunte righe ausiliarie alla tabella dati

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

#1000

Re: Graph Builder. Come combinare Smoother e Line?

Spero che qualcuno trovi un modo per creare questo grafico in Jmp (17) - senza aggiungere nuove righe e colonne al grafico.

Overlay per più colonne risolverà il problema. Se Overlay accetta più di una colonna, l'utente può selezionare Overlay diversi per i due tipi di grafico:

1. Sovrapposizione per l'elemento più liscio:
   :group-> una curva di adattamento per gruppo
   
   
2. Sovrapposizione per l'elemento linea:
   :Stazione -> tracce separate per stazione = nessuna linea a zig-zag

Oltre a migliorare la funzionalità Overlay, ecco un altro desiderio di Graph Builder: Linea - possibilità di aggiungere interruzioni che utilizza un semplice trucco per aggiungere le interruzioni:
L'idea: una traccia di misurazione va da sinistra a destra.
Ogni passaggio da destra a sinistra segna l'inizio di una nuova traccia -> aggiungi un'interruzione.

Re: Graph Builder. Come combinare Smoother e Line?

Ah, il Colore = "Gruppo" è semplicemente troppo. Può essere rimosso completamente.

riguardo Zig-Zag:
Voglio avere curve separate per stazione, ecco perché ho abilitato l'ordine delle righe .

Disattivando l'opzione si ottiene una curva combinata per tutte le stazioni di un gruppo.

versione 2 (b):

• le misure di un gruppo hanno lo stesso colore
• fastidiosi salti indietro per le singole curve (risolti rimuovendo l'ordine delle righe)
  purtroppo non più:una curva per stazione
• la trasparenza funziona
• ogni gruppo ha la sua curva più fluida
• curve più morbide con colori abbinati

Ri: Costruttore di grafici. Combina Smoother e Line: come?

Prova a rimuovere il gruppo dal colore per renderlo più fluido e per rimuovere lo zigzag disabilita l'ordine delle righe

 

Ri: Costruttore di grafici. Combina Smoother e Line: come?

@XanGregg , la codifica Overlay faciliterà la creazione di tali grafici (curve di adattamento individuali e di colore diverso per varianti diverse, ma più di una curva di misurazione per variante).

Re: Graph Builder. Come combinare Smoother e Line?

E configurare i livelli ?
no: di nuovo le linee a zig-zag.

Vedi altro...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

Re: Graph Builder. Combinare Smoother e Line: come?

Se generi regolarmente grafici di questo tipo, dai un'occhiata alla barra degli strumenti QuickSelect .
È presente un'icona di collegamento per creare automaticamente le righe fittizie e per ordinare la tabella in modo da posizionare le righe fittizie nella posizione corretta.

La funzionalità è stata rimossa dalla barra degli strumenti di selezione rapida.
Una funzionalità simile è ora disponibile tramite la barra degli strumenti GraphBuilder

Re: Graph Builder. Come combinare Smoother e Line?

Stiamo solo testando la versione beta di un componente aggiuntivo "telecomando" per Graph Builder che semplificherà la formattazione manuale dei grafici.
Ho aggiunto un pulsante per rimuovere le linee a zig-zag : )

rispetto a "aggiungi righe fittizie" ha il vantaggio di non entrare in conflitto con Ordina tabella dati + aggiungi righe + concatena -- rendilo possibile

Re: Graph Builder. Come combinare Smoother e Line?

un formalismo come "colonna ID curva" in Adatta curva per suddividere i dati in singole curve, ma comunque per raggruppare curve simili in base a un'altra colonna.

Fit Curve ha questa funzionalità. Anche Graph Builder potrebbe trarne vantaggio.

Re: Graph Builder. Combinare Smoother e Line: come?

Un bel miglioramento in JMP19 è la funzionalità Proprietà del tipo() , che ci consente di applicare la trasparenza molto più facilmente:

• stesso gruppo = stesso colore
• trasparenza tramite Proprietà tipo: non è necessario impostarla manualmente per ogni curva.
• ogni gruppo ha la sua curva più fluida (codifica overlay = automatica o colore)
• curve più morbide con colori coordinati
• solo le linee a zig-zag richiedono un po' di sforzo in più *)
  

*) e questo argomento potrebbe essere affrontato in una futura versione di JMP:
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
Freddo!

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

Re: Graph Builder. Combinare Smoother e Line: come?

Fantastico, JMP20 offrirà una soluzione molto semplice al problema delle linee a zig-zag : sì, restate sintonizzati!

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

Re: Graph Builder. Combinare Smoother e Line: come?

Sembra un punto di svolta per tipi specifici di grafici, come le curve IV raggruppate.
@isabelleswaenep