643247_zh-TW

liliconcom

來自多個數據表的多選項卡儀表板

您好，我正在根據以下發現談話中給出的腳本創建一個多選項卡式儀表板： https://community.jmp.com/t5/Discovery-Summit-Americas-2021/One-Multi-tabbed-Filterable-Dashboard-2021-US-30MP-803/ta-p/398667

 

用於組合多個儀表板的腳本如下：

 

 

dashes = Find All(Reports);

tb = Expr(Tab Box());

For(i = 1, i<= N Items(dashes), i ++,
 
 tabPage = Expr(Tab Page Box());
 dfcb = Expr(Data Filter Context Box());
 lub = Expr(Line Up Box(N Col(2)));
 hlb = Expr(H List Box());

 //Get Data table name to use with the data filter
 wintitle = dashes[i] << Get Window Title;
 wordone = Word(1, wintitle, "-");
 wordtwo = Word(2, wintitle, "-");
 dtname = Substr(wordone, 1, Length(wordone)-1 );
 dt = Eval Expr(Data Table(Expr(dtName)));
 
 //Get dashboard name 
 dashName = Substr(wordtwo, 2);
 
 failed = 0;
 j = 1;
 //Loop through the tab page boxes in the dashboard, and extract the scripts
 While(failed ==0,
  Try(tpb = dashes[i] << Find(TabPageBox(j)),
   failed = 1; Continue();
  );
  //Try to get the script from the display box if it exisits
  Try(obj = tpb << Get Scriptable Object;
   script = obj << Get Script,
   j ++; Continue();
  );
  //If the script is for the local data filter add the script to the H List Box
  If(Char(Head(Name Expr(script))) == "Data Filter",
   FilterExprStr = char(NameExpr(dt)) || " << " || char(Name Expr(script));
   FilterExpr = Parse(FilterExprStr);
   Insert Into(hlb,NameExpr(FilterExpr));
  ,
   //Else add it to the lineup box
   If( Char(Name Expr(script)) != "Scriptable[]",
    reportExprStr = char(NameExpr(dt)) || " << " || char(Name Expr(script));
    reportExpr = Parse(reportExprStr);
    scrollbox = Expr(Scroll Box());
    Insert Into(scrollbox, Name Expr(reportExpr));
    Insert Into(lub,Name Expr(scrollbox)); 
   );
   
  );
  
  
  j ++;
 );
 
 //Build up the display boxes
 Insert Into(hlb, Name Expr(lub));
 Insert Into(dfcb, Name Expr(hlb));

 Insert Into(tabPage, Eval Expr(Title(Expr(dashName))), 1);
 Insert Into(tabPage, Name Expr(dfcb), 2);
 
 Insert Into(tb, Name Expr(tabPage));
);

//Create combined dashboard window
New Window("Ac-225 trending tool, v0.1", tb);

//Close all the individual dash reports
For( w = 1, w <= N Items(dashes), w ++,
 dashes[w] << Close Window;
);

 

 

然而，與發現談話相反，我的儀表板基於不同的數據表，而不是單個數據表。
我打開了所有數據表和儀表板，並運行上述腳本以將所有儀表板組合成一個多選項卡式儀表板。 這會給出以下錯誤消息：

看起來它無法從我的儀表板中提取本地數據過濾器。 關於如何更改通用腳本以便能夠組合所有打開的儀表板的任何建議？

自動化和腳本回复：來自多個數據表的多選項卡儀表板

或者也許還有其他解決方案可以將多個開放儀表板組合到多選項卡儀表板上？

回复：來自多個數據表的多選項卡儀表板

更新：

 

上面的錯誤信息與數據源是多個表無關。 另一方面，如果其中一個數據表的名稱包含連字符 (-)，CombineDashboards.jsl 將不起作用。 從名稱中刪除連字符可以解決問題。