657090_zh-TW

liliconcom

按最終濃度與初始濃度過濾數據的公式？

我正在尋找一種方法來過濾圖表上的數據，以僅包含正在累積或耗盡的數據。 其簡單版本是累積 = 最終時間點的濃度 > 初始時間點的濃度（或 < 如果耗盡）。 然而，由於最終時間點並不總是相同，它會變得稍微複雜一些 - 有些數據集可能超過 12 天，有些可能是 14 天，等等。每個時間點實際上是 3 天也是很常見的重複，因此在決定事物是否正在積累或消耗時能夠使用這些平均值是理想的（如果不是，它可能並不重要）。 例如，在包含的圖像中，我希望能夠過濾並僅顯示用於累積分析物的藍線。 任何入門幫助將不勝感激！ 我的目標是有一列輸出為“累積”或“耗盡”，這樣它就可以添加到數據過濾器中。 提前致謝！

基礎數據分析和建模回复：按最終濃度與初始濃度過濾數據的公式？

列平均值()和其他類似的 Col 函數（Col Min、Col Max，...）可能會有所幫助。 如果您可以提供示例數據，其中一列指示正確答案，則可以提供示例。

回复：按最終濃度與初始濃度過濾數據的公式？

您好，我附上了我正在使用的數據類型的轉換/簡化版本，如果有幫助的話。 我知道 Col 功能，但我一直在努力以一種有效的方式將東西組合在一起

回复：按最終濃度與初始濃度過濾數據的公式？

由於沒有提供“正確”答案欄，我進行了猜測。 該腳本將創建公式列，這將有助於構建最終列。 使用公式時還有其他選項，或者您可以使用與公式完全不同的方法

Names Default To Here(1);

dt = Open("$DOWNLOADS/Sample Data for JMP Forum.jmp");
dt << Sort(By(:Time), Order(Ascending), Replace Table); // to make this a bit simpler sort by :Time

// Assumption: Time and Analyte create a group
dt << New Column("Mean_TimeAnalyte", Numeric, Continuous, Formula(
 Col Mean(:"Concentration (mM)"n, :Time, :Analyte)
));

// Assumption: We are looking for first and last average value for each Analyte
dt << New Column("FirstAnalyteValue", Numeric, Continuous, Formula(
 Col Sum(
  If(Row() == Col Min(Row(), :Analyte),
   :Mean_TimeAnalyte
  ,
   0
  ),
  :Analyte
 )
));

dt << New Column("LastAnalyteValue", Numeric, Continuous, Formula(
 Col Sum(
  If(Row() == Col Max(Row(), :Analyte),
   :Mean_TimeAnalyte
  ,
   0
  ),
  :Analyte
 )
));

dt << New Column("AnalyteStatus", Numeric, Continuous, Formula(
 If(:LastAnalyteValue > :FirstAnalyteValue,
  "Accumulating"
 ,
  "Depleting"
 );
));


gb = dt << Graph Builder(
 Size(528, 492),
 Show Control Panel(0),
 Variables(
  X(:Time),
  Y(:"Concentration (mM)"n),
  Group X(:AnalyteStatus),
  Overlay(:Analyte)
 ),
 Elements(
  Points(X, Y, Legend(5), Summary Statistic("Mean")),
  Line(X, Y, Legend(6))
 ),
 Local Data Filter(Add Filter(columns(:AnalyteStatus)))
);