658341_fr-FR

liliconcom

Créateur de graphiques. Combiner lissage et lignes : comment ?

J'ai des groupes de mesures que je souhaite représenter graphiquement « ensemble ».

Les courbes de mesure individuelles d'un groupe doivent avoir la même couleur et être semi-transparentes.
Pour chaque groupe, il devrait y avoir une courbe supplémentaire plus lisse de la même couleur.

Est-ce possible dans Jmp ? - sans « solutions de contournement » ?

version 1 :

• Les mesures d'un même groupe ont la même couleur
• une courbe par mesure
• La transparence fonctionne
• 1 ligne plus lisse au lieu de 3
• la courbe plus lisse n'a pas la « bonne » couleur [erreur conséquente]

version 2 :

• Les mesures d'un même groupe ont la même couleur
• des sauts en arrière désagréables pour les courbes individuelles
• La transparence fonctionne
• chaque groupe a sa propre courbe plus lisse
• Les courbes plus douces ont la mauvaise couleur

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

Exploration et visualisation des donnéesRe: Graph Builder. Combiner Smoother et Line - comment ?

Sympa : La suggestion de secours de Graph Builder : Ligne - possibilité d'ajouter des sauts [option (2)] est déjà disponible :

Avec cette nouvelle découverte, je suis heureux de vous présenter :

version 3:

• même groupe = même couleur
• pas de courbes en zigzag désagréables
• la transparence fonctionne
• chaque groupe a sa propre courbe plus lisse
• des courbes plus douces avec une couleur assortie
  
• nouvelles lignes ajoutées au tableau de données *)

*) OK comme solution de contournement : cela fonctionne car des lignes auxiliaires ont été ajoutées à la table de données

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Color( 0 ), Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

#1000

Re: Graph Builder. Combiner Smoother et Line - comment ?

J'espère que quelqu'un trouvera un moyen de créer ce graphique dans Jmp (17) - sans ajouter de nouvelles lignes et colonnes au graphique.

La superposition de plusieurs colonnes résoudra le problème. Si la superposition accepte plusieurs colonnes, l'utilisateur peut sélectionner différentes superpositions pour les deux types de tracés :

1. Superposition pour l'élément le plus lisse :
   :group-> une courbe d'ajustement par groupe
   
   
2. Superposition pour l'élément de ligne :
   :Station -> traces séparées par station = pas de lignes en zigzag

Outre l'amélioration de la fonctionnalité Overlay, voici un autre souhait de Graph Builder : Line - possibilité d'ajouter des sauts qui utilise une astuce simple pour ajouter les sauts :
L'idée : une trace de mesure s'étend de gauche à droite.
Chaque étape de droite à gauche marque le début d'une nouvelle trace -> ajouter une pause.

Re: Graph Builder. Combiner Smoother et Line - comment ?

Ah, la couleur = "Groupe" est tout simplement trop importante. Elle peut être complètement supprimée.

concernant Zig-Zag :
Je souhaite avoir des courbes séparées par station, c'est pourquoi j'ai activé l'ordre des lignes .

La désactivation de l'option entraîne une courbe combinée pour toutes les stations d'un groupe.

version 2 (b) :

• les mesures d'un groupe ont la même couleur
• sauts désagréables vers l'arrière pour les courbes individuelles (corrigé en supprimant l'ordre des lignes)
  malheureusement plus maintenant :une courbe par station
• la transparence fonctionne
• chaque groupe a sa propre courbe plus lisse
• des courbes plus douces avec une couleur assortie

Re : Générateur de graphiques. Combiner Smoother et Line - comment ?

Essayez de supprimer le groupe de la couleur pour plus de fluidité et pour supprimer le zigzag, désactivez l'ordre des lignes.

 

Re : Générateur de graphiques. Combiner Smoother et Line - comment ?

@XanGregg , Overlay Encoding facilitera la création de tels tracés (différentes couleurs et courbes d'ajustement individuelles pour différentes variantes - mais plus d'une courbe de mesure par variante).

Re: Graph Builder. Combiner Smoother et Line - comment ?

Et configurer les niveaux ?
non : encore les lignes en zigzag.

Voir plus...

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

Re : Créateur de graphiques. Combiner lissage et lignes : comment ?

Si vous générez régulièrement de tels graphiques, veuillez consulter la barre d'outils QuickSelect .
Il existe une icône de raccourci permettant de créer automatiquement les lignes factices et de trier le tableau afin de placer ces lignes factices au bon endroit.

Cette fonctionnalité a été supprimée de la barre d'outils QuickSelect.
Une fonctionnalité similaire est désormais disponible via la barre d'outils GraphBuilder.

Re: Graph Builder. Combiner Smoother et Line - comment ?

Nous testons simplement la version bêta d'un module complémentaire de « contrôle à distance » pour Graph Builder qui facilitera le formatage manuel des tracés.
J'ai ajouté un bouton pour supprimer les lignes en zig-zag : )

comparé à « ajouter des lignes factices », il présente l'avantage de ne pas entrer en conflit avec Trier le tableau de données + ajouter des lignes + concaténer - le rendre possible

Re: Graph Builder. Combiner Smoother et Line - comment ?

un formalisme comme « colonne d'ID de courbe » dans Ajuster la courbe pour diviser les données en courbes individuelles - mais toujours pour regrouper des courbes similaires en fonction d'une autre colonne.

Fit Curve possède cette fonctionnalité - Graph Builder pourrait également en bénéficier.

Re : Créateur de graphiques. Combiner lissage et lignes : comment ?

Une amélioration notable de JMP19 est la fonctionnalité Propriétés de type() , qui nous permet d'appliquer la transparence beaucoup plus facilement :

• même groupe = même couleur
• Transparence via les propriétés de type : inutile de la définir manuellement pour chaque courbe.
• chaque groupe possède sa propre courbe plus lisse (encodage de superposition = auto ou couleur)
• Des courbes plus douces avec une couleur assortie
• Seules les lignes en zigzag nécessitent un effort supplémentaire *)
  

*) et ce sujet pourrait être abordé dans une future version de JMP :
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
cool!

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

Re : Créateur de graphiques. Combiner lissage et lignes : comment ?

Génial ! JMP20 apportera une solution très simple au problème des lignes en zigzag : restez à l'écoute !

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));<BR />
Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

Re : Créateur de graphiques. Combiner lissage et lignes : comment ?

Cela semble changer la donne pour certains types de graphiques, comme les courbes IV groupées.
@isabelleswaenep