nav[aria-label="Primary Navigation"] { padding: 0; & ul { list-style: none; width: 100%; display: flex; flex-direction: row; justify-content: start; align-items: start; gap: 30px; padding: 0; & li { margin: 0; } & ul li { list-style: none; } } }

656597_it-IT

liliconcom

Re: Seleziona 2 righe dal dado fallito

Forse qualcosa del genere

dtt = Open( "/Z:/failures.jmp" );// 109 inner rows

expand = 2;// how far to look for a failure
// these are paired, keep them in a Nx2 matrix...
fail = (dtt:X coord << get values) || (dtt:Y coord << get values);
// get min and max of the matrix columns
failmin = V Min( fail );
failmax = V Max( fail );
// find the +/- 2 area of interest
colmin = failmin[1] - expand;
colmax = failmax[1] + expand;
rowmin = failmin[2] - expand;
rowmax = failmax[2] + expand;
// turn the failure list back into a rectangular matrix, mark the actual failures
unmarked = 0; // points that have not been marked yet
interior = 1; // the failures are interior points
border = 2; // the border points are near the failures
bigpatch = J( rowmax + 1, colmax + 1, unmarked );
For Each( {{r, c}}, across( fail[0, 2], fail[0, 1] ), bigpatch[r, c] = interior );
// helper to check near r,c
nearFailure = Function( {r0, c0}, //parameters
 {rlow, rhigh, clow, chigh, r, c}, // locals
 // low..high is expanded without going beyond the edge of bigpatch
 rlow = Max( 1, r0 - expand );
 rhigh = Min( N Rows( bigpatch ), r0 + expand );
 clow = Max( 1, c0 - expand );
 chigh = Min( N Cols( bigpatch ), c0 + expand );
 // rlow..chigh is a slightly expanded search area
 For( r = rlow, r <= rhigh, r += 1,
  For( c = clow, c <= chigh, c += 1, 
   // any interior point (1) nearby?
   If(
    bigpatch[r, c] == interior// uncomment for "rounder"    
//    & Sqrt( (r - r0) ^ 2 + (c - c0) ^ 2 ) <= expand// the diagonal distance of the corners is expand*1.414...nearly 3...
   ,
    Return( 1 ) // found an interior point nearby
   )
  )
 );
 /*return*/ 0; // no interior point found nearby
);

For( r = rowmin, r <= rowmax, r += 1,
 For( c = colmin, c <= colmax, c += 1,
  If( bigpatch[r, c] == unmarked & nearFailure( r, c ),
   bigpatch[r, c] = border// add a border to the bigpatch
  )
 )
);
// view a cellplot
dtcp = As Table( bigpatch[rowmin - 1 :: rowmax + 1, colmin - 1 :: colmax + 1] );
dtcp[1 :: N Rows( dtcp ), 0] = dtcp[N Rows( dtcp ) :: 1, 0];// flip to make the same as graph builder
dtcp << Cell Plot( Scale Uniformly( 0 ), Center at zero( 0 ), Y( dtcp << getcolumnnames ) );


dt = Open( "/Z:/Summary Bins.jmp" );// all rows
//Clear values
dt:Highlight[1 :: N Rows( dt )] = "";
//Loop to highlight 2 dies
dt << Begin Data Update;
For( i = 1, i <= N Rows( dt ), i++,
 c = dt:X coord[i];
 r = dt:Y coord[i];
 If( r < N Rows( bigpatch ) & c < N Cols( bigpatch ) & bigpatch[r, c] == border,
  dt:Highlight[i] = "1"
 );
);
dt << End Data Update;

dt << select where( :Highlight == "1" & :Bins == "1" );

dt << Graph Builder( Size( 528, 454 ), Show Control Panel( 0 ), Variables( X( :X coord ), Y( :Y coord ) ), Elements( Points( X, Y, Legend( 7 ) ) ) );

Potresti volere questo

o questo, vedere la riga commentata per il calcolo della distanza. Dipende da come vuoi trattare la distanza diagonale.

Re: Seleziona 2 righe dal dado fallito

Grazie mille Craig

Seleziona 2 righe

Ciao comunità JMP,

Voglio evidenziare due punti dati da ciascuna coordinata X e Y del contenitore dei guasti "2". Ho provato a scrivere un codice jsl, ma i risultati non sono corretti.
Il codice seguente evidenzia più di due punti dati dalle coordinate X e Y del contenitore errori "2". Eventuali suggerimenti?

Ecco il codice

Names Default To Here( 1 );
dtt = Data Table( "failures" );
dt = Data Table( "Summary Bins" );
//Clear values
dt:Highlight[1 :: N Rows( dt )] = "";
//define list for storing +/-2 X and Y coord in the list
xList = [];
yList = [];

//get X and Y coord of the failing dies
fail_xcoord = dtt:X coord << get values;
fail_ycoord = dtt:Y coord << get values;

// Add and subtract 2 from X and Y using a loop
For( j = 1, j <= N Rows( dtt ), j++,
 For( i = -2, i <= 2, i++,
  newX = dtt:X coord[j] + i;
  newY = dtt:Y coord[j] + i;

  If( newX != dtt:X coord[j],
   Insert Into( xList, newX )
  ); 
    

  If( newY != dtt:Y coord[j],
   Insert Into( yList, newY )
  );

    
 )
);

//Loop to highlight 2 dies
dt << Begin Data Update;
For( i = 1, i <= N Rows( dt ), i++,
 If( Contains( xlist, dt:X coord[i] ) & Contains( fail_ycoord, dt:Y coord[i] ),
  dt:Highlight[i] = "1";
  
  
 );
 If( Contains( ylist, dt:Y coord[i] ) & Contains( fail_xcoord, dt:X coord[i] ),
  dt:Highlight[i] = "1";
  
  
 );
  
);
dt << End Data Update;

dt << select where( :Highlight == "1" & :Bins == "1" );

Grazie,
Jackie

Automazione e scripting