655511_de-DE

liliconcom

Problem beim Hinzufügen eines Kontrolldiagramms zum Dashboard

Hallo alle,

Ich versuche, mehrere Kontrolldiagramme zu einem Dashboard hinzuzufügen und habe dabei Probleme.Insbesondere wird beim Versuch, die Diagramme einem Dashboard hinzuzufügen, der angehängte Fehler angezeigt.Ich habe dies versucht, indem ich Fenster

 

-Matt

Grundlegende Datenanalyse und ModellierungBetreff: Problem beim Hinzufügen eines Kontrolldiagramms zum Dashboard

Hallo @barnabei – Ich bin mir aufgrund des Fehlers nicht sicher, ob es die Plattform oder vielleicht die Datentabelle ist, die dazu führt, dass Dashboard Builder das Objekt nicht erstellen kann.Es kann hilfreich sein, die JMP-Version zu kennen, wie die Datentabelle erstellt wurde und wie das Skript für den Control Chart Builder aussieht.

 

-Dan

Betreff: Problem beim Hinzufügen eines Kontrolldiagramms zum Dashboard

Hallo @danschikore , die JMP-Version ist 17.0.0 (Mac).

 

Siehe Anhang für die Datentabelleneingabe (Daten gelöscht)

 

Skript zum Erstellen von Regelkarten:

 

dtSum = Current Data Table();
Summarize( assaylist = by( :Assay x Ctl ) );
NAssays = Length( assaylist );
For( i = 1, i <= NAssays, i++,
 dtSum << Control Chart Builder(
  Variables(
   Subgroup( :batch_id ),
   Y( :"Mean(Inf conc Mean Median)"n ),
   Phase( :Ctl lot x Assay x Ctl )
  ),
  Get Limits(
   "/Users/matt.barnabei/Desktop/QC Plotting Data/QC Limit Summary.jmp"
  ),
  Show Control Panel( 0 ),
  Where( :Assay x Ctl == assaylist[i] ),
  SendToReport(
   Dispatch(
    {},
    "Control Chart Builder",
    FrameBox,
    {Frame Size( 0, 0 )}
   )
  )
 )
);

Betreff: Problem beim Hinzufügen eines Kontrolldiagramms zum Dashboard

Hallo @barnabei - Das Problem hier ist der Ausdruck, der in der where()-Klausel übergeben wird.JMP behält diesen Ausdruck in der geschriebenen Form bei, und wenn das Skript für die Plattform gespeichert und erneut ausgeführt wird, sind die Variablen nicht mehr vorhanden.Dies hätte auch Auswirkungen auf andere Aktionen, die die Möglichkeit erfordern, eine Plattform über ein Skript erneut auszuführen, z. B. das Veröffentlichen in JMP Live oder das Speichern in einem JMP-Projekt.Dieses Beispiel zeigt das gleiche Problem:

 

 

dt=Open("$SAMPLE_DATA/Big Class.jmp");
level=15;
biv = dt << Bivariate(X(:height),Y(:weight),Where(:age==level));

 

Eine Möglichkeit, das Problem zu beheben, besteht darin, den Ausdruck so zu manipulieren, dass er in die tatsächliche Ebene eingefügt wird:

 

 

dt=Open("$SAMPLE_DATA/Big Class.jmp");
level=15;
Eval(EvalExpr(biv = dt << Bivariate(X(:height),Y(:weight),Where(:age==Expr(level)))));

Hoffentlich hilft das!