506731_ko-KR

liliconcom

byVar가 있는 통계 사용자 지정(수식) 함수 만들기

내가 만든 이 위시리스트 항목과 관련하여: 정규화 및 강력한 통계 함수(및 행렬 함수) 추가 . 지금은 이것을 사용자 정의 함수로 작성하려고 시도할 수 있다고 생각했지만(공유하고 모든 사람을 위해 업데이트하는 것이 불가능하다는 것을 알고 있음에도 불구하고) 거의 즉시 첫 번째 문제에 직면했습니다. 열을 참조하는 방법... 사용자 지정 수식을 사용할 때 행 수준 계산을 사용하거나 :colname 대신 열을 문자열로 참조하여 수식 편집기에서 직접 사용할 수 없게 됩니다.

 

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

my_min = New Custom Function(
 "custom",
 "My Min1",
 Function({x, y},
  As Constant(
   vals = Column(x) << get values;
   groups = Column(y) << get values;
  );
  cur_group = Loc(groups, As Column(y));
  vals[cur_group[Loc Min(vals[cur_group])]];
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);

my_min = New Custom Function(
 "custom",
 "My Min2",
 Function({x, y},
  Col Minimum(Column(x), Column(y));
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);

my_min = New Custom Function(
 "custom",
 "My Min3",
 Function({x, y},
  Col Minimum(x, y);
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);

dt << New Column("ColMin", Numeric, Continuous, Formula(Col Minimum(:height, :sex)));
dt << New Column("MyMin1_str", Numeric, Continuous, Formula(custom:My Min1("height", "sex")));
dt << New Column("MyMin2_str", Numeric, Continuous, Formula(custom:My Min2("height", "sex")));
dt << New Column("MyMin3_str", Numeric, Continuous, Formula(custom:My Min3("height", "sex")));
dt << New Column("MyMin1_ref", Numeric, Continuous, Formula(custom:My Min1(:height, :sex)));
dt << New Column("MyMin2_ref", Numeric, Continuous, Formula(custom:My Min2(:height, :sex)));
dt << New Column("MyMin3_ref", Numeric, Continuous, Formula(custom:My Min3(:height, :sex)));

데이터 테이블스크립팅Re: byVar가 있는 통계 사용자 정의(수식) 함수 생성

이것을 훨씬 더 쉽게 만들어줄 위시리스트 항목:

사용자 지정 열 수식을 한 번에 평가하거나 행 간에 값을 캐시하는 옵션 또는 함수

Re: byVar가 있는 통계 사용자 정의(수식) 함수 생성

두 가지 의견:

1. 그것에 대한 참조를 찾을 수 없는 것 같지만 한 지점에서 내부 수식처럼 행 사이에 값을 캐시하는 사용자 지정 열 수식을 작성할 방법이 없다고 확실히 들었던 것을 기억합니다.따라서 각 행의 컨텍스트에서 평가하는 함수를 작성해야 합니다. 즉, 한 번에 하나의 값을 반환합니다.(가능하다면 여기에서 누군가 나를 바로잡아 주었으면 합니다.)
2. JMP는 열 참조를 함수에 전달하기 전에 평가합니다(즉시 평가). 즉, 전체 열 대신 해당 행에서 값을 가져옵니다.열에 대한 참조를 전달하도록 JMP에 지시해야 하며 Expr을 사용하여 이를 수행할 수 있습니다.

이것이 두 가지 문제를 모두 해결한다고 생각하지만 매우 직관적이거나 사용자에게 친숙한지는 잘 모르겠습니다.

업데이트: 사용자 지정 함수는 행 컨텍스트에 액세스할 수 있으므로 Test2에서와 같이 현재 행의 값을 함수에 전달할 필요가 없습니다.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

my_min = New Custom Function(
 "custom",
 "Test1",
 Function({x,y,yval},
  show(yval);
  show(Name Expr(x)<< get values);
  show(Loc(Name Expr(y) << Get Values, yval));
  Min((Name Expr(x)<< get values)[Loc(Name Expr(y) << Get Values, yval)]);
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);

custom:Test1(Expr(:age),Expr(:sex),"F");

dt << New Column("Test1", Numeric, Continuous, Formula(custom:Test1(Expr(:height), Expr(:sex), :sex)));

my_min = New Custom Function(
 "custom",
 "Test2",
 Function({x,y},
  xvals = Name Expr(x)<< get values;
  yvals = Name Expr(y) << Get Values;
  Min(xvals[Loc(yvals, yvals[row()])]);
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);

dt << New Column("Test2", Numeric, Continuous, Formula(custom:Test2(Expr(:height), Expr(:sex))));

Re: byVar가 있는 통계 사용자 정의(수식) 함수 생성

좋은 지적!평가할 열 참조를 얻는 데 너무 집중했기 때문에 값이 무의미하다는 사실조차 인식하지 못했습니다.나는 그것에 대해 더 생각할 것이다.

Re: byVar가 있는 통계 사용자 정의(수식) 함수 생성

열이 아닌 "행 단위"로 평가할 가능성이 높기 때문에 정답을 제공하지 않는 것 같습니다.

 

Re: byVar가 있는 통계 사용자 정의(수식) 함수 생성

원하는 대로 작동합니까?열 참조가 될 것으로 예상되는 경우 함수 매개 변수를 명시적으로 평가해야 하는 것 같습니다.

my_min = New Custom Function(
 "custom",
 "My Min4",
 Function({x, y},
  EvalExpr(Col Minimum(Expr(x), Expr(y)));
 ),
 << Formula Category("Statistical")
);
Add Custom Functions(my_min);