643247_zh-CN

liliconcom

来自多个数据表的多选项卡仪表板

您好，我正在根据以下发现谈话中给出的脚本创建一个多选项卡式仪表板： https://community.jmp.com/t5/Discovery-Summit-Americas-2021/One-Multi-tabbed-Filterable-Dashboard-2021-US-30MP-803/ta-p/398667

 

用于组合多个仪表板的脚本如下：

 

 

dashes = Find All(Reports);

tb = Expr(Tab Box());

For(i = 1, i<= N Items(dashes), i ++,
 
 tabPage = Expr(Tab Page Box());
 dfcb = Expr(Data Filter Context Box());
 lub = Expr(Line Up Box(N Col(2)));
 hlb = Expr(H List Box());

 //Get Data table name to use with the data filter
 wintitle = dashes[i] << Get Window Title;
 wordone = Word(1, wintitle, "-");
 wordtwo = Word(2, wintitle, "-");
 dtname = Substr(wordone, 1, Length(wordone)-1 );
 dt = Eval Expr(Data Table(Expr(dtName)));
 
 //Get dashboard name 
 dashName = Substr(wordtwo, 2);
 
 failed = 0;
 j = 1;
 //Loop through the tab page boxes in the dashboard, and extract the scripts
 While(failed ==0,
  Try(tpb = dashes[i] << Find(TabPageBox(j)),
   failed = 1; Continue();
  );
  //Try to get the script from the display box if it exisits
  Try(obj = tpb << Get Scriptable Object;
   script = obj << Get Script,
   j ++; Continue();
  );
  //If the script is for the local data filter add the script to the H List Box
  If(Char(Head(Name Expr(script))) == "Data Filter",
   FilterExprStr = char(NameExpr(dt)) || " << " || char(Name Expr(script));
   FilterExpr = Parse(FilterExprStr);
   Insert Into(hlb,NameExpr(FilterExpr));
  ,
   //Else add it to the lineup box
   If( Char(Name Expr(script)) != "Scriptable[]",
    reportExprStr = char(NameExpr(dt)) || " << " || char(Name Expr(script));
    reportExpr = Parse(reportExprStr);
    scrollbox = Expr(Scroll Box());
    Insert Into(scrollbox, Name Expr(reportExpr));
    Insert Into(lub,Name Expr(scrollbox)); 
   );
   
  );
  
  
  j ++;
 );
 
 //Build up the display boxes
 Insert Into(hlb, Name Expr(lub));
 Insert Into(dfcb, Name Expr(hlb));

 Insert Into(tabPage, Eval Expr(Title(Expr(dashName))), 1);
 Insert Into(tabPage, Name Expr(dfcb), 2);
 
 Insert Into(tb, Name Expr(tabPage));
);

//Create combined dashboard window
New Window("Ac-225 trending tool, v0.1", tb);

//Close all the individual dash reports
For( w = 1, w <= N Items(dashes), w ++,
 dashes[w] << Close Window;
);

 

 

然而，与发现谈话相反，我的仪表板基于不同的数据表，而不是单个数据表。
我打开了所有数据表和仪表板，并运行上述脚本以将所有仪表板组合成一个多选项卡式仪表板。 这会给出以下错误消息：

看起来它无法从我的仪表板中提取本地数据过滤器。 关于如何更改通用脚本以便能够组合所有打开的仪表板的任何建议？

自动化和脚本回复：来自多个数据表的多选项卡仪表板

或者也许还有其他解决方案可以将多个开放仪表板组合到多选项卡仪表板上？

回复：来自多个数据表的多选项卡仪表板

更新：

 

上面的错误信息与数据源是多个表无关。 另一方面，如果其中一个数据表的名称包含连字符 (-)，CombineDashboards.jsl 将不起作用。 从名称中删除连字符可以解决问题。